extrair Valores Distintos de planilha com Filtro

Mathmatic

12-07-2016 02:59:43

Saudações Senhores,

Segue uma planilha em Anexo, cuja Coluna A está Filtrada.

Agora, após este Filtro (que será feito por mim), preciso de um Código VBA para extrair (copiar) somente os valores Distintos (sem repetição) da Coluna C , e os cole na Coluna E .
Lembrando que executarei esta operação VBA depois que eu Filtrar a Coluna A, e que a mesma permanecerá Filtrada durante a operação VBA.

Obs: a planilha em anexo é apenas um modelo para poder criar o código VBA, pois a planilha base tem muito mais Linhas.

Agradeço desde já a ajuda dos senhores !

Mathmatic

14-08-2016 06:04:31

Pessoal,
encontrei um Link (VBA) que "Extrai" valores Distintos da uma planilha "sem filtros" (obs: adaptei para colar os resultados extraídos na Plan2).

Quase resolveu o que eu precisava .... Tentei adaptar para executar a mesma operação em "Células Visíveis", ou seja, numa planilha Filtrada, ... mas não consegui.

Será que poderiam me ajudar adaptar este código do Link para executar em "Células Visíveis" .

Link : http://www.microsoftexcel.com.br/index. ... cados.html


muito obrigado.

Mauro Coutinho

15-08-2016 14:50:33

Mathmatic, ajustando uma outra Function para contar indicada no link http://www.mrexcel.com/forum/excel-ques ... nge-2.html, para retornar da forma que quer chegamos as rotinas abaixo :

Uma observação, é que diz que quer o retorno na Coluna E, se executar no modelo que enviou você irá visualizar os resultados, mas supondo que seu filtro inicie na linha 2 alguns resultados não irão aparecer pelo fato das linhas ocultas, então o ideal seria jogar o resultado para uma outra aba, de uma olhada faça alguns testes.

Código: Selecionar todos

Function CountUniqueVisible(Target As Range)
''==============================================
''Return the # of unique items in visible cells in a selected range
''Created 29 July 2011 by Denis Wright
''Updated to work with blank ranges and
''as a worksheet function, 18 Aug 2011
''==============================================
    Dim Rng As Range, c As Range
    Dim dic As Object
    Dim y
    Dim j As Long
    Dim Sht As Worksheet
    Dim strSheets As String
    Dim r
    
    r = 4
    
    Set dic = CreateObject("Scripting.Dictionary")
    Set Rng = Target.SpecialCells(xlCellTypeVisible)
 
    If Application.WorksheetFunction.CountA(Rng) > 0 Then
        j = 0
        For Each c In Rng
            If Not (dic.exists(c.Value) Or c.EntireRow.Hidden) Then
                j = j + 1
                dic.Add c.Value, j
                
                Cells(r, 5).Value = c.Value
                
                r = r + 1
            End If
        Next c
        y = dic.keys
        'Now we have a list of unique values. Next step is to return the count.
        CountUniqueVisible = UBound(y) + 1
    Else
        CountUniqueVisible = 0
    End If
ExitHere:
    Set dic = Nothing
    Set Rng = Nothing
End Function

Sub FiltroUnicosFiltrado()
    Dim rnAux1 As Range
    Dim lRow As Long
    
    lRow = Cells(Rows.Count, 1).End(xlUp).Row
    
    Set rnAux1 = Range("C2:C" & lRow).SpecialCells(xlCellTypeVisible)
    
    sVr = CountUniqueVisible(rnAux1)

End Sub

Mathmatic

15-08-2016 20:09:40

Muito obrigado sr. Mauro Coutinho, Resolveu meu dilema !

Obs : Já adaptei para "sair" os resultados na Plan2

Parabéns pelo seu conhecimento !