NOME DE ARQUIVO [RESOLVIDO]

HUGO SOUZA

10-09-2014 18:04:42

OLÁ!
QUERO ENCONTRAR QUAISQUER ARQUIVOS QUE CONTENHA UMA PALAVRA NO NOME.

COMO É A SINTAXE?


EXEMPLO: * PALAVRA *

NÃO SEI USAR O CARACTER CURINGA.

Reinaldo

10-09-2014 19:23:08

Em principio pode ser utilizado o caracter coringa ao lado da palavra "*palavra*", porem dependerá tambem de como está "procurando" o arquivo e se o retorno esperado é apenas um ou mais arquivos.

HUGO SOUZA

10-09-2014 21:12:25

A Sub coleta arquivo por arquivo.

O que eu queria era saber se o nome do arquivo contém a palavra MATRÍCULA e se é do tipo PDF.

Pode ajudar, por favor?

HUGO SOUZA

11-09-2014 12:06:28

Esta é a rotina que peguei na net:

Sub ListaArquivos()

'Se quiser utilizar Early Binding, adicione a biblioteca Microsoft Scripting Runtime

'Mude esse valor para buscar outro caminho:
Const strCaminho As String = "G:\MATRICULAS"

'Declaração de variáveis:
Dim fso As Object 'Scripting.FileSystemObject
Dim fld As Object 'Scripting.Folder
Dim fl As Object 'Scripting.File
Dim n As Long

'Aqui é criado o objeto que comunica com as pastas do computador
Set fso = CreateObject("Scripting.FileSystemObject")

'Esse objeto executa um método do FileSystemObject
'para buscar atribuir à variável fld uma pasta
Set fld = fso.GetFolder(strCaminho)

With ActiveSheet
'Limpa e formata a Planilha ativa:
.Cells.Delete
.Range("A1:D1") = Array("Caminho", "Nome", "Tamanho", "Modificado em:")
n = 2

'Laço em cada arquivo do caminho desejado:

For Each fl In fld.Files
'If fl = Dir(fl & "*.dwg*") Then



.Cells(n, "A") = fl.Path 'Caminho completo
.Cells(n, "B") = fl.Name 'Nome
.Cells(n, "C") = fl.Size 'Tamanho
.Cells(n, "D") = fl.DateLastModified 'Data de Modificação
n = n + 1
'Note que você poderia adicionar outras propriedades dos arquivos em outras colunas
'Nesse exemplo foram mostrados como visualizar apenas quatro de muitas propriedades de um arquivo


Next fl
End With

Cells.Select
Cells.EntireColumn.AutoFit
Range("A1").Select
End Sub

Reinaldo

11-09-2014 15:38:58

Experimente assim:

Código: Selecionar todos

Sub ListaArquivos()

'Se quiser utilizar Early Binding, adicione a biblioteca Microsoft Scripting Runtime

'Mude esse valor para buscar outro caminho:
mpat = ThisWorkbook.Path
Const strCaminho As String = "G:\MATRICULAS"

'Declaração de variáveis:
Dim fso As Object 'Scripting.FileSystemObject
Dim fld As Object 'Scripting.Folder
Dim fl As Object 'Scripting.File
Dim n As Long

  'Aqui é criado o objeto que comunica com as pastas do computador
Set fso = CreateObject("Scripting.FileSystemObject")

'Esse objeto executa um método do FileSystemObject
'para buscar atribuir à variável fld uma pasta
Set fld = fso.GetFolder(strCaminho)

With ActiveSheet
'Limpa e formata a Planilha ativa:
.Cells.Delete
.Range("A1:D1") = Array("Caminho", "Nome", "Tamanho", "Modificado em:")
n = 2

'Laço em cada arquivo do caminho desejado:

For Each fl In fld.Files
If fl.Name Like "*MATRÍCULA*" And Right(fl.Name, 3) = "pdf" Then
'If fl = Dir(fl & "*.dwg*") Then



.Cells(n, "A") = fl.Path 'Caminho completo
.Cells(n, "B") = fl.Name 'Nome
.Cells(n, "C") = fl.Size 'Tamanho
.Cells(n, "D") = fl.DateLastModified 'Data de Modificação
n = n + 1
'Note que você poderia adicionar outras propriedades dos arquivos em outras colunas
'Nesse exemplo foram mostrados como visualizar apenas quatro de muitas propriedades de um arquivo
End If

Next fl

End With

Cells.Select
Cells.EntireColumn.AutoFit
Range("A1").Select
End Sub

HUGO SOUZA

11-09-2014 21:09:08

Muuuuuuuuito obrigado!!!