Suplemento VBA

PRMPOKER

30-01-2013 19:13:28

Galera, recebi uma dúvida de um internauta e não soube responder:
Como acessar uma Sub, que está dentro de um SUPLEMENTO, chamando por um BUTTON?
Tentei de tudo aqui e não consegui.
Alguém me ajuda?

No anexo tem a plan e o .xla

Obrigado.

Abraços.

PRMPOKER

31-01-2013 01:56:03

Boa noite galera....
Ninguém?
Só preciso saber se é possível chamar uma SUB de um .xla através de um BUTTON...
Abração.

Mauro Coutinho

31-01-2013 02:37:33

PRMPOKER escreveu:Boa noite galera....
Ninguém?
Só preciso saber se é possível chamar uma SUB de um .xla através de um BUTTON...
Abração.
Desde que instale o suplemento (AddIn) é possivel utiliza-lo, de uma olhada em alguns links de como proceder :
Installing An Add-In
http://www.cpearson.com/excel/installinganxla.aspx

Microsoft Excel VBA Macros. How to Create an Excel Add-in For Them
http://www.ozgrid.com/VBA/excel-add-in-create.htm

Can I install an add-in using VBA
http://www.mrexcel.com/forum/excel-ques ... tions.html

[]s

PRMPOKER

31-01-2013 11:49:01

Bom dia Coutinho, muito obrigado pela resposta.
Conteúdo muito bom, mas essa parte estava dominada.
Na verdade o que faltava era adicionar a REFERÊNCIA do .XLA para poder desfrutar de suas funcionalidades!
Feito isso, tudo resolvido.
Como é bom aprender, hehehehe...
Muitíssimo obrigado.

PRMPOKER

31-01-2013 11:53:56

Pessoal, não sei como colocar "RESOLVIDO" no título do tópico, comofas?
Abraços.

PRMPOKER

31-01-2013 18:24:56

Boa tarde Galera!
Caso posso interessar a alguém, desenvolvi uma maneira de fazer a referência programaticamente, facilitando o processo.

Um grande abraço.

Paulinho Monteiro.

Newton

01-02-2013 23:38:26

PRMPOKER escreveu:Galera, recebi uma dúvida de um internauta e não soube responder:
Como acessar uma Sub, que está dentro de um SUPLEMENTO, chamando por um BUTTON?
Tentei de tudo aqui e não consegui.
Alguém me ajuda?

No anexo tem a plan e o .xla

Obrigado.

Abraços.
Você pode usar um Módulo (normal) para instanciar uma classe do suplemento externo, que te permitirá acessar as propriedades/métodos públicos dela.

Por exemplo, para quem quiser fazer um teste:

Crie um módulo de Classe e altere o nome para ClasseXLA.

Nesse módulo de classe coloque o seguinte código:

Código: Selecionar todos

Private strNome As String

Public Property Get Nome() As String
    Nome = strNome
End Property

Public Property Let Nome(ByVal Argumento As String)
    strNome = Argumento
End Property
Agora crie um Módulo normal e dê o nome de ModuloXLA e coloque esse código:

Código: Selecionar todos

Public Function InstanciarClasse() As ClasseXLA
    Set InstanciarClasse = New ClasseXLA
End Function
Altere o nome do projeto para ProjetoXLA e salve o arquivo com a extensão XLA.

Feche o arquivo.

Agora abra uma planilha em branco e vá no editor do VBA e abra o suplmento da seguinte forma,

Ferramentas > Referência > Procurar (altere o tipo de arquivo para 'Todos os arquivos').

Após escolher o arquivo. Crie um módulo na planilha e coloque o seguinte código:

Código: Selecionar todos

Dim ProjetoExterno As ProjetoXLA.ClasseXLA

Sub teste()

Set ProjetoExterno = ProjetoXLA.InstanciarClasse
    
    ProjetoExterno.Nome = "Teste"
    MsgBox ProjetoExterno.Nome
    
End Sub
Agora qualquer propriedade/método público pode ser acessado pelo arquivo externo.

PRMPOKER

06-02-2013 12:14:45

Grande newton, muito bom também...
Resolvi apenas carregando o suplemento e em seguida, chamando a referência programaticamente:

Option Explicit

Public Sub ChecaReferencias()

Dim mensagem As String
'Faz a referência ao projeto VBA
Dim vbProj As VBProject
'A referencia em si
Dim chkRef As Reference

'Seta a variável para o projeto da pasta de trabalho ativa.
Set vbProj = ActiveWorkbook.VBProject

'Checa as referências selecionadas (veja na caixa de diálogo Referências)
For Each chkRef In vbProj.References
'monta a string que conterá o nome de todas as referências
mensagem = mensagem & "Nome: " & chkRef.Name & " - GUID: " & chkRef.GUID & " - Major: " & chkRef.Major & " - Minor: " & chkRef.Minor & Chr(13)
Next
'Mostra a mensagem com o nome das referência selecionadas
MsgBox mensagem
End Sub

Public Sub AdicionaReferencia()

'Faz a referência ao projeto VBA
Dim vbProj As VBProject
'A referencia em si
Dim chkRef As Reference
Dim numRef As String

'Suprimir erros para tratá-los posteriormente
On Error Resume Next

'Seta a variável para o projeto da pasta de trabalho ativa.
Set vbProj = ActiveWorkbook.VBProject

numRef = 1

For Each chkRef In vbProj.References

'MsgBox ("Referência " & chkRef.Name & " já está adicionada")

'Verifica se a referência existe:
If chkRef.Name = "bpf.xla" Then
Exit For
Else
'Adiciona a referência
vbProj.References.AddFromFile ("bpf.xla")

'Counter para controlar a passagem pelo laço apenas uma vez
numRef = numRef + 1

If numRef > 1 Then
Exit For
End If

End If

Next

'Em caso de erro:
Select Case Err.Number

Case Is = 32813
'A referência já estava habilitada
MsgBox "A referência já está habilitada." _
, vbInformation _
, "Informação"
Case Is = vbNullString
'A referência foi adicionada com sucesso
MsgBox "Referência Plugin adicionada com sucesso!" _
, vbInformation _
, "Informação"
Case Else
'Um erro desconhecido foi encontrado
MsgBox "Um erro foi encontrado " & vbNewLine _
& "ao se tentar adicionar a referência." _
, vbCritical _
, "Error!"
End Select

On Error GoTo 0


End Sub

Public Sub RemoveReferencia()

'Faz a referência ao projeto VBA
Dim vbProj As VBProject
'A referencia em si
Dim chkRef As Reference

'Seta a variável para o projeto da pasta de trabalho ativa.
Set vbProj = ActiveWorkbook.VBProject

For Each chkRef In vbProj.References
'Verifica se a referência é do Word:
If chkRef.Name = "Plugin" Then
'Se for, remove
vbProj.References.Remove chkRef
End If
Next

End Sub
Desta forma consigo verificar se a mesma já existe, senão, adiciono-a.
Desta forma funcionou perfeitamente.
Obrigado.