Criar nova aba e nomeando pelo InputBox [RESOLVIDO]

costaribeiro

10-07-2015 13:40:40

:) Olá pessoal.

Bom dia.

Estou criando um planilha de controle de receita e despesas para minha mãe (que é idosa) e tem que ser bem simples. Assim, quero que ela possa criar (após a guia "MENU") uma nova aba, com base num modelo de "planilha de caixa" armazenado num determinado diretório, consequentemente nomeando-a por meio de InputBox.
Se compliquei, desculpe... kkk

Vi este código no site http://www.microsoftexcel.com.br/index. ... encia.html, mas ele não cria a nova aba após uma "guia principal" (no caso "MENU"):

Código: Selecionar todos

Sub Adiciona_novo_nome_planiha2()
    Dim PlanilhaAtual As String
    PlanilhaAtual = ActiveSheet.Name

    'Adiciona nova planilha
    Sheets.Add

    'verificando se o nome é valido
    On Error Resume Next

     'Receba o novo nome
     ActiveSheet.Name = InputBox("Nome para nova folha de planilha?")

    'Pergunta novamente se o nome é um nome válido
    Do Until Err.Number = 0
        Err.Clear
        ActiveSheet.Name = InputBox("Tente novamente!" _
          & vbCrLf & "Nome de planilha, esta planilha já existe" _
          & vbCrLf & "Por favor digite outro nome para nova planilha")
    Loop
    On Error GoTo 0

'Volte para onde você começou
'Não é necessário se você não quer voltar
'para onde você começou, mas quer ficar
'sobre a nova planilha

Sheets(PlanilhaAtual).Select

End Sub

Agradeço se ajudarem.

Forte abraço. :geek:

netocasaroli

10-07-2015 14:31:21

Tente este código:

Código: Selecionar todos

Sub NovaPlanilha()

    Dim newPlan As Worksheet
    
    Set newPlan = Worksheets.Add
    
    With newPlan
        .Name = InputBox("Nome para nova folha de planilha?")
        .Move After:=Sheets("MENU")
    End With
    
    Set newPlan = Nothing
    
End Sub

costaribeiro

10-07-2015 18:46:30

Caríssimo netocasaroli,

Obrigado pela resposta.

Ficou muito bom. Mas, para continuar inserindo nova aba, seguinte àquela que foi criada, tem como fazer?. P.ex.: após a aba "MENU", criou-se "JANEIRO", então para criar outra "FEVEREIRO" (ou qualquer outro nome) e que não fique após "MENU", e sim após à anterior criada ("JANEIRO", p.ex.), como deve ser feito?

|MENU|JANEIRO|FEVEREIRO|...→

Não sei se fui claro... :shock:

Abração!

netocasaroli

10-07-2015 19:00:03

A parte do código que define após qual planilha a nova ficará é: .Move After:=Sheets("MENU")

É só substituir o nome MENU pelo nome da planilha após a qual a nova planilha deverá ficar. Se for um caso pontual, faça isso e estará tudo resolvido. Caso queira automatizar esse processo, use o código abaixo:

Código: Selecionar todos

Sub NovaPlanilha()

    Dim newPlan As Worksheet
    
    Set newPlan = Worksheets.Add
    
    With newPlan
        On Error GoTo Err_Handler1
        .Name = InputBox("Nome para nova folha de planilha?")
        On Error GoTo Err_Handler2
        .Move After:=Sheets(InputBox("Após qual planilha a nova será inserida?"))
    End With
    
    On Error GoTo 0
    
    Set newPlan = Nothing
    
    Exit Sub
    
Err_Handler1:
    MsgBox "Já existe uma planilha com este nome. Informe novamente.", vbOKOnly + vbCritical
    Resume
    
Err_Handler2:
    MsgBox "Essa planilha não existe. Informe novamente.", vbOKOnly + vbCritical
    Resume
    
End Sub

costaribeiro

10-07-2015 19:11:29

Netocasaroli,

Ficou perfeito. Valeu fera! :D

Se não for abusar... E para copiar o conteúdo de uma planilha "padrão" (formatação e tudo) para a aba (planilha) nova? Pretendo com isso que, ao criar uma nova (aba/planilha), seja copiado a estrutura de uma planilha padrão (p.ex.: "BASE"), na qual está a estrutura do "caixa" para contabilização no mês seguinte, por exemplo.

Abração!

netocasaroli

10-07-2015 20:06:57

Vamos lá... E o nosso código só crescendo... kkk... Tenta aí:

Código: Selecionar todos

Sub NovaPlanilha()

    Dim newPlan As Worksheet
    Dim basePlan As String
    
    If MsgBox("Deseja utilizar alguma planilha como base para a nova?", vbInformation + vbYesNo) = vbYes Then
        On Error GoTo Err_Handler3
        basePlan = InputBox("Qual planilha servirá de base para a nova?")
        If basePlan = vbNullString Then Exit Sub
        Worksheets(basePlan).Copy Before:=Sheets(1)
        With Sheets(1)
            On Error GoTo Err_Handler1
            .Name = InputBox("Nome para nova folha de planilha?")
            On Error GoTo Err_Handler2
            .Move After:=Sheets(InputBox("Após qual planilha a nova será inserida?"))
        End With
    On Error GoTo 0
    Else
        Set newPlan = Worksheets.Add
        With newPlan
            On Error GoTo Err_Handler1
            .Name = InputBox("Nome para nova folha de planilha?")
            On Error GoTo Err_Handler2
            .Move After:=Sheets(InputBox("Após qual planilha a nova será inserida?"))
        End With
    
    End If
    
    On Error GoTo 0
    
    Set newPlan = Nothing
    
    Exit Sub
    
Err_Handler1:
    MsgBox "Já existe uma planilha com este nome. Informe novamente.", vbOKOnly + vbCritical
    Resume
    
Err_Handler2:
    MsgBox "Essa planilha não existe. Informe novamente.", vbOKOnly + vbCritical
    Resume
    
Err_Handler3:
    MsgBox "Essa planilha não existe. Informe novamente.", vbOKOnly + vbCritical
    basePlan = InputBox("Qual planilha servirá de base para a nova?")
    Resume
    
End Sub

messiasmbm

12-07-2015 15:37:40

Tem muita coisa pronta inclusive fiz um para uso próprio... viewtopic.php?f=23&t=3820#.VaE32bVLDi4

costaribeiro

13-07-2015 13:00:54

Galera, Valeu!!! :D

Netocasaroli, você é gênio! kkk

Obrigado Messiasmbm