Relatório Resolvido

cloudrickk

11-09-2015 13:03:55

Bom dia!!
Gostaria de uma ajuda de vocês, estou com uma planilha de controle de estoque e precisava colocar um botão de relatório... nessa planilha cheguei até a inciar o relatório, só que não estou conseguindo fazer ele calcular o estoque atual e o custo médio de cada produto.
Nesse botão ele abre uma janela e só colocar o código que ele puxa as informações, só que o estoque atual não vai e nem o custo médio.
Na aba relatório eu consegui fazer com formulas para puxar o estoque atual, seria igual a formula... em questão do custo médio não consegui nem em formula e nem em VBA.
Vocês poderiam me ajudar nessa?

cloudrickk

11-09-2015 17:01:31

Boa tarde pessoal,
Acho eu não conseguir expressar a minha dúvida direito, vou postar uma planilha com apenas 2 abas... a de Registro de Inventário é onde está as informações, e a aba de Relatório é onde eu quero que apareça os resultados.
Vamos tentar ir por parte, primeiro vamos tentar fazer o macro puxar para o relatório o estoque atual do código 3.

Edcronos

11-09-2015 18:36:11

não sei se entendi
mas ve se a macro te atente

Código: Selecionar todos

Private Sub BTN_Gerar_Relatorio()
    Dim cod As Long, L2 As Long, L As Long, regO(), regD(1 To 4)

    Application.ScreenUpdating = False
    Application.Calculation = xlCalculationManual
    With Sheets("Registro de Inventário")
        regO = .Range("A2:E" & .Cells(Rows.Count, 1).End(xlUp).Row).Value2
    End With

    With Sheets("Relatório")
        For L2 = 2 To .Cells(Rows.Count, 1).End(xlUp).Row
            cod = .Cells(L2, 1).Value2
            regD(2) = 0
            For L = 1 To UBound(regO, 1)
            
                If regO(L, 1) = cod Then
                    regD(1) = regO(L, 2)
                    If regO(L, 3) = "E" Then
                        regD(2) = regD(2) + regO(L, 5)
                    Else
                        regD(2) = regD(2) - regO(L, 5)    'Qtde.
                    End If
                End If
            Next
            .Range(.Cells(L2, 2), .Cells(L2, UBound(regD) - 1)).Value2 = regD
        Next
    End With
    Application.Calculation = xlCalculationAutomatic
    Application.ScreenUpdating = True
End Sub

Sobre o custo médio vc vai ter que definir como vai ser feito o calculo
eu poderia incluir na macro se vc desse maiores detalhes
isso pq tem entrada e saída
o custo seria a soma do custo dividido pela quantidade de entrada
mas não entendi o custo médio a que vc se refere

cloudrickk

13-09-2015 14:42:46

Bom dia Edcronos,
É isso mesmo, só fiz uma modificação para ficar perfeito.
A parte de custo médio vou colocar um site que vai explicar melhor, vai ser igual o exemplo 1.
http://www.portaldeauditoria.com.br/tem ... derado.htm
Eu consegui fazer em formula na primeira planilha que postei, na aba consulta estoque... qualquer dúvida sobre o custo médio posta que estarei tentando explicar.

Edcronos

13-09-2015 15:07:18

E pq vc não pode explicar o calculo feito?

tipo coluna Qtde. * valor - (Qtde. saida)

cloudrickk

13-09-2015 15:27:48

Tentarei explica como é feito então.
Pra achar o Valor Mov;
Qtde*Valor.

Depois que achou o valor total vamos achar o custo médio;
Valor total + Valor Mov(da nova entrada)/pelo estoque atual
Seria dessa forma, vai somar o valor total anterior com o valor total da nova entrada ou saída, e dividir pelo estoque atual... ai encontraremos o estoque médio.
Ex da planilha;
40 (Valor total anterior) + 15 (valor do Mov da entrada) = 55 ( valor Total) / 30 ( estoque atual) = 1,83 (custo Médio)

Edcronos

13-09-2015 17:23:58

para mim isso ficou confuso
no caso na aba Registro de inventario "da onde vc pediu para tirar o relatório"
vc tem :
------------ Mov ------ data ------Quant.------- valor
Pedra 0 __ E __ 01/09/2015 __ 20.00 ____ R$ 2.00
Pedra 0 __ E __ 01/09/2015 __ 10.00 ____ R$ 1.50
Pedra 0 __ S __ 01/09/2015 __ 16.00 ____ R$ 1.83

como ficaria esse calculo com esses valores ?

cloudrickk

13-09-2015 17:42:47

Ficaria assim,
2,00 (Valor) * 20,00 (Quant) = 40,00 (valor Total não está na planilha é o resultado da multiplicação) / 20,00 (Quant) = 2,00 (custo médio). isso na primeira linha, depois ele val calcula assim nas outras linhas;
1,50 (Valor, da nova entrada) * 10 (Quant, da nova entrada) = 15,00 (valor Total não está na planilha é o resultado da multiplicação) + 40,00 (valor Total não está na planilha é o resultado da multiplicação, referente a linha anterior) / 30,00 (Quant somada que dará o resultado do estoque atual) = 1,833333(custo médio)
E seria a mesma coisa nas outras linhas.

Edcronos

13-09-2015 18:18:03

vc gosta de enrolar ou está querendo embaralhar o raciocínio ???
no caso os valores de saida estão fora do calculo
linha 1 (E)
2,00 (Valor) * 20,00 (Quant) = 40,00
linha 2 (E)
1,50 (Valor) * 10 (Quant) = 15,00

(resultado da linha1)+(resultado da linha2)/(soma das quantidades)
=15,00 + 40,00 /(20+10)

poste a mudança que vc fez na macro para eu poder aplicar o calculo

cloudrickk

13-09-2015 18:37:58

Seria isso msm, o que você postou foi a mesma coisa que eu, porém resumindo... como eu não sei se vocês estavam entendeu o raciocínio de custo médio, por isso postei um site para poder entender o que seria o custo médio, e fica difícil de saber o que vocês não estao entendendo.
Pode fazer em cima da macro anterior, por a mudança que eu fiz deu um erro, na hora de colocar o código... vou ter que voltar para o que você fez e estudar o que eu errei na mudança que eu fiz.

Edcronos

13-09-2015 18:43:07

coloque assim mesmo para eu poder verificar oq vc quer

e não foi a mesma coisa não não
30 ( estoque atual) esse não seria o estoque atual
isso é estoque total de entrada, estoque atual seria o de entrada menos o de saida
e fora outras inconsistências na sua explicação alem de colocar coias sem sentido

cloudrickk

13-09-2015 18:47:30

Então eu tentei fazer com que ele jogasse o código sozinho, por que eu preciso colocar o código na aba relatório para gerar tudo... eu queria apertar botão e ele jogasse tudo sozinho.
Mas pode ser em cima do código anterior que você fez, por que o meu novo eu apaguei e coloquei o seu de volta.

Edcronos

13-09-2015 18:51:17

tá mas é só criar um botão e adicionar a macro

mas ve se é isso

Código: Selecionar todos

Sub BTN_Gerar_Relatorio()
        Dim cod As Long, L2 As Long, TQ As Long, L As Long, regO(), regD(1 To 4)

        Application.ScreenUpdating = False
        Application.Calculation = xlCalculationManual
        With Sheets("Registro de Inventário")
            regO = .Range("A2:F" & .Cells(Rows.Count, 1).End(xlUp).Row).Value2
        End With

        With Sheets("Relatório")
            For L2 = 2 To .Cells(Rows.Count, 1).End(xlUp).Row
                cod = .Cells(L2, 1).Value2
                regD(2) = 0
                 regD(3) = 0
                TQ = 0
                For L = 1 To UBound(regO, 1)
               
                    If regO(L, 1) = cod Then
                        regD(1) = regO(L, 2)
                        If regO(L, 3) = "E" Then
                            regD(2) = regD(2) + regO(L, 5)
                            regD(3) = regD(3) + (regO(L, 5) * regO(L, 6))
                            TQ = TQ + regO(L, 5)
                        Else
                            regD(2) = regD(2) - regO(L, 5)    'Qtde.
                        End If
                    End If
                Next
                regD(3) = regD(3) / TQ
                .Range(.Cells(L2, 2), .Cells(L2, 1 + UBound(regD))).Value2 = regD
            Next
        End With
        Application.Calculation = xlCalculationAutomatic
        Application.ScreenUpdating = True
        
    End Sub



cloudrickk

13-09-2015 19:02:47

É isso mesmo, ficou perfeito agora... só uma duvida, se eu colocar as saídas e vai calcular tabém?

Edcronos

13-09-2015 19:07:33

como assim colocar as saidas?

essa macro ignora os valores de saida no caso de custo, isso foi oq vc pediu

acho que vc deveria repensar o tipo de informação que vai colocar no relatorio
vc colocou estoque atual (entrada-saida)
e o custo medio de entrada
está faltando especificar outras coisas nesse relatorio para não confundir

cloudrickk

13-09-2015 19:16:57

Então, o custo médio ele funciona desse jeito que você colocou, só que ele calcula as saídas tambem... é isso mesmo que você fez, o que eu expressei estava correto, faltando lembrar que tinha as saídas tbm, custo médio funciona com as entradas e saídas... teria como colocar para calcular as saídas tbm? é a mesma coisa que você fez com as entradas, só que fazer quando tiver as saídas tbm

Edcronos

13-09-2015 19:26:47

o erro foi seu cara
Edcronos escreveu:para mim isso ficou confuso
no caso na aba Registro de inventario "da onde vc pediu para tirar o relatório"
vc tem :
------------ Mov ------ data ------Quant.------- valor
Pedra 0 __ E __ 01/09/2015 __ 20.00 ____ R$ 2.00
Pedra 0 __ E __ 01/09/2015 __ 10.00 ____ R$ 1.50
Pedra 0 __ S __ 01/09/2015 __ 16.00 ____ R$ 1.83

como ficaria esse calculo com esses valores ?
eu perguntei com esses valores e vc não colocou na explicação a linha 3 que tem a Saida "S"

se entrar na conta do custo medio a saida vai mudar totalmente a conta

vc falou 30,00 (Quant somada que dará o resultado do estoque atual)
só que estoque atual seria 20+10-16 e isso não dá 30

bem, eu fico por aqui, espero que encontre alguem para te ajudar

cloudrickk

13-09-2015 19:32:14

Se pegar só a linha 1 e 2 o estoque atual vai ser 30, na logica teria a linha 3 depois e linha 4 por diante... por isso coloquei que seria assim nas outras linhas, por que vai ter as saídas também.

Edcronos

13-09-2015 19:45:49

não, a logica não é a mesma

no original vc pediu
"Para achar a quantidade real nessa aba, precisa somar o que é E (Entrada) e subtrair o que é S (saída)"
SE "E" é entrada
custo = valor/quantidade

se S é saida
subtrai do total do estoque
como eu incluo isso na conta do custo médio?
não é nem questão de matemática é apenas logica

sem falar que o custo médio só poderia valer se for por períodos de compras equivalente, ou então todas as compras sendo para um mesmo proposito que deve ser o seu caso "construção"

a saida somente estaria ligado ao custo medio pelo valor do mesmo, e não no calculo
o valor da quantidade de saida é o valor do custo medio
custo de 1m area na saida = Valor custo medio

cloudrickk

13-09-2015 19:58:22

Toda vez que tiver uma saída usamos o custo médio, anterior e com isso vai ter modificação no estoque atual, se eu não fizer isso vai da erro.
Dá uma olhada na tabela que está em anexo.

Edcronos

13-09-2015 20:00:38

tá, e como eu aplico isso na "SUA planilha"?

cloudrickk

13-09-2015 20:12:40

Vai ser quase a mesma coisa, só que no lugar de somar os valores(R$), vai subtrair.

Edcronos

13-09-2015 20:14:48

e qual seria o resultado esperado para a tabela de comparação?

cloudrickk

13-09-2015 20:21:52

linha 1 (E)
2,00 (Valor) * 20,00 (Quant) = 40,00
linha 2 (E)
1,50 (Valor) * 10 (Quant) = 15,00

(resultado da linha1)+(resultado da linha2)/(soma das quantidades)
=15,00 + 40,00 /(20+10)

Linha 3 (S)
1,83 (Valor) *16 (Quant)= 29,28
(resultado da linha2)-(resultado da linha3)/(soma das quantidades)
=55,00 - 29,28,00 /(30-16)= 1,83
Seria desse jeito.

Edcronos

13-09-2015 20:26:47

e não dá na mesma?
a não ser que o valor de saida tenha diferencial do de entrada e isso somente se aplicaria a um comercio

outros dia eu aplico isso, tá muito frio aqui até para pensar
e tem que adicionar mais variaveis para esse complento

cloudrickk

13-09-2015 20:36:16

Na contabilidade tem que ter isso, se não o custo fica errado.
Tudo bem, outro dia agente continua.
Muito obrigado por está me ajudando.

Edcronos

19-09-2015 15:08:54

tenta esse aí
ou poste uma planilha resumida com mais exemplos e resultado esperado

Código: Selecionar todos

Sub BTN_Gerar_Relatorio()
            Dim cod As Long, L2 As Long, TQ As Long, L As Long, regO(), regD(1 To 4)

            Application.ScreenUpdating = False
            Application.Calculation = xlCalculationManual
            With Sheets("Registro de Inventário")
                regO = .Range("A2:F" & .Cells(Rows.Count, 1).End(xlUp).Row).Value2
            End With

            With Sheets("Relatório")
                For L2 = 2 To .Cells(Rows.Count, 1).End(xlUp).Row
                    cod = .Cells(L2, 1).Value2
                    regD(2) = 0
                     regD(3) = 0
                    TQ = 0
                    For L = 1 To UBound(regO, 1)
                   
                        If regO(L, 1) = cod Then
                            regD(1) = regO(L, 2)
                            If regO(L, 3) = "E" Then
                                regD(2) = regD(2) + regO(L, 5)
                                regD(3) = regD(3) + (regO(L, 5) * regO(L, 6))
                                TQ = TQ + regO(L, 5)
                            Else
                                regD(2) = regD(2) - regO(L, 5)
                                regD(3) = regD(3) - (regO(L, 5) * regO(L, 6))
                                TQ = TQ - regO(L, 5)
                            End If
                        End If
                    Next
                    regD(3) = regD(3) / TQ
                    .Range(.Cells(L2, 2), .Cells(L2, 1 + UBound(regD))).Value2 = regD
                Next
            End With
            Application.Calculation = xlCalculationAutomatic
            Application.ScreenUpdating = True
           
        End Sub

cloudrickk

19-09-2015 17:51:58

Boa tarde Edcronos,
É isso mesmo, agora deu certo.
Muito obrigado mesmo.