Substituir várias palavras no Word 2003

engenheiro_pb

03-05-2011 12:29:49

Pessoal,
preciso substituir uma determinada palavra que se encontra em vários arquivos .doc. Para não ter que abrir cada arquivo para realizar essa operação, será que alguém poderia me informar se há um programa ou uma macro que possa realizar isso.

Desde já agradeço a ajuda.

webmaster

03-05-2011 14:01:23

Colega,

Se for Word 2003, o código abaixo resolve:

Código: Selecionar todos

Sub FindReplaceAllDocsInFolder( )
Dim i As Integer
Dim doc As Document
Dim rng As Range

With Application.FileSearch
    .NewSearch
    .LookIn = "C:\Meus Documentos"
    .SearchSubFolders = False
    .FileType = msoFileTypeWordDocuments
    If Not .Execute( ) = 0 Then
        For i = 1 To .FoundFiles.Count
             Set doc = Documents.Open(.FoundFiles(i))
             Set rng = doc.Range
              With rng.Find
                .ClearFormatting
                .Replacement.ClearFormatting
                .Text = "Texto procurado"
                .Replacement.Text = "Texto substituto"
                .Forward = True
                .Wrap = wdFindContinue
                .Format = False
                .MatchCase = False
                .MatchWholeWord = False
                .MatchWildcards = False
                .MatchSoundsLike = False
                .MatchAllWordForms = False
                .Execute Replace:=wdReplaceAll
               End With

             doc.Save
             doc.Close

             Set rng = Nothing
             Set doc = Nothing
        Next i
    Else
        MsgBox "Não houve substituições " & .FileName
    End If
End With
End Sub
Se for 2007 ou superior, será preciso codificar uma rotina com FileSystemObject, provavelmente.

Referências:
http://oreilly.com/pub/h/2573