Como atribuir um código a inumeras plans

MarceloAdriano

12-09-2016 01:20:45

Olá
Tem um código, abaixo, que sera utilizada em diversas plans. Ressalto que estas planilhas são identicas, porém o código especifica "planila1" e assim por diante... e dessa forma tenho que multiplicar o mesmo código. Como reformular esse parâmetro para que possa utilizar o mesmo código em em diversas planilhas? Evitando assim as várias cópias do mesmo código para atederem as diversas plans?
Espero ter feito entender...
Grato,
Marcelo Adriano

IMAGEM 1
Imagem
IMAGEM 2
Imagem
Parte do código:
Option Private Module

Option Explicit

Sub CélulasParaMatriz_PrimeiroBimestre()
Dim w As Worksheet, t As Long, i As Long
On Error Resume Next
Set w = Planilha4 ===> TORNAR ESSE CÓDIGO DE FORMA GLOBAL QUE POSSA USÁ-LA EM OUTRAS PLANS. E NÃO MULTIPLICAR O MESMO CÓDIGO.


t = w.Cells(w.Cells.Rows.Count, 2).End(xlUp).Row

Mauro Coutinho

12-09-2016 12:11:03

Marcelo, supondo que irá executar a rotina atraves de um Botão quando determinada aba estiver selecionada, é só trocar :

Set w = Planilha4

por Set w = ActiveSheet

[]s

MarceloAdriano

12-09-2016 16:10:42

Obrigado Mauro Coutinho
Era isso que necessitava.
Só em termo de curiosidade teria como excutar uma marcro para todas as plans de um vez só?
Segue o códigona integra:
As planilhas que irão compor serão:

Nome Plan VBA
Planilha4
Planilha8
Planilha412
Planilha16

Option Private Module

Option Explicit

Sub CélulasParaMatriz_AlunosInativos()
Dim w As Worksheet, t As Long, i As Long
On Error Resume Next
Set w = ActiveSheet 'O código será realizado na planilha ativa.Dessa forma não há necessidade de referenciar a todas as planilha que receberão este código

t = w.Cells(w.Cells.Rows.Count, 2).End(xlUp).Row


If MsgBox("Deseja realmente executar esta operação? Executando, irá substituir as notas pelas informações contidas nas observações do campo <dos respectivos alunos inativos>.", vbInformation + vbYesNo, "ATENÇÃO!") = vbNo Then

MsgBox "código abortado", , "Atenção"
Exit Sub

Else


If t < 14 Then

MsgBox "não há nomes na lista para executar o comando"
Exit Sub
End If

For i = 14 To t Step 1

If Len(w.Cells(i, 22)) > 0 Then

If Not IsNumeric(w.Cells(i, 22)) Then
Application.DisplayAlerts = False
w.Range("c" & i, "F" & i).Merge
w.Cells(i, 3) = w.Cells(i, 22)

Application.DisplayAlerts = True
End If

End If

Next i

End If
MsgBox "Executado", , "Atenção"

End Sub



Set w =ActiveSheet

Thisworkbook.Sheets(Array("Sheet1", "Sheet2", "Sheet3", "Sheet4"))

Mauro Coutinho

12-09-2016 17:57:39

Marcelo, você pode estar utilizando um ARRAY para as abas como você citou no final de sua msg, mas na minha opinião o inconveniente é que temos de Listar todas dentro do Array, ou seja, se chegar a acrescentar outra aba, terá de ajustar na rotina, e conforme você disse de "uma marcro para todas as plans de um vez só" suponho que não teremos nenhuma fora do Array, se for assim eu sugiro utilizar um Loop por todas as Abas sem precisarmos utilizar o ARRAY.

Estou colocando as duas rotinas e você analise e veja qual seria melhor utilizar, lembrando que por estarmos trabalhando em Loop tirei as Instruções de Exit Sub pois se deixarmos sairemos da rotina sem percorrer as outras abas, veja que o principio é o mesmo só alterando a questão do Array.

Código: Selecionar todos

Sub CélulasParaMatriz_AlunosInativos_Mauro_Array()
    Dim w As Worksheet, t As Long, i As Long
    Dim wsName As Variant
    
    For Each wsName In Array("Sheet1", "Sheet2", "Sheet3", "Sheet4")
    
        Set w = Worksheets(wsName)
    
        t = w.Cells(w.Cells.Rows.Count, 2).End(xlUp).Row
    
    
        If MsgBox("Deseja realmente executar esta operação? Executando, irá substituir as notas pelas informações contidas nas observações do campo <dos respectivos alunos inativos>.", vbInformation + vbYesNo, "ATENÇÃO!") = vbNo Then
        
            MsgBox "código abortado para a Sheet:- " & wsName, , "Atenção !!! - " & wsName & " - Abortado"
            'Exit Sub
            GoTo Next_wsName
        Else
    
            If t < 14 Then
            
                MsgBox "não há nomes na lista para executar o comando na Sheet:- " & wsName, , "Atenção !!! - " & wsName & " - Abortando"
                'Exit Sub
                GoTo Next_wsName
            End If
    
            For i = 14 To t Step 1
            
                If Len(w.Cells(i, 22)) > 0 Then
                
                    If Not IsNumeric(w.Cells(i, 22)) Then
                        Application.DisplayAlerts = False
                        w.Range("c" & i, "F" & i).Merge
                        w.Cells(i, 3) = w.Cells(i, 22)
                        
                        Application.DisplayAlerts = True
                        
                    End If
                
                End If

            Next i
    
        End If
        
Next_wsName:
    
    Next wsName
    
    MsgBox "Executado", , "Atenção"

End Sub

Código: Selecionar todos

Sub CélulasParaMatriz_AlunosInativos_Mauro()
    Dim w As Worksheet, t As Long, i As Long
    Dim wsName
    Dim wsSheet
    
    For Each wsSheet In ActiveWorkbook.Worksheets
        
        Set w = Worksheets(wsSheet.Name)
        
        wsName = wsSheet.Name
        
        t = w.Cells(w.Cells.Rows.Count, 2).End(xlUp).Row
    
        If MsgBox("Deseja realmente executar esta operação? Executando, irá substituir as notas pelas informações contidas nas observações do campo <dos respectivos alunos inativos>.", vbInformation + vbYesNo, "ATENÇÃO!") = vbNo Then
        
            MsgBox "código abortado para a Sheet:- " & wsName, , "Atenção !!! - " & wsName & " - Abortado"
            GoTo Next_wsName
        Else
    
            If t < 14 Then
            
                MsgBox "não há nomes na lista para executar o comando na Sheet:- " & wsName, , "Atenção !!! - " & wsName & " - Abortando"
                GoTo Next_wsName
            End If
    
            For i = 14 To t Step 1
            
                If Len(w.Cells(i, 22)) > 0 Then
                
                    If Not IsNumeric(w.Cells(i, 22)) Then
                        Application.DisplayAlerts = False
                        w.Range("c" & i, "F" & i).Merge
                        w.Cells(i, 3) = w.Cells(i, 22)
                        
                        Application.DisplayAlerts = True
                        
                    End If
                
                End If

            Next i
    
        End If
        
Next_wsName:
    
    Next wsSheet
    
    MsgBox "Executado", , "Atenção"

End Sub
[]s

MarceloAdriano

12-09-2016 21:27:48

Olá Mauro Coutinho
Estupendo seu raciocínio! Todas os dois códigos funcionaram perfeitamente, entretanto, o primeiro é mais adequado e ajustou melhor, uma vez, que o segundo código percorre todas as plans desnecessariamente.
Obrigado por compartilhar o seu conhecimento, e contribuir com meus estudos em VBA e principalmente a sua boa vontade em ajudar!
Irei estudar as etapas (passo a passo) para assimilar o seu raciocínio.
De qual Estado você é?
Muito Agradecido a sua pessoa....
Grato,
Marcelo Adriano

Mauro Coutinho

13-09-2016 00:47:49

Marcelo, moro em São José dos Pinhais - Pr, e se a ajuda foi favorável, faça o favor de clicar na mãozinha no lado direito do post para agradecer.

[]s