gerar arquivo.TXT de cada filtro do Loop

Mathmatic

14-09-2016 18:59:41

Saudações,

Tenho o arquivo em anexo (Filtro e Loop.xls) que Filtra informações contidas em A1:E6 (código VBA criado pelo amigo Reinaldo).
conforme um Loop por G2:G4 e Lança os resultados (um por vez) abaixo de A11:E11 , até aí tudo perfeito.

Agora enuncio abaixo minha dúvida (necessidade) :

É possível transformar as informações que aparecerão abaixo de A11:E11 (uma por uma gerada pelo Loop) em Arquivo.txt ? e Salvar estes Arquivos.txt (cada um que o Loop gerar) na pasta: C:\Teste1\Teste2 ?

Obs: o nome do arquivo.txt pode ser atribuído pela célula cujo Filtro foi gerado, ou seja, de G2 à G4.

Mauro Coutinho

15-09-2016 14:47:41

Cheguei a ver seu outro tópico, e quanto a criar o arquivo texto é simples, ainda mais se chegar a olhar o tópico :
Exportar dados para *txt - viewtopic.php?f=20&t=4820 logo abaixo deste que criou.

Para criar me baseei na rotina indicada no tópico acima e com alguns ajustes fica da seguinte forma, troque as que estão no modelo que enviou por estas, lembrando que geramos arquivos texto simples, para o tipo de formatação que citou no outro tópico terá de pesquisar e ajustar.

Código: Selecionar todos

Dim sNome

Sub filtrar_dados()
    Dim x As Integer
    
    For x = 2 To Cells(Cells.Rows.Count, "G").End(xlUp).Row
        Range("O2").Value = Range("G" & x).Value
        Range("A1:E6").AdvancedFilter Action:=xlFilterCopy, CriteriaRange:=Range( _
            "O1:O2"), CopyToRange:=Range("A11:E11"), Unique:=False
        
        sNome = Range("O2").Value
        
        Call CriarText
        
        limpar_teste
        
    Next
    
    Range("O2") = ""
    
End Sub

Sub limpar_teste()
    [A12:E20].Clear 'Contents
End Sub

Sub CriarText()
    'Declarar variáveis
    Dim txtLinha As String
    Dim nSeq As Long
    Dim rg As Range
    Dim rgRow As Range
    Dim rgCell As Range
    Dim sPasta
    
    'Definir o caminho do arquivo
    sPasta = "C:\Teste1\Teste2"
    
    'Definir o intervalo que será convertido, a partir de A12
    Set rg = Sheets("Loop VBA").Range("A12", Sheets("Loop VBA").Cells(Rows.Count, "E").End(xlUp))

    'Criar novo arquivo ou sobrescrever arquivo antigo
    txtNome = sPasta & "\" & sNome & ".txt"
    
    nSeq = FreeFile
        
        Open txtNome For Output As #nSeq
    
        'Loop para percorrer as linhas do intervalo rg
        For Each rgRow In rg.Rows
            'Inserir o código de início de uma linha de tabela
            txtLinha = vbLf
            
                'Loop para percorrer as células da linha
                For Each rgCell In rgRow.Cells
                
                    'Concatenar a string para definir uma célula da tabela
                    txtLinha = txtLinha & rgCell & vbLf
                    
                    'Concatenar a string para fechar uma célula da tabela
                    txtLinha = txtLinha & " " ' & vbLf
                Next rgCell
            
            'Concatenar a string para fechar a linha da tabela
            txtLinha = txtLinha
            
            'Inserir o código gerado no arquivo txt
            Print #nSeq, txtLinha
            
        Next rgRow
        
        'Fechar o arquivo txt
        Close #nSeq
        
End Sub
[]s

Mathmatic

15-09-2016 18:26:09

... mais uma vez, muito obrigado sr. Mauro Coutinho

ajudou muitíssimo com o código VBA acima.

as demais adaptações vou pesquisando e ajustando..... o principal foi RESOLVIDO com o código acima.