Selecionar células preenchidas sem pular vazias (RESOLVIDO)

Erikson

23-06-2012 12:13:39

Bom dia Pessoal,
Preciso de uma macro que selecione de uma determinada linha até a ultima linha que contenha dados, porem se nesse intervalo houver linhas vazias, a macro deve conciderar e manter a seleção da determinada linha até a ultima que conter dados, ficando assim uma única seleção.

Pesquisei e o maximo que consegui foi esse código:

Código: Selecionar todos

Sub Selecionar()
    Dim Intervalo As Range
   
    Set Intervalo = [B8:C5000].SpecialCells(xlTextValues)
    Intervalo.Select
    Selection.Copy
End Sub
Porem o código acima termina a seleção quando há um linha vázia e começa outra seleção a partir da proxima que conter dados, criando várias seleções.

webmaster

28-06-2012 20:26:49

Talvez esse código ajuda, mas ele considera a última célula selecionada considerando todas as colunas:

Código: Selecionar todos

Sub Seleciona()
ActiveSheet.Range(ActiveSheet.Cells(1, 1), ActiveSheet.Cells(ActiveSheet.UsedRange.Rows.Count, 1)).Select
End Sub
Abraços

JValq

28-06-2012 22:10:27

Boa noite,

Pelo que entendi, o seu código pode ser alterado para ficar assim:

Código: Selecionar todos

Sub Selecionar()
    Dim Intervalo As Range
   
    Set Intervalo = Range("B8:C" & [B8:C5000].SpecialCells(xlCellTypeLastCell).Row)
    Intervalo.Select
    Selection.Copy
End Sub
Eu utilizaria o mesmo código de forma mais "enxuta":

Código: Selecionar todos

Sub Selecionar()
    Range("B8:C" & [B8:C5000].SpecialCells(xlCellTypeLastCell).Row).Select
End Sub
Uma outra forma, com uma sutil diferença:

Código: Selecionar todos

Sub Selecionar()
    Range(Cells(8, 2), Cells([B8:C5000].SpecialCells(xlCellTypeLastCell).Row, [B8:C5000].SpecialCells(xlCellTypeLastCell).Column)).Select
End Sub
Na última opção, se o último valor preenchido estiver na coluna "B", não vai haver seleção de nenhum valor na coluna "C".

Abraço

Erikson

29-06-2012 01:54:53

Obrigado pela ajuda pessoal, mas a solução veio de um colega de outro forum. O código que atendeu meu desejo foi esse:

Código: Selecionar todos

Sub Selecionar()
    Dim lRowLast As Long
   
    lRowLast = WorksheetFunction.Max( _
      RowLast(Columns("B")), _
      RowLast(Columns("C")))
   
    Range("B8:C" & lRowLast).Select
End Sub

Function RowLast(rng As Range) As Long
    'Retorna o valor da última linha povoada do intervalo rng
    With rng
        On Error Resume Next
        RowLast = .Find(What:="*" _
          , After:=.Cells(1) _
          , SearchDirection:=xlPrevious _
          , SearchOrder:=xlByColumns _
          , LookIn:=xlFormulas).Row
        If RowLast = 0 Then RowLast = rng.Cells(1).Row
    End With
End Function

joseA

29-06-2012 12:08:11

Pelo que testei, a instrução que o nosso amigo JValq passou faz o mesmo que a aolução que vc encontrou e é bem mais simples...