Conversão de Unidades

eng.darlon

29-03-2016 14:39:35

Olá amigos,

Estou criando um planilha, e preciso trabalhar com duas unidades de Refrigeração (TR e kW). Acontece que recebo os dados nas apenas em uma das unidades, dependendo do cliente, e para executar meus cálculos, preciso converte-las.

Precisava de um código VBA associado à um botão que converta todos os valores da Coluna "C" para a "D" ou vice e versa, dependendo da unidade dos dados que recebi.

As formulas são:

de kW p/ TR
kWx860/3024

de TR p/ kW
TRx3024/860

Alguém poderia me ajudar?!

Grato!

netocasaroli

02-04-2016 12:50:35

Primeiramente, bem-vindo ao fórum.

Crie um módulo e cole o seguinte código (e não esqueça de salvar a planilha em formato .xlsm):

Código: Selecionar todos

Option Explicit

Sub ConvertUnits()
'-------------------------------------------------------------------------------------------------------'
' Autor:        Neto Casaroli                                                                           '
' Criação:      02/04/2016                                                                              '
' Comentário:   Converte os dados da tabela de kW para TR e vice-e-versa, conforme disponibilidade      '
'-------------------------------------------------------------------------------------------------------'

    Dim i               As Integer
    Dim LinhaInicial    As Integer
    Dim LinhaFinal      As Integer
    Dim ColunaInicial   As Integer
    Dim Planilha        As Worksheet
    
    Set Planilha = ThisWorkbook.Sheets("Plan1") 'nome da planilha
    LinhaInicial = 4 'primeira linha de dados da tabela
    ColunaInicial = 3 'primeira coluna de dados (C)
    LinhaFinal = Planilha.Cells(Rows.Count, ColunaInicial).End(xlUp).Row 'última linha de dados
    
    'Avalia a disponibilidade de dados e realiza a conversão
    With Planilha
        For i = LinhaInicial To LinhaFinal
            If (.Cells(i, ColunaInicial) = 0 Or .Cells(i, ColunaInicial) = vbNullString) And (.Cells(i, ColunaInicial).Offset(0, 1) <> vbNullString And .Cells(i, ColunaInicial).Offset(0, 1) <> 0) Then
                .Cells(i, ColunaInicial) = .Cells(i, ColunaInicial).Offset(0, 1) * 3024 / 860
                
            ElseIf (.Cells(i, ColunaInicial).Offset(0, 1) = 0 Or .Cells(i, ColunaInicial).Offset(0, 1) = vbNullString) And (.Cells(i, ColunaInicial) <> vbNullString And .Cells(i, ColunaInicial) <> 0) Then
                .Cells(i, ColunaInicial).Offset(0, 1) = .Cells(i, ColunaInicial) * 860 / 3024
            End If
        Next i
    End With

End Sub
Qualquer dificuldade, poste aí...