Bom dia segue a macro que exporta/cria dados como imagem Jpeg ou Gif.
Código: Selecionar todos
Sub Gera_Relatorio()
If MsgBox("Este comando só é aconselhavel executa-lo na Versão 2003 do Excel !! Deseja Realmente Gerar Relatório ?? ", vbExclamation + vbYesNo, " .:: RELATORIO ") = vbNo Then Exit Sub
Dim tmpSheet As Worksheet
Dim tmpChart As Chart
Dim tmpImg As Object
Dim fjpeg As String
Dim margem As Integer
On Error GoTo erro
'caso seja uma area fixa a copiar
Range("A4:j35").CopyPicture _
Appearance:=xlScreen, _
Format:=xlBitmap
'usar a selecção activa
' Selection.CopyPicture Appearance:=xlScreen, Format:=xlBitmap
'impede que se veja a acção acelerando o procedimento de cópia
'e exportação
Application.ScreenUpdating = False
'uma folha para colocarmos o grafico sem atrapalhar o resto
Set tmpSheet = Worksheets.Add
'colocar um grafico nesta nova folha
Charts.Add
'definições essenciais ao grafico, para que fique numa worksheet
'e não numa folha grafico
ActiveChart.Location Where:=xlLocationAsObject, Name:=tmpSheet.Name
'Colar a zona copiada para dentro da area do grafico
Set tmpChart = ActiveChart
With tmpChart
.Paste
Set tmpImg = Selection
With .ChartArea
'--------->
'(não essencial ao funcionamento da rotina)
'coloca um degrade no fundo do grafico
.Fill.OneColorGradient _
Style:=msoGradientHorizontal, _
Variant:=1, _
Degree:=0.231372549019608
'<----------
'sem linha de rebordo
.Border.LineStyle = xlNone
End With
'configurar a area do grafico acrescentando
'uma pequena borda ao redor da imagem centrando esta
margem = 8
With .Parent
.Height = tmpImg.Height + margem
.Width = tmpImg.Width + margem
End With
End With
'localização e nome do ficheiro de imagem
fjpeg = ThisWorkbook.Path & _
"\Relatório_" & Format(Now, "hhmmss_ddmmyyyy") & ".jpeg"
'exportar grafico
tmpChart.Export Filename:=fjpeg, FilterName:="jpeg"
'eliminar a folha temporaria sem avisos
Application.DisplayAlerts = False
tmpSheet.Delete
Application.DisplayAlerts = True
'repor o estado normal
Application.ScreenUpdating = True
'aviso de operação terminada
MsgBox "Seu Arquivo encontra-se em " & fjpeg, _
vbInformation, _
".:: Exportação"
GoTo fim
erro:
MsgBox "Erro: " & Err.Description, _
vbCritical, _
"Erro: " & Err.Number
fim:
Set tmpSheet = Nothing
Set tmpChart = Nothing
Set tmpImg = Nothing
End Sub
É valida apenas para o excel 2003 para 2007 tem que fazer adptações.
Abraço.