Inserir números sequenciais com botão [RESOLVIDO]

Sandro Oliveira

11-03-2016 13:44:25

Bom dia, estou com certa dificuldade em encontrar adequação ao meu problema, vejamos:
gostaria de criar um botão que ao clicá-lo abrisse um caixa box, a qual seria digitado qualquer número e, através dessa informação,
gerasse uma sequência de números em determinado intervalo de células de uma coluna.

ex.: ao clicar no botão, a cx aparece, digito, por exemplo, 5, aí a partir da celula e coluna determinada , a numeração é preenchida automaticamente. Ao clicar novamente os números são substituídos pela próxima entrada. ex. digitei 3, aí a numeração iria de 1 2 e 3 limpando o quatro e cinco. Caso não tenha como limpar, só o fato de gerar a numeração seria extremamente útil.
1
2
3
4
5
Desde de já agradeço

Mikel Silveira Fraga

11-03-2016 16:23:13

Sandro, boa tarde e seja bem vindo ao fórum.

Cara, veja se esse código atende sua necessidade.

Código: Selecionar todos

Sub AutoNumera()

    'Variáveis que irão armazenar
    'os valores Incremental e Total.
    Dim iIncrement, iTotal As Integer
    
    'Atribui o valor total, através
    'da função "InputBox".
    iTotal = InputBox("Favor informar o valor máximo da sequência.", "Valor Máximo")
    
    'Cria um laço que vai do valor
    '1 até o valor informado pelo usuário.
    For iIncrement = 1 To iTotal
    
        'Consicerando que os valores serão armazenados
        'na coluna A da Plan1, usamos o comando Cells, onde:
        '- iIncrement: linha da célula;
        '- valor 1: coluna da célula.
        Plan1.Cells(iIncrement, 1).Value = iIncrement
    
    Next iIncrement
    
End Sub
Teste e nos retorne.
Forte abraço!!!

Sandro Oliveira

11-03-2016 17:41:17

Mikel, Boa tarde,

Obrigado pela atenção, estou adaptando distribuição de frequência (Estatística), após concluir postarei o exemplo aqui. Em relação ao
tópico só mais uma dúvida, caso eu queira determinar qual coluna e célula que iniciará a a inserção dos números como devo alterar o código?
e caso eu digite um valor menor do que está mostrado, tem como de forma automática apagar os de maior valor ? quando solicito um número maior do que está ele acrescenta (isso é ótimo), agora quando é menor não. Há outra coisa, abro o inputbox e não prossigo e sim vou no botão cancelar, dá erro em tempo de execução,
como trato o erro caso clique no botão cancelar.
Ex1: que iniciar na Coluna b linha 15
Ex 2:
Digito 7, posteriormente digito 4( aí os elementos acima de 4 são apagados)
1 1
2 2
3 3
4 4
5
6
7

Mais uma vez, obrigado pela atenção

Sandro Oliveira

11-03-2016 18:12:07

Mikel,

Conseguir adequar o código, falta só a parte de apagar números existentes caso digite menor do que os vigentes.
o Código ficou assim, no lugar de Cells coloquei Range

Sub AutoNumera()
On Error Resume Next
'Variáveis que irão armazenar
'os valores Incremental e Total.
Dim iIncrement, iTotal As Integer

'Atribui o valor total, através
'da função "InputBox".
iTotal = InputBox("Favor informar o número de Classes.", "Distribuição de Frequência")

'Cria um laço que vai do valor
'1 até o valor informado pelo usuário.
For iIncrement = 1 To iTotal

'Consicerando que os valores serão armazenados
'na coluna A da Plan1, usamos o comando Cells, onde:
'- iIncrement: linha da célula;
'- valor 1: coluna da célula.

Plan1.Range("A15")(iIncrement, 1).Value = iIncrement


Next iIncrement

End Sub

Sandro Oliveira

11-03-2016 18:12:58

Mikel,

Conseguir adequar o código, falta só a parte de apagar números existentes caso digite menor do que os vigentes.
o Código ficou assim, no lugar de Cells coloquei Range

Sub AutoNumera()
On Error Resume Next
'Variáveis que irão armazenar
'os valores Incremental e Total.
Dim iIncrement, iTotal As Integer

'Atribui o valor total, através
'da função "InputBox".
iTotal = InputBox("Favor informar o número de Classes.", "Distribuição de Frequência")

'Cria um laço que vai do valor
'1 até o valor informado pelo usuário.
For iIncrement = 1 To iTotal

'Consicerando que os valores serão armazenados
'na coluna A da Plan1, usamos o comando Cells, onde:
'- iIncrement: linha da célula;
'- valor 1: coluna da célula.

Plan1.Range("A15")(iIncrement, 1).Value = iIncrement


Next iIncrement

End Sub

Mikel Silveira Fraga

11-03-2016 18:36:38

Sandro, boa tarde.

Cara, acrescente o código abaixo, antes da linha de comando que possuí o InputBox. Segue comando:

Código: Selecionar todos

'Limpar coluna.
iTotal = Plan1.Range("A15").End(xlDown).Row
Plan1.Range("A15:A" & iTotal).ClearContents
Teste e nos retorne.

Sandro Oliveira

11-03-2016 19:05:03

Perfeito!!! Estou quase concluindo, só falta uma coisa, Quando digitamos o "ROL" (números aleatórios), depois temos o "ROL" ordenado, isso já está completo, a questão é quando digitamos o ROL, temos que fazê-lo em linha ex: 1 (cel 1 da lin 1, ou seja A1) 22(cel 2 da lin 1, ou seja, B2)... quando se digita teclando enter é mais fácil e rápido, só que no caso do excel , ao teclar enter, os números são em coluna ( um abaixo do outro) e não lateralmente. Como as vezes o ROL é composto de muitos números, tem como criar um input ou form que ao clicar no botão esse abriria e, conforme ou fosse digitando e teclando enter, ele iria adicionando os números nas células e colunas determinadas?
Ex. digito 5 enter vai para cel A2, digito 11 vai para cel B2... até o limite de coluna imposta, passando para linha abaixo que no caso seria A3...

Mikel Silveira Fraga

11-03-2016 19:37:20

Sandro,

Cara, entendi que você precisa de mover a célula lateralmente em alguns momentos. Beleza, isso é fácil.
Agora, o que não consegui entender nada, foi em que momento você vai precisar que a célula mova na horizontal, ao invés da vertical.

Da pra postar um modelo ou tentar explicar um pouco mais claramente!?

No aguardo.

Sandro Oliveira

11-03-2016 19:58:19

Na verdade não é mover a célula, é adicionar os números ordenando-os na horizontal, a matriz tem que ser preenchida horizontalmente, se eu iniciar por exemplo na A2, tenho que digitar os números sequencialmente em B2, C2, D2 até o limite da matriz que é O2, passando para linha abaixo, iniciando na A3, B3,C3...O3, passando para linha abaixo. Não posso digitar na vertical A2, A3, A4,A5... e depois ir para B2,B3,B4...Se eu fizer assim dará erro. A matriz é 15 x 15 de A2 a O16. A questão que como são muitos números, digitando um a um teclando a seta à direita do teclado e mais demorado do que se tiver uma maneira de ir digitando teclando enter e os números irem se ordenando na horizontal, até chegar ao limite de linha imposta, passando a adicionar na linha abaixo e assim sucessivamente.
Outra coisa há como criar input que eu determine o intervalo de linhas à serem ocultas e outra para reexibi-las, vi alguns códigos, mas todos já determinam as linhas à serem ocultas e reexibí-las, no caso, preciso informar quais são as linhas que preciso ocultar, caso contrário teria que ir ao código toda vez para informar o intervalo.

Sandro Oliveira

11-03-2016 20:09:33

Mikel,

Sobre oculta e reexibir consegui, tem um código que só oculta linhas vazias, as que estão preenchidas permanecem. Em um dos casos resolveu, agora preciso de uma forma que oculte linhas que tenham conteúdo. kkk A questão da digitação horizontal é só pra facilitar
e agilizar...

Código ocultar e reexibir abaixo
Sub OcultaLinB1()
Application.ScreenUpdating = False
For Each myCell In Sheets("Plan2").Range("A2:A16")
If myCell = "" Then
myCell.EntireRow.Hidden = True
End If
Next myCell
Application.ScreenUpdating = True

End Sub



**********************


Sub ReexibirLinB1()
Application.ScreenUpdating = False
For Each myCell In Sheets("Plan2").Range("A2:A16")
If myCell = "" Then
myCell.EntireRow.Hidden = False
End If
Next myCell
Application.ScreenUpdating = True
End Sub

Sandro Oliveira

11-03-2016 20:27:16

Relativo a ocultar e reexibir resolvi, são dois tipos de intervalos um pra linhas sem conteúdo e outro para linhas com conteúdo, não sei se é o mais adequado mas funcionou, o código ficou assim:
Sub OcultaLinB1()
Application.ScreenUpdating = False
For Each myCell In Sheets("Plan2").Range("A2:A16", "A18:A32")
If myCell = "" Then
myCell.EntireRow.Hidden = True
End If
Next myCell
Application.ScreenUpdating = True
Rows("55:66").EntireRow.Hidden = True

End Sub
Sub ReexibirLinB1()
Application.ScreenUpdating = False
For Each myCell In Sheets("Plan2").Range("A2:A16", "A18:A32")
If myCell = "" Then
myCell.EntireRow.Hidden = False
End If
Next myCell
Application.ScreenUpdating = True
Rows("55:66").EntireRow.Hidden = False
End Sub

Mikel Silveira Fraga

14-03-2016 13:28:05

Sandro, bom dia.

Cara, somente hoje tive tempo de olhar sua mensagem.

Substitua a rotina anterior, por esta abaixo:

Código: Selecionar todos

Sub AutoNumera()

    'Variáveis que irão armazenar
    'os valores Incremental e Total.
    Dim iLinha, iColuna, iIncrement, iTotal As Integer
    
    'Ativa tratamento de erro com um
    'desvio para o fim da rotina.
    On Error GoTo fimRotina
    
    'Limpar coluna.
    Plan1.Range("A2:O16").ClearContents
    
infNovo:
    'Atribui o valor total, através
    'da função "InputBox".
    iTotal = InputBox("Favor informar o valor máximo da sequência.", "Valor Máximo")
    
    'Como estamos trabalhando com uma matriz 15x15,
    'o valor máximo que pode ser informado é 225.
    If iTotal > 225 Then
        MsgBox "O valor informado é maior do que permitido pela matriz." & VBA.Chr(13) & _
               "Para uma matriz 15 x 15, o valor máximo a ser informado é 225." & VBA.Chr(13) & _
               "Informe um novo valor.", vbExclamation, "Alerta!"
        GoTo infNovo
    End If
    
    'Atribui o valor inicial.
    iIncrement = 1
    
    'Cria um laço que vai do valor
    '1 até o valor informado pelo usuário.
    For iLinha = 2 To 16
    
        For iColuna = 1 To 15
        
            'Consicerando que os valores serão armazenados
            'na coluna A da Plan1, usamos o comando Cells, onde:
            '- iIncrement: linha da célula;
            '- valor 1: coluna da célula.
            Plan1.Cells(iLinha, iColuna).Value = iIncrement
            iIncrement = iIncrement + 1
            If iIncrement > iTotal Then Exit Sub
        
        Next iColuna
        
    Next iLinha
    
fimRotina:
End Sub
Veja se era isso que você estava precisando.

Aguardo seu retorno.

Sandro Oliveira

15-03-2016 02:32:26

Mikel muito bom essa rotina, mas não é o que necessito, a questão que são duas matrizes, uma digito os valores aleatórios dos dados butos, os quais não são números sequencias, são aleatórios e as vezes repetidos. ex. 1 13 14 22 54 2 11 75 80 35 35 1 3 3 7 56 48, após digitar esses números a outra matriz às ordena de forma sequencial e automatica, e que nesse caso já está feito. A questão que no Excel quando digitamos e teclamos enter , a próxima célula ativa é a de baixo, ou seja, A2, A3, A4...(sentido vertical) só que no caso do preenchimento de frequência tenho que digitar na horizontal, ou seja, A2, B2, C2... até chegar no fim da linha e coluna determinada, passando assim para o início da linha abaixo, que no caso, seria : A3, B3, C3...etc, caso contrário dará diferença de resultado, porque se tenho determinada quantidade de números e não preencho as linhas completamente o resultado fica comprometido, por esse motivo tenho que ir completando linha por linha até acabarem os números aleatórios. Para efetuar essa digitação é ruim porque ao invés de teclar enter tenho que digitar o número e teclar seta a direita, se conseguisse criar uma maneira de ir digitando os números e esses fossem preenchidos na horizontal e quando chegasse ao limite da linha com a coluna determinada, passasse para o inicio da linha abaixo automaticamente, seria mais rápido e prático. Por isso pensei numa input que eu fosse digitando e teclando enter para que essa entrada de dados ocorresse na horizontal.
Vou mandar o arquivo para seu e-mail para melhor entendimento o nome do arquivo é Dist de freq.xlsm

Mikel Silveira Fraga

15-03-2016 13:16:02

Bom dia Sandro, tudo bem?

Então, agora sua explicação foi mais objetiva, facilitando o entendimento.

Montei as rotinas abaixo e, acredito que deva resolver:

Código: Selecionar todos

Dim iLinha, iColuna As Integer

Private Sub Worksheet_Change(ByVal Target As Range)
    
    iLinha = Target.Row
    iColuna = Target.Column
    
    If iLinha >= 2 And iLinha <= 16 Then
    
        If iColuna >= 1 And iColuna <= 15 Then
        
            If iColuna < 15 Then
            
                iColuna = iColuna + 1
                
            Else
            
                iColuna = 1
                iLinha = iLinha + 1
                
            End If
        
        End If
    
    End If
    
End Sub

Private Sub Worksheet_SelectionChange(ByVal Target As Range)
    
    If iLinha <= 0 And iColuna <= 0 Then Exit Sub
    Me.Cells(iLinha, iColuna).Select
    iLinha = 0: iColuna = 0
    
End Sub
Todos esses blocos de códigos, devem ser colocados no Sheet, dentro do Editor de Macros (VBE).

Teste e retorne se funcionou, ok.

Abraços.

Sandro Oliveira

15-03-2016 21:18:46

Excelente!!! era exatamente isso, valeu demais.