Separ Texto & Gerar Base Dados [Resolvido]

salvador

05-08-2016 12:33:19

Pessoal, bom dia!

Preciso de uma ajuda que facilitará muito a minha vida!

Gero através do meu sistema um relatório com as seguintes colunas:
Cod Cargo / Cargo / CCusto / Treinamentos
Porém, a coluna Treinamentos, numa única célula vem todos os treinamentos separados por ponto e virgula.

Daí o que eu faço: separo texto em colunas e para cada cod cargo eu insiro a quantidade de linhas de treinamentos que existe, copio o cod cargo, cargo, c custo e utilizo o transpor para empilhar os treinamentos. Faço na mão sempre que gero esse arquivo.

Será que vocês poderiam ajudar-me com uma macro para faze-lo!

Deixei no arquivo duas planilhas
Base_Dados = Forma como vem do sistema
Como Ficar = Forma como tem que ficar com alguns exemplos!

Obrigado pela ajuda Amigos

Reinaldo

05-08-2016 20:05:41

Experimente

Código: Selecionar todos

Sub Como_Fica()
Dim x As Integer
Dim cLin As Long, nLin As Long
Dim vCurso() As String

nLin = Sheets("plan1").Cells(Cells.Rows.Count, "A").End(xlUp).Row + 1

For cLin = 2 To Sheets("Base_Dados").Cells(Cells.Rows.Count, "A").End(xlUp).Row
    If Sheets("Base_Dados").Range("D" & cLin).Value = "" Then
        Sheets("Plan1").Range("A" & nLin).Value = Sheets("Base_Dados").Range("A" & cLin).Value
        Sheets("Plan1").Range("B" & nLin).Value = Sheets("Base_Dados").Range("B" & cLin).Value
        Sheets("Plan1").Range("C" & nLin).Value = Sheets("Base_Dados").Range("C" & cLin).Value
    nLin = nLin + 1
    Else
        vCurso = Split(Sheets("Base_Dados").Cells(cLin, 4), ";")
        For x = LBound(vCurso) To UBound(vCurso)
            Sheets("Plan1").Range("A" & nLin).Value = Sheets("Base_Dados").Range("A" & cLin).Value
            Sheets("Plan1").Range("B" & nLin).Value = Sheets("Base_Dados").Range("B" & cLin).Value
            Sheets("Plan1").Range("C" & nLin).Value = Sheets("Base_Dados").Range("C" & cLin).Value
            Sheets("Plan1").Range("D" & nLin).Value = vCurso(x)
        nLin = nLin + 1
        Next
    End If
Next

End Sub

salvador

08-08-2016 10:33:36

Reinaldo, bom dia!

Obrigado pelo retorno. É isso mesmo! Ficou muito bom, muito bom mesmo!

Para encerrar o assunto, vi que você separou os dados na mesma planilha depois do banco!
Existe a possibilidade de fazer essa separação numa planilha nova?

Aguardo Retorno
Obrigado mais uma vez

Mauro Coutinho

08-08-2016 12:58:44

Veja se é isto :

Código: Selecionar todos

Sub Como_Fica_New_Sheet()
    Dim x As Integer
    Dim cLin As Long, nLin As Long
    Dim vCurso() As String
    Dim iLin
    Dim cCol
    
    'Cria uma aba nova
    Sheets.Add After:=Sheets(Sheets.Count)
    'Renomeia a nova aba
    ActiveSheet.Name = "Relatorio"
    
    'Preenche o cabeçalho
    Range("A1:D1") = Array("Cod Cargo", "Cargo", "CC", "Treinamento")

    iLin = 1
    cCol = 1
    
    nLin = Sheets("relatorio").Cells(Cells.Rows.Count, "A").End(xlUp).Row + 1

    For cLin = 2 To Sheets("Base_Dados").Cells(Cells.Rows.Count, "A").End(xlUp).Row
        If Sheets("Base_Dados").Range("D" & cLin).Value = "" Then
            Sheets("relatorio").Range("A" & nLin).Value = Sheets("Base_Dados").Range("A" & cLin).Value
            Sheets("relatorio").Range("B" & nLin).Value = Sheets("Base_Dados").Range("B" & cLin).Value
            Sheets("relatorio").Range("C" & nLin).Value = Sheets("Base_Dados").Range("C" & cLin).Value
        nLin = nLin + 1
        
        Else
            vCurso = Split(Sheets("Base_Dados").Cells(cLin, 4), ";")
            For x = LBound(vCurso) To UBound(vCurso)
                Sheets("relatorio").Range("A" & nLin).Value = Sheets("Base_Dados").Range("A" & cLin).Value
                Sheets("relatorio").Range("B" & nLin).Value = Sheets("Base_Dados").Range("B" & cLin).Value
                Sheets("relatorio").Range("C" & nLin).Value = Sheets("Base_Dados").Range("C" & cLin).Value
                Sheets("relatorio").Range("D" & nLin).Value = vCurso(x)
            nLin = nLin + 1
            Next
        End If
    Next

    Columns("A:D").AutoFit
    
End Sub
[]s

salvador

08-08-2016 14:38:15

Mauro / Reinaldo, bom dia!

Perfeito meu amigo. Economizarei um tempo absurdo!

Obrigado mesmo!

Muito Show!

Abraços