Listar documentos via VBA

vhdocavaco

23-05-2013 13:56:44

Pessoal,

Bom dia,

Tentei adaptar o código do http://www.tomasvasquez.com.br/blog/mic ... -diretorio para VBA do Excel sem sucesso, alguém pode compartilhar um que funcione eu passando o path (caminho) ou um arquivo de exemplo para eu ver sua estrutura

Na verdade meu intuito é listar o documento e algumas propriedades do mesmo (Detalhes se possível se alguém tiver pronto ajudaria muito! ;)

[]s

vhdocavaco

28-05-2013 15:44:59

Pessoal, consegui um código que lista os arquivos direto numa Plan segue:

Código: Selecionar todos

Dim iRow

Sub ListFiles()
    iRow = 11
    Call ListMyFiles(Range("C7"), Range("C8"))
End Sub

Sub ListMyFiles(mySourcePath, IncludeSubfolders)
    Set MyObject = New Scripting.FileSystemObject
    Set mySource = MyObject.GetFolder(mySourcePath)
    On Error Resume Next
    For Each MyFile In mySource.Files
        iCol = 2
        Cells(iRow, iCol).Value = MyFile.Path
        iCol = iCol + 1
        Cells(iRow, iCol).Value = MyFile.Name
        iCol = iCol + 1
        Cells(iRow, iCol).Value = MyFile.Size
        iCol = iCol + 1
        Cells(iRow, iCol).Value = MyFile.DateLastModified
        iRow = iRow + 1
    Next
    If IncludeSubfolders Then[code]
For Each mySubFolder In mySource.SubFolders
Call ListMyFiles(mySubFolder.Path, True)
Next
End If
End Sub [/code]

Na C7 você especifica o caminho e na C8 verdadeiro/falso para listar subpastas

Agora preciso de uma ajuda neste que lista Pastas:

Código: Selecionar todos

    Sub ListDir()
        Dim DirectoryName
        Dim Path As String
        Dim Contador As Long
        
        Contador = 0
        
        
        iRow = 11
        
        Path = "c:\temp\"
     
        DirectoryName = Dir(Path, vbDirectory)
                
        Do Until DirectoryName = ""
            If DirectoryName <> "." And DirectoryName <> ".." Then
                Contador = Contador + 1
                Debug.Print DirectoryName
                If (GetAttr(Path & DirectoryName) And vbDirectory) = vbDirectory Then
                End If
            End If
            iCol = 2
            Cells(iRow, iCol).Value = DirectoryName
            iCol = iCol + 1
            DirectoryName = Dir
        Loop
            Debug.Print Contador
    End Sub 
Eu consigo ver as pastas no Debug mas queria que gravasse nas celulas alguém pode me dar uma luz?

Grato e []s

vsPacheco

28-05-2013 16:25:38

Ola,
Não vou inserir outro codigo para não confundir
Vou seguir nesse mesmo com algumas alteraçoes que
vai fazer ele funcionar, assim creio que vai conseguir assimilar melhor
pois pelo que eu vi, vc gosta de aprender ( somos 2 )
...

o 1º code nao olhei pois vc disse q esta OK,
o 2º code é o seu problema correto?
Baseado nisso, olhei ele, mas não compreendi do pq
Contador = 0
iRow = 11
iCol = 2
iCol = iCol + 1

pois na linha 23 esta assim
Cells(iRow, iCol).Value = DirectoryName
esta Linha que vai Escrever na sua Plan, Então;
Se sempre iCol vai ser 2 já deixe 2 ali
Cells(iRow, 2).Value = DirectoryName

Outro Detalhe é o iRow, ele esta sempre como 11
Mude iRow para o Contador
e tbm Contador = 0 para Contador = 1
Assim vai ficar os arquivos LISTADOS um ABAIXO do OUTRO

Da maneira como estava ele Escrevia Sempre na Mesma Coluna e Sempre na Mesma linha
Creio que seria essa sua duvida, espero ter ajudado.

vhdocavaco

29-05-2013 12:08:27

vsPacheco

Fiz as alterações sugeridas mas ainda não rolou, as pastas ainda são exibidas somente no Debug faça um teste crie uns 3 diretórios na pasta "c:\temp\" e execute o código

A proposta total é (depois eu posto aqui pra quem quiser tem um template):

- Listar os diretórios
- Usar a função Indireto para criar uma lista de Seleção Dinâmica
- Usar o codigo que lista arquivos deste diretório para baseado na Seleção

Grato pelo apoio ;)

vhdocavaco

29-05-2013 12:27:31

Pessoal,

Consegui melhorar o código e fazer escrever na Planilha veja só como ficou:

Código: Selecionar todos

    Sub ListDir()
        Dim DirectoryName
        Dim Path As String
        Dim Contador As Long
        
        Contador = 1
        
        
        iRow = 1
        iCol = 1
        
        Path = "c:\temp\"
     
        DirectoryName = Dir(Path, vbDirectory)
                
        Do Until DirectoryName = ""
            
            If DirectoryName <> "." And DirectoryName <> ".." Then
                Debug.Print DirectoryName
                If (GetAttr(Path & DirectoryName) And vbDirectory) = vbDirectory Then
                End If
            End If
            Contador = Contador + 1
            Cells(iRow, iCol).Value = DirectoryName
            iRow = iRow + 1
            DirectoryName = Dir
        Loop
            Debug.Print Contador
    End Sub
Agora o que preciso saber é como faço ele mostrar a partir da terceira pasta

Exemplo tenho lá no Temp as pastas DIR1, DIR2, DIR3, DIR4

Executando o script vai ficar dessa forma na Plan

.
..
DIR1
DIR2
DIR3
DIR4

Eu gostaria que ".", ".." e "DIR2" não fossem exibidos,

Alguma luz?

[]s

vsPacheco

29-05-2013 13:37:13

Bah ! desculpe vhdocavaco,
mas nao entendi o que voce quer fazer,
Porem para compensar vou ajudar no que "eu acho" que entendi !!! eheheh

No seu primeiro post relatou que listaria os Diretorios um abaixo do outro na Coluna 2 iniciando na linha 11
Esse Code Funciona, e lista APENAS os diretorios a partir da linha 11

Código: Selecionar todos

Sub ListDir()
Dim DirectoryName
Dim Path As String
Dim Contador As Long
        
Contador = 11
Path = "C:\Temp\"
DirectoryName = Dir(Path, vbDirectory)
                
Do Until DirectoryName = ""
    If DirectoryName <> "." And DirectoryName <> ".." Then
        If (GetAttr(Path & DirectoryName) And vbDirectory) = vbDirectory Then
            Cells(Contador, 2) = DirectoryName
            Contador = Contador + 1
        End If
    End If
    DirectoryName = Dir
Loop
End Sub
...
Esse Code Funciona, faz a mesma coisa que o Code acima porem com uma ADD,
ele Não Lista o Diretorio "DIR2"

Código: Selecionar todos

Sub ListDir()
Dim DirectoryName
Dim Path As String
Dim Contador As Long
        
Contador = 11
Path = "C:\Temp\"
DirectoryName = Dir(Path, vbDirectory)
                
Do Until DirectoryName = ""
    If DirectoryName <> "." And DirectoryName <> ".." Then
        If (GetAttr(Path & DirectoryName) And vbDirectory) = vbDirectory And DirectoryName <> "DIR2" Then
            Cells(Contador, 2) = DirectoryName
            Contador = Contador + 1
        End If
    End If
    DirectoryName = Dir
Loop
End Sub
...
Então,
a Linha 6 é onde informa a LINHA INICIAL da LISTA de DIRETORIOS
a Linha 12 é onde informa "TBM" onde será IGNORADO um Diretorio da LISTA
a Linha 13 é onde informa QUAL COLUNA será MANTIDA A LISTA

Não pude lhe ajudar muito mas espero que isto lhe ajude em ALGO.