Integração VBA com IE para Download

afbergman

11-04-2015 14:19:21

Bom dia Pessoal,

Sei que existem outros topicos com esse assunto, porem, estao um pouco confusos pois tem muitos comentarios diferentes.
Gostaria de uma ajuda com relação a um projeto. Estou querendo criar um formulário com um botao que ao clicar faça o download de uma planilha nesse link: https://sistemas.anac.gov.br/SACI/naore ... adas25.asp
Esse link já faz diretamente o download de uma planilha excel. Depois desse processo precisaria extrair alguns dados de colunas especificas. Só que preciso filtrar informações da coluna "origem" e "destino", no caso os voos com saindo e chegando no Aeroporto do Galeao.

Depois essas informações seriam exibidas numa msgbox.

Alguem consegue me ajudar???
Segue o anexo do modelo do formulario.

Abraços.

afbergman

15-04-2015 14:16:36

Alguem poderia me ajudar????

skuma

17-04-2015 18:01:09

Amigo, no caso do download talvez eu consiga te ajudar. Segue abaixo um código já com o link que você disponibilizou:

No seu botão você chama a função Baixar:

Código: Selecionar todos

Call Baixar
Crie um módulo e coloque este código:

Código: Selecionar todos

#If VBA7 Then
    Public Declare Function URLDownloadToFile Lib "urlmon" Alias "URLDownloadToFileA" (ByVal pCaller As LongPtr _
      , ByVal szURL As String _
      , ByVal szFileName As String _
      , ByVal dwReserved As LongPtr _
    , ByVal lpfnCB As LongPtr) As Long
#Else
    Public Declare Function URLDownloadToFile Lib "urlmon" Alias "URLDownloadToFileA" (ByVal pCaller As Long _
      , ByVal szURL As String _
      , ByVal szFileName As String _
      , ByVal dwReserved As Long _
    , ByVal lpfnCB As Long) As Long
#End If

Public Sub Baixar()
    'Declaração de variáveis
    Dim sURL As String
    Dim sDestino As String
    Dim blSucesso As Boolean
    
    'Altere as informações abaixo de acordo com sua necessidade
    sURL = "https://sistemas.anac.gov.br/SACI/naoregular/_relatorios/OperacoesAprovadas25.asp "
    sDestino = Application.GetSaveAsFilename("NOME DO ARQUIVO.XLSX")

    If sDestino = "Falso" Or sDestino = "False" Then
    Exit Sub
    End If
        
    'Baixa o arquivo da internet
    blSucesso = DownloadArquivo(sURL, sDestino)
    If blSucesso Then
        MsgBox "O arquivo foi salvo com sucesso em:" & sDestino _
          , vbInformation _
          , "Informação"
    Else
        MsgBox "O arquivo não está disponível para download." _
          , vbCritical _
          , "Erro - Download indisponível"
    End If
End Sub

Private Function DownloadArquivo(sURL As String, sDestino As String) As Boolean
    Dim l As Long
    l = URLDownloadToFile(0, sURL, sDestino, 0, 0)
    If l = 0 Then DownloadArquivo = True
End Function
Ve se isso ajuda.
Abs