[RESOLVIDO] Troca de Sheets automaticamente

l.mansur

07-06-2011 13:05:27

Prezados,
Bom dia!

Preciso de uma macro que execute a seguinte ação:

Trocar de uma planilha para a outra automaticamente.

No caso eu tenho 06 planilhas no workbook, e preciso que as 03 primeiras alternem em intervalos de 10 seg.

Ex:
Plan1
10 seg após
Plan2
10 seg após
plan 3
10 seg após
plan 1
10 seg após
plan 2
[...]

Tentei pelo código abaixo que vi em outro post do fórum mas não sei por que não funcionou.

Sub IniciaSlideShow()
SlideShowActive = True
Application.OnTime Now + TimeValue("00:00:10"), "Troca"
End Sub

Espero que me ajudem, obrigado!

JValq

07-06-2011 17:57:27

Boa tarde,

Veja se este código te ajuda:

Código: Selecionar todos

Dim SlideShowActive As Boolean

Sub IniciaSlideShow()
    SlideShowActive = True
    Troca
End Sub

Sub Troca()
    If SlideShowActive = True Then
        If ActiveSheet.Index < 3 Then
            Sheets(ActiveSheet.Index + 1).Select
        Else
            Sheets(1).Select
        End If
        Application.OnTime Now + TimeValue("00:00:10"), "Troca"
    End If
End Sub

Sub PararSlideShow()
    SlideShowActive = False
End Sub
Abraço

l.mansur

07-06-2011 21:25:04

Exelente !

Funciona perfeitamente, resolve meu problema !

A principio queria fazer uma macro que fizesse o seguinte:

Deixar as 3 colunas na mesma planilha ao invés de 3 planilhas diferentes e utilizar uma macro para ir selecionando as Rows que tivessem dados também com timming e quando não tivesse mais nada em determinada Row voltasse para a primeira (9).

Desta forma:

Col 1...................Col 2...................Col 3
.1........................1........................1.
.1........................1........................1.
.1........................1........................1.
.1........................1........................1.
.1........................1........................1.
.1........................1........................1.
.1.................................................1.
.1.................................................1.
.1...................................................

Fosse descendo, a principio infinitamente, ou até que não tivesse nenhum dado na row, a cada 05 seg cada linha.
E ao chegar a na última linha com dados voltasse para a linha 9.

Se não for pedir muito e puder me ajudar nesta tarefa, agradeço.


Estava batendo cabeça tentando fazer pelo código abaixo (que engloba vários de vários fóruns - perdoe a ignorancia):

Sub Selection()

Dim i As Integer
Dim cl As Range
For x = 1 To 1000
i = 9
Firstrow = 9

If Sheets("PAINEL MP").[b9] <> "" Then
Sheets("PAINEL MP").[b9:r9]
Application.OnTime Now + TimeValue("00:00:02"), "ActiveSheets.Range[b10:r10].Select"

ElseIf Sheets("PAINEL MP").[b10] <> "" Then
Set cl = Sheets("PAINEL MP").[b10:r10]
Else: Set cl = Sheets("PAINEL MP").[b9].End(xlUp)(2)

End If

Next x

End Sub

JValq

07-06-2011 23:21:05

Boa noite,

Veja se o código abaixo, atende:

Código: Selecionar todos

Dim SlideShowActive As Boolean

Sub IniciaSlideShow()
    SlideShowActive = True
    [A9:C9].Select
    Troca
End Sub

Sub Troca()
    Dim Intervalo As Range
    
    Set Intervalo = Selection.Offset(1, 0)
    
    If SlideShowActive = True Then
        If WorksheetFunction.CountIf(Intervalo, "") < 3 Then
            Selection.Offset(1, 0).Select
        Else
            [A9:C9].Select
        End If
        Application.OnTime Now + TimeValue("00:00:05"), "Troca"
    End If
End Sub

Sub PararSlideShow()
    SlideShowActive = False
End Sub
Abraço

l.mansur

08-06-2011 12:24:12

Pode fechar o tópico !
Vocês são demais !

Muito obrigado JValq !

Grande Abraço !