ListBox com dados de uma planilha (RESOLVIDO)

Erikson

10-12-2011 12:12:11

Bom dia pessoal, estou precisando montar um lintbox com os dados de uma planilha, preciso tambem saber como configurar a listbox, por exemplo configurar a quantidade de colunas que ela terá e barra de rolagem. É só para visualização dos dados, listbox é a melhor opção ou será o combobox? Ops.. não esquecendo, preciso dos códigos VBA para apontar a planilha e as células, ou sejá toda a estrutura.

joseA

10-12-2011 14:08:00

As mais utilizadas são:

Código: Selecionar todos

Private Sub UserForm_Initialize()
Dim lastRow As Long
Dim i As Integer
ListBox1.Clear
' Verifica qual a ultima linha preenchida
lastRow = Plan1.Range("A65000").End(xlUp).Row
'adiciona dados
For i = 2 To lastRow
ListBox1.AddItem Plan1.Range("A" & i)
Next
End Sub
e na Propriedade acionando o RowSource, idendificando ali o intervalo desejado, tipo: Plan1!A2:D7.
Vc pode inserir no RowSource também um intervalo nomeado.

Para o controle das colunas seria pela propriedade ListCount.

Erikson

11-12-2011 00:49:47

Pelo RowSource deu certo. Porem pelo código ficou mais interessante, a duvida que restou é a seguinte: como exibir mais de uma coluna, ex: A:C sem perder as propriedades do codigo VBA acima?

Mauro Coutinho

11-12-2011 21:26:10

Erikson,

não esquecendo, preciso dos códigos VBA para apontar a planilha e as células, ou sejá toda a estrutura

Não entendi esta parte, se quer ajuda ou um modelo pronto, se for ajuda, alem da sugestão do JoséA, você pode dar uma olhada no tópico abaixo tambem :
Inserir o valor que está na listbox p/ celula ativa excel
viewtopic.php?f=20&t=1259&hilit=listbox1

Se realizar Busca no Forum por "Listbox1", encontrará uma infinidade de exemplos e ajudas.

Agora se for um modelo pronto, é um pouco mais dificil.

Eu, particularmente, depois que conheci o controle ListView, praticamente abandonei o Listbox.

[]s

joseA

11-12-2011 23:29:16

Teste assim:

Código: Selecionar todos

Private Sub UserForm_Initialize()
Dim Registros As Long
Registros = Plan1.Range("A65536").End(xlUp).Row
If Registros > 1 Then
   With ListBox1
        .ColumnCount = 3
        .RowSource = "Plan1!A2:C" & Registros
   End With
End If
End Sub

joseA

11-12-2011 23:32:12

Mais do mesmo:

Código: Selecionar todos

Private Sub UserForm_Initialize()
'ao inicializar o form preenche o controle
Call PreencherListBox
End Sub

Sub PreencherListBox()
Dim lastRow As Long
Dim i As Integer
ListBox1.Clear
With ListBox1
'define nº colunas
        .ColumnCount = 3
End With
' Verifica qual a ultima linha preenchida
lastRow = Plan1.Range("A65000").End(xlUp).Row
'adiciona dados
For i = 2 To lastRow
Me.ListBox1.AddItem Plan1.Range("A" & i)
Me.ListBox1.List(Me.ListBox1.ListCount - 1, 1) = Plan1.Range("B" & i)
Me.ListBox1.List(Me.ListBox1.ListCount - 1, 2) = Plan1.Range("C" & i)
Next
End Sub

Erikson

13-12-2011 20:56:37

Obrigado a todos, principamente com a dica do José, o objetivo foi alcançado.

joseA

14-12-2011 00:42:05

Estando ao nosso alcance disponha. ;)

No entanto, fico com o Mauro, prefiro o ListView. Tem uma estética melhor e mais recursos.

Erikson

17-12-2011 09:00:12

joseA escreveu:Estando ao nosso alcance disponha. ;)

No entanto, fico com o Mauro, prefiro o ListView. Tem uma estética melhor e mais recursos.
Ok José, irei seguir a dica e pesquisar sobre ListView, pois o listbox é bem restrito.

joseA

17-12-2011 20:44:04

Olha aquí um exemplo para 05 colunas:

Código: Selecionar todos

Sub PreencheListview()
    Dim itens As ListItem
    Dim lastRow As Long
    Dim X As Long
    
    Set ws = Plan9
        
        ' Verifica qual a ultima célula preenchida
        lastRow = ws.Cells(Rows.Count, 1).End(xlUp).Row
    
    'Cria o cabeçalho
    With ListView1
        .ColumnHeaders.Clear
        .Gridlines = True
        .View = lvwReport
        .ListItems.Clear
        '.FullRowSelect
        .ColumnHeaders.Add Text:="Data de Lçto", Width:=60 'Data de Lçto
        .ColumnHeaders.Add Text:="Safra", Width:=50 'Safra
        .ColumnHeaders.Add Text:="Cliente", Width:=90 'Cliente
        .ColumnHeaders.Add Text:="Nº Nota Fiscal", Width:=90 'Nº Nota Fiscal
        .ColumnHeaders.Add Text:="Produto", Width:=90 'Nº Nota Fiscal
    End With
    
    ' Ciclo em todas as linhas
    For X = 6 To lastRow
        'PREENCHENDO O LISTVIEW
        Set itens = Me.ListView1.ListItems.Add(, , ws.Cells(X, 1).Value) 'Data de Lçto
            itens.SubItems(1) = ws.Cells(X, 2).Value 'Safra
            itens.SubItems(2) = ws.Cells(X, 13).Value 'Cliente
            itens.SubItems(3) = ws.Cells(X, 3).Value 'Nº Nota Fiscal
            itens.SubItems(4) = ws.Cells(X, 15).Value 'Produto
            
    Next
End Sub

strong

26-01-2017 18:38:24

Queria aproveitar o post e pedir ajuda ao pessoal, teria como me ajudar com uma planilha minha com listbox, ou listview