LOCALIZAR DADOS EM VÁRIAS PLANILHAS NO EXCEL

Gustavo Alcoforado

09-03-2016 15:55:10

Boa tarde!

Estou com esse código que localiza em várias planilhas, porém eu só queria que localizasse em apenas duas abas pré definidas.
Poderiam me ajudar?

Sub Procura()
'Declara uma strign que vai receber o valor a ser procurado na planilha
Dim procurado As String
'Declara uma variável para receber o resultado de um MsgBox
Dim result As VbMsgBoxResult
'Declara duas variáveis do tipo inteiro
'i -> Para controlar o laço de repetição
'QuantPlanilhas -> para armazenar a quantidade de planilhas da pasta de trabalho atual
Dim i, QuantPlanilhas As Integer
'Atribui a quantidade de planilhas da pasta atual à variável QuantPlanilhas
'O método ThisWorkbook.Worksheets.Count retorna esse parâmetro
QuantPlanilhas = ThisWorkbook.Worksheets.Count
'Mostra um InputBox para que seja inserido o dado que será procurado em todas a
'Pasta de trabalho e atribui seu valor à variávle procurado
procurado = InputBox("Digite o valor a ser procurado", "Valor procurado", "Exemplo, 2, 3, uma data qualquer")
'Inicia o laço de repetição que varre todas as planilhas da pasta de trabalho atual
For i = 1 To QuantPlanilhas Step 1
'Seleciona toda a área da planilha
With Worksheets(i).Range("A:IV")
'Efetua o método de busca, que retorna o valor se for encontrado ou
'Nothing caso não encontre nada
Set c = .Find(procurado, LookIn:=xlValues)
'Caso tenha achado algo, ativa a célula onde está o valor procurado
'e oferece para o usuário se quer ou não continuar a busca
If Not c Is Nothing Then
Worksheets(i).Select
Range(c.Address).Select
result = MsgBox("Deseja continuar a busca?", vbYesNo, "Continuar?")
'Caso queira, continua a busca, caso contrário, sai do laço
If result = vbNo Then
Exit Sub
End If
End If
End With
Next
End Sub

Reinaldo

09-03-2016 16:56:34

Talvez assim:

Código: Selecionar todos

Sub Procura()
'Declara uma strign que vai receber o valor a ser procurado na planilha
Dim Procurado As String, c As Variant
'Declara uma variável para receber o resultado de um MsgBox
Dim result As VbMsgBoxResult, t As Worksheet
'Declara duas variáveis do tipo inteiro
'i -> Para controlar o laço de repetição
'QuantPlanilhas -> para armazenar a quantidade de planilhas da pasta de trabalho atual
Dim i As Integer, QuantPlanilhas As Integer
'Atribui a quantidade de planilhas da pasta atual à variável QuantPlanilhas
'O método ThisWorkbook.Worksheets.Count retorna esse parâmetro
QuantPlanilhas = ThisWorkbook.Worksheets.Count
'Mostra um InputBox para que seja inserido o dado que será procurado em todas a
'Pasta de trabalho e atribui seu valor à variávle procurado
Procurado = InputBox("Digite o valor a ser procurado", "Valor procurado", "Exemplo, 2, 3, uma data qualquer")
'Inicia o laço de repetição que varre todas as planilhas da pasta de trabalho atual
For i = 1 To QuantPlanilhas Step 1
    'atribui a variavel a planilha
    Set t = Sheets(i)
    'determine o nome da planilha a ser utilizado
    If t.Name = ("PAULOBRAZ") Or t.Name = ("LEXBAXTER") Then
    'Seleciona toda a área da planilha
        With t.Range("A:IV")
        'Efetua o método de busca, que retorna o valor se for encontrado ou
        'Nothing caso não encontre nada
            Set c = .Find(Procurado, LookIn:=xlValues)
        'Caso tenha achado algo, ativa a célula onde está o valor procurado
        'e oferece para o usuário se quer ou não continuar a busca
            If Not c Is Nothing Then
                t.Select
                Range(c.Address).Select
                result = MsgBox("Deseja continuar a busca?", vbYesNo, "Continuar?")
                'Caso queira, continua a busca, caso contrário, sai do laço
                If result = vbNo Then
                    Exit Sub
                End If
            End If
        End With
    End If
Next
End Sub

Gustavo Alcoforado

09-03-2016 17:41:39

Obrigado pela atenção Reinaldo!

Bom fiz o que você recomendou, porém não tenho resposta nenhuma depois que digito a minha busca. Ele não da erro e nem vai para a linha encontrada, simplesmente ele sai da janela de busca.

Reinaldo

09-03-2016 18:01:26

Bom em teoria deve funcionar, desde que tenha modificado os nomes das planilhas na linha
If t.Name = "PAULOBRAZ" Or t.Name = "LEXBAXTER" Then

Para uma melhor inidicação poste seu modelo, altere dados que julgar necessário para fictícios

Gustavo Alcoforado

09-03-2016 18:18:24

Reinaldo escreveu:Bom em teoria deve funcionar, desde que tenha modificado os nomes das planilhas na linha
If t.Name = "PAULOBRAZ" Or t.Name = "LEXBAXTER" Then

Para uma melhor inidicação poste seu modelo, altere dados que julgar necessário para fictícios
Boa tarde!

Reinaldo, segue anexo a planilha. coloquei a macro no botão "Buscar Contratos".
Obrigado

Reinaldo

09-03-2016 19:04:54

Altere assim
If t.Name = ("Controle Contratos") Or t.Name = ("Contratos Encerrados") Then

e veja se retorna

Gustavo Alcoforado

14-03-2016 19:07:03

Muito Obrigado Reinaldo!