Função SE após dados de uma TextBox [RESOLVIDO]

Dianderson

16-03-2014 15:13:24

Ola Galera,
Bom Estou em um empenho tentando aprender na marra a fazer um VBA para a empresa que trabalho,
Está legal e bem simples porem me deparei com um problema,
preencho um "Userform" e ao clicar em "Lançar (Botao)" ele copia as informações das Textbox para minha planilha que chamei de "Caixa".
onde na planilha "Caixa" eu tenho alguns formulários (SE, formatação condicional, etc).
Quando "exporto" esses dados da "Userform" para minha planilha a data que vai nao aceita a formula SE,
É como se a celula que esta com a DATA que veio da Textbox tivesse bloqueado esta dd/mm/aaaa mais nao permite que a função SE atue.

Segue a codificação caso precise de mais alguma coisa favor solicita.
Obrigado desde ja.

Private Sub ComboBox1_Enter()

Me.ComboBox1.List = Application.WorksheetFunction.Transpose(Plan1.Range("H2:H100"))

End Sub

Private Sub ComboBox2_Enter()

Me.ComboBox2.List = Application.WorksheetFunction.Transpose(Plan1.Range("k2:k100"))

End Sub

Private Sub ComboBox3_Enter()

Me.ComboBox3.List = Application.WorksheetFunction.Transpose(Plan1.Range("B2:B100"))

End Sub

Private Sub ComboBox4_Enter()

Me.ComboBox4.List = Application.WorksheetFunction.Transpose(Plan1.Range("E2:E100"))

End Sub

Private Sub CommandButton1_Click()

Dim iRow As Long
Dim ws As Worksheet
Set ws = Worksheets("Fluxo_de_Caixa")


iRow = ws.Cells.Find(What:="a", SearchOrder:=xlByRows, _
SearchDirection:=xlPrevious, LookIn:=xlValues).Row + 1

'copia os dados para as celulas
ws.Cells(iRow, 7).Value = Me.TextBox1.Value 'Razão Social
ws.Cells(iRow, 8).Value = Me.TextBox2.Value 'Nota Fisca
ws.Cells(iRow, 14).Value = Me.TextBox3.Text 'Data da Emissão
ws.Cells(iRow, 2).Value = Me.TextBox9.Text 'Data do Vencimento
ws.Cells(iRow, 5).Value = Me.TextBox10.Value 'Valor

'Limpa os campos TextBox para inserir novos dados
Me.TextBox1.Value = ""
Me.TextBox2.Value = ""
Me.TextBox3.Value = ""
Me.TextBox9.Value = ""
Me.TextBox10.Value = ""

ActiveWorkbook.Save

End Sub

Private Sub CommandButton2_Click()

ActiveWorkbook.Save
Unload Me

End Sub

Private Sub textbox3_KeyPress(ByVal KeyAscii As MSForms.ReturnInteger)
'Limita a Qde de caracteres
TextBox3.MaxLength = 10

'para permitir que apenas números sejam digitados
If KeyAscii < Asc("0") Or KeyAscii > Asc("9") Then
KeyAscii = 0
End If

End Sub

Private Sub textbox3_Change()
'Formata : dd/mm/aaaa
If Len(TextBox3) = 2 Or Len(TextBox3) = 5 Then
TextBox3.Text = TextBox3.Text & "/"
SendKeys "{End}", True
End If
End Sub

Private Sub textbox9_KeyPress(ByVal KeyAscii As MSForms.ReturnInteger)
'Limita a Qde de caracteres
TextBox9.MaxLength = 10

'para permitir que apenas números sejam digitados
If KeyAscii < Asc("0") Or KeyAscii > Asc("9") Then
KeyAscii = 0
End If

End Sub

Private Sub textbox9_Change()
'Formata : dd/mm/aaaa
If Len(TextBox9) = 2 Or Len(TextBox9) = 5 Then
TextBox9.Text = TextBox9.Text & "/"
SendKeys "{End}", True
End If
End Sub


Irei precisar de outra planilha mais complexa um pouco.
se alguem fizer comercialmente favor me informar.

Novamente Obrigado.

Mauro Coutinho

16-03-2014 15:30:54

Dianderson, a Função SE não reconhece a Data devido ao Valor gerado por TextBox serem Texto e não numericos, neste caso temos de converter o Valor para Data, então troque as linhas :

ws.Cells(iRow, 14).Value = Me.TextBox3.Text 'Data da Emissão
ws.Cells(iRow, 2).Value = Me.TextBox9.Text 'Data do Vencimento


por :
ws.Cells(iRow, 14).Value = Me.CDate(TextBox3.Value) 'Data da Emissão
ws.Cells(iRow, 2).Value = Me.CDate(TextBox9.Value) 'Data do Vencimento

Dianderson

16-03-2014 18:14:55

Poxa não funcionou não.
Ta dando um erro.

Erro de Compilação:
Método ou membro de dados não encontrado

:(

Mauro Coutinho

16-03-2014 18:19:26

Quando da o erro é mostrado alguma linha em amarelo ? Pois a unica alteração que fiz é a formatação e se a rotina sem esta modificação não dava erro, alguma coisa está diferente. Revise os nomes dos controles, se não conseguir só anexando um modelo compactado para uma melhor analise.

Editado : Va no Menu na Janela do VBA - Ferramemtas / Referencias se na caixa que abrir tem alguma linha escrito AUSENTE, se tiver desabilite.

[]s

Dianderson

16-03-2014 18:20:12

Muito Obrigado.

Só mudei uma coisa e funcionou legal.

Ficou assim.

ws.Cells(iRow, 14).Value = CDate(Me.TextBox3.Value) 'Data da Emissão
ws.Cells(iRow, 2).Value = CDate(Me.TextBox9.Value) 'Data do Vencimento

Mauro Coutinho

16-03-2014 18:22:57

Correto, eu havia colocado o CDATE no local errado, valeu.

[]s