Verificar conexão com Internet

pedrobb

25-07-2012 15:49:10

Para verificar conexão com a Internet, Tentei usar a função abaixo:

Private Declare Function InternetGetConnectedStateEx Lib "wininet.dll" _
(ByRef lpdwFlags As Long, _
ByVal lpszConnectionName As String, _
ByVal dwNameLen As Integer, _
ByVal dwReserved As Long) _
As Long

Dim sConnType As String * 255

Sub TesteConexaoInternet()
Dim Ret As Long
Ret = InternetGetConnectedStateEx(Ret, sConnType, 254, 0)
If Ret = 1 Then
MsgBox "Você está conectado a Internet via " & sConnType, vbInformation
Else
MsgBox "Você não está conectado a Internet", vbInformation
End If
End Sub

Mas uso Windows 7 - 64 bits. e dá erro pedindo atualização para 64 bits.
Alguem pode ajudar?
Grato,
Pedro

CavalheiroCambará

18-02-2017 12:49:06

Este é o código. Personalize a vontade no Sub main().

Option Explicit

#If Win64 Then
Public Flg As LongPtr
Public Declare PtrSafe Function InternetGetConnectedState _
Lib "wininet.dll" (lpdwFlags As LongPtr, _
ByVal dwReserved As Long) As Boolean
#Else
Public Flg As Long
Public Declare Function InternetGetConnectedState _
Lib "wininet.dll" (lpdwFlags As Long, _
ByVal dwReserved As Long) As Boolean
#End If

Private Const INTERNET_CONNECTION_MODEM As Long = &H1
Private Const INTERNET_CONNECTION_LAN As Long = &H2
Private Const INTERNET_CONNECTION_PROXY As Long = &H4
Private Const INTERNET_CONNECTION_OFFLINE As Long = &H20

Function IsInternetConnected() As Boolean
Dim R As Long

R = InternetGetConnectedState(Flg, 0&)

If Flg >= INTERNET_CONNECTION_OFFLINE Then
Debug.Print "INTERNET_CONNECTION_OFFLINE"
End If

If CBool(R) Then
IsInternetConnected = True
Else
IsInternetConnected = False
End If
End Function

Sub main()
Dim mssg As String
If IsInternetConnected Then
mssg = "Connected"
Else
mssg = "Not connected"
End If
MsgBox mssg
End Sub

pedrobb

08-05-2017 21:36:06

CavalheiroCambará,
Perfeito.
Muito Obrigado!
Pedro