Importar dados de uma planilha para outra

fabianolordelo

13-08-2015 17:38:27

Boa tarde.

Estou precisando de uma macro para importar os dados de uma planilha para outra que estejam salvas na mesma pasta.

Exemplo: Sempre que eu clicar no botão "importar dados" da planilha "DOCUMENTOS" eu consiga pesquisar, achar a planilha que quero importar e ao clicar nela, seus dados passassem para a planilha "DOCUMENTOS"

Poderiam me ajudar?

Fabio Trindade

23-08-2015 03:40:22

Boa noite, fabianolordelo

Da uma olhada nesse código.

Código: Selecionar todos

Private Sub cmdImportExcel_Click()
' import excel file

Dim importFileName As Variant
Dim importWorkbook As Workbook
Dim importSheet As Worksheet
Dim importRange As Range
       
	' show open file dialog
	importFileName = Application.GetOpenFilename(FileFilter:="Arquivo do Excel (*.xls; *.xlsx), *.xls;*.xlsx", Title:="Escolha um arquivo do Excel")
	
	' if user pressed cancel buton: exit
	If importFileName = False Then Exit Sub
	
	Application.ScreenUpdating = False
	
		 ' if user selected a excel file, open it
		 Set importWorkbook = Application.Workbooks.Open(importFileName)
		 Set importSheet = importWorkbook.Worksheets(1)

		 ' copy from import sheet
		 Set importRange = importSheet.Range( _
			 importSheet.Range("A2"), _
			 importSheet.Range("I" & importSheet.Rows.Count).End(xlUp) _
		 )
		 
		 importRange.Copy
		 
		 ' paste into Data sheet
		 SheetData.Range("A1").PasteSpecial xlValues
		 SheetData.Range("A1").PasteSpecial xlPasteFormats
		 Application.CutCopyMode = False
 
 importWorkbook.Close
       
End Sub

fcunha

06-12-2018 09:17:24

Olá, coloquei esse código acima na minha planilha, no entanto, dá erro 424 Object Required na linha DataSheet...

Alguém poderia ajudar? Sei que esse post é muito antigo, então vou ficar na espectativa de alguém ainda vir ler por aqui, obrigado.

Reinaldo

06-12-2018 10:00:03

Dificil auxiliar pela info passada. Não localizei na rotina qualquer linha com DataSheet..
Agora se refere-se ao trecho

Código: Selecionar todos

...' paste into Data sheet
		 SheetData.Range("A1").PasteSpecial xlValues
		 SheetData.Range("A1").PasteSpecial xlPasteFormats...
a referencia SheetData.Range deve ser alterada de acordo com o nome de sua planilha "recebedora" dos dados

fcunha

13-12-2018 08:40:43

Reinaldo escreveu: ↑Qui Dez 06, 2018 7:00 am Dificil auxiliar pela info passada. Não localizei na rotina qualquer linha com DataSheet..
Agora se refere-se ao trecho

Código: Selecionar todos

...' paste into Data sheet
		 SheetData.Range("A1").PasteSpecial xlValues
		 SheetData.Range("A1").PasteSpecial xlPasteFormats...
a referencia SheetData.Range deve ser alterada de acordo com o nome de sua planilha "recebedora" dos dados
Reinaldo, obrigado pelo seu comentário. Eu tentei colocar o nome da planilha, mas aí aparece um erro 9 dizendo: Subscript Out of Range.

O código que estou usando é esse (tive que tirar de Private Sub porque não estava sabendo como fazer isso funcionar):

Código: Selecionar todos

Sub cmdImportFlatALL_Click()
' import excel file

Dim importFileName As Variant
Dim importWorkbook As Workbook
Dim importSheet As Worksheet
Dim importRange As Range
       
' show open file dialog
importFileName = Application.GetOpenFilename(FileFilter:="Arquivo do Excel (*.xls; *.xlsx; *.xlsb), *.xls;*.xlsx;*.xlsb", Title:="Escolha um arquivo do Excel")

' if user pressed cancel buton: exit
If importFileName = False Then Exit Sub
Application.ScreenUpdating = False
' if user selected a excel file, open it
Set importWorkbook = Application.Workbooks.Open(importFileName)
Set importSheet = importWorkbook.Worksheets(3)
' copy from import sheet
Set importRange = importSheet.Range(importSheet.Range("A1"), importSheet.Range("AK" & importSheet.Rows.Count).End(xlUp))
importRange.Copy
 ' paste into Data sheet

    Sheets("EUR - Flat-ALL").Range("C10").PasteSpecial xlValues
    Sheets("EUR - Flat-ALL").Range("C10").PasteSpecial xlPasteFormats
Application.CutCopyMode = False
importWorkbook.Close
End Sub
Mas o que na verdade eu queria era que ao invés de eu ter que especificar exatamente qual planilha é pra ele colar, queria que ele utilizasse a planilha ativa. Até tentei usar Active.Sheets (ou qualquer coisa similar isso que encontrei pelo forum), mas também não funcionou.

Obrigado de antemão pela ajuda.

Reinaldo

13-12-2018 10:32:17

Experimente assim:

Código: Selecionar todos

Sub cmdImportFlatALL_Click()
' import excel file
Dim importFileName As Variant
Dim importWorkbook As Workbook
Dim importSheet As Worksheet
Dim importRange As Range
Dim wb As Workbook
Dim sh As Worksheet
'Determina o arquivo onde sera colado os dados
Set wb = ThisWorkbook
Set sh = wb.ActiveSheet
' show open file dialog
importFileName = Application.GetOpenFilename(FileFilter:="Arquivo do Excel (*.xls; *.xlsx; *.xlsb), *.xls;*.xlsx;*.xlsb", Title:="Escolha um arquivo do Excel")

' if user pressed cancel buton: exit
If importFileName = False Then Exit Sub
Application.ScreenUpdating = False
' if user selected a excel file, open it
Set importWorkbook = Application.Workbooks.Open(importFileName)
Set importSheet = importWorkbook.Worksheets(3)
' copy from import sheet
Set importRange = importSheet.Range(importSheet.Range("A1"), importSheet.Range("AK" & importSheet.Rows.Count).End(xlUp))
MsgBox importRange.Address
importRange.Copy
 ' paste into Data sheet
wb.Activate
sh.Range("C10").PasteSpecial xlValues
sh.Range("C10").PasteSpecial xlPasteFormats
Application.CutCopyMode = False
importWorkbook.Close
End Sub

fcunha

14-12-2018 09:29:05

Reinaldo escreveu: ↑Qui Dez 13, 2018 7:32 am Experimente assim:
...
Reinaldo, muito obrigado mesmo! Ajudou demais!!!

lnunes.eng

11-04-2019 17:06:30

boa tarde.

estou tentando usar este mesmo código, e está dando erro de subscript out of range na linha:
Set importSheet = importWorkbook.Worksheets(3)

a diferença é que vinculei o script a um botão, e o conteúdo do arquivo que eu escolhi vai para uma outra sheet, ou seja, possuo multiplas sheets dentro do meu arquivo excel.

CBPR

11-04-2021 16:50:08

lnunes.eng escreveu: ↑Qui Abr 11, 2019 2:06 pm boa tarde.

estou tentando usar este mesmo código, e está dando erro de subscript out of range na linha:
Set importSheet = importWorkbook.Worksheets(3)

a diferença é que vinculei o script a um botão, e o conteúdo do arquivo que eu escolhi vai para uma outra sheet, ou seja, possuo multiplas sheets dentro do meu arquivo excel.
-----
Utilize:
Set importSheet = importWorkbook.Worksheets(1)

Provavelmente dará certo.

anderson_brito2008

12-07-2021 13:19:36

Bom dia! Reinaldo o no caso de importa dados entre tabelas da mesma planilha. Vc teria um codigo ?

A sutiação é a seguinte: Tenho um tabela dinamica e quero enviar os info para outra tabela planilha, mais que seja de forma automatica sem precisa criar algum botão.