[RESOLVIDO]Como alterar o nome do arquivo mais recente?

Wagner.cwb

25-10-2016 01:35:26

Olá Caros Colegas,

preciso realizar uma rotina de relatório, pensei em criar uma macro, porém esbarro com a padronização dos nomes dos arquivos.

Descrição da rotina:

Tenho uma pasta com arquivos de relatório diários - nesta pasta são gerados 4 arquivos distintos .csv, que dão origem a um relatório final.

O meu problema é que os arquivos não assumem um padrão, por favor, observem na imagem anexa.
Basedados.PNG
Pensei em criar um modulo que abra o arquivo mais recente pelo prefixo do nome e salve com o nome novo.
Como faço para abrir o arquivo mais recente para cada um dos nomes?
Por exemplo:

Agentes2_102416_031504_sgacthr

Abrir/Alterar arquivo com prefixo Agentes2 para "Agentes".
Não estou certo se consigo isso por vba ou vbs ou até mesmo .bat?

Por favor, podem me ajudar?

Abraços!

Wagner.cwb

28-10-2016 01:22:26

Boa noite Colegas,

estou quase lá... rs
pesquisando pela internet, consegui subsídios para tentar uma solução.
Para quem estiver com um problema parecido, recomendo a leitura do link http://forum.clubedohardware.com.br/top ... s-recente/

Antes de rodar o código é necessário marcar certa referência no VBA, caso não esteja marcada:
no menu do editor VBA Ferramentas > Referências > marque 'Microsoft Scripting Runtime'

Código: Selecionar todos

Sub AbreMaisRecenteNovo()
  Dim arqSys As FileSystemObject
  Dim objArq As File
  Dim minhaPasta
  Dim nomeArq As String
  Dim dataArq As Date
        Const Diret As String = "C:\teste"
        Set arqSys = New FileSystemObject
        Set minhaPasta = arqSys.GetFolder(Diret)
        dataArq = DateSerial(1900, 1, 1)
For Each objArq In minhaPasta.Files
    If objArq.DateLastModified > dataArq Then
        dataArq = objArq.DateLastModified
        nomeArq = objArq
    End If
Next objArq
        ActiveWorkbook.FollowHyperlink Address:=nomeArq
        Set arqSys = Nothing
        Set minhaPasta = Nothing
End Sub
Aqui abriu o arquivo mais recente, ótimo, agora estou pensando como vou abrir o mais recente entre os nomes... por exemplo
abrir agentes2 e depois o diário... etc..

pensei até agora... pegar 4 últimos mais recentes e copiar em outra pasta com os nomes que preciso... ou então só renomear direto da pasta origem e fazer o arquivo base buscar via "dados - obter dados externos"... por enquanto só estou planejando e pesquisando para saber como escrever tudo isso em vba.
Abraços!

Reinaldo

28-10-2016 11:35:07

uma possibilidade e "questionar" o nome do arquivo retornado no ObjArq
algo +/- assim

Código: Selecionar todos

For Each objArq In minhaPasta.Files
    If objArq.Name Like "*xls*" Then
        If objArq.DateLastModified > dataArq Then
            dataArq = objArq.DateLastModified
            nomeArq = objArq
        End If
    End If
Assim a variável nomeArq irá retornar o mais recente que tiver (no meu exemplo) xls na descrição

Wagner.cwb

29-10-2016 00:02:54

Reinaldo escreveu:uma possibilidade e "questionar" o nome do arquivo retornado no ObjArq
algo +/- assim

Código: Selecionar todos

For Each objArq In minhaPasta.Files
    If objArq.Name Like "*xls*" Then
        If objArq.DateLastModified > dataArq Then
            dataArq = objArq.DateLastModified
            nomeArq = objArq
        End If
    End If
Assim a variável nomeArq irá retornar o mais recente que tiver (no meu exemplo) xls na descrição
Obrigado Reinaldo, por favor, veja se eu entendi corretamente,

eu entendi que é para colocar o nome do arquivo e interesse na Like, correto? ficou desta forma:

Código: Selecionar todos

Sub AbreMaisRecenteNovo()

'http://forum.clubedohardware.com.br/topic/891657-resolvido-macro-para-abrir-um-determinado-arquivo-mais-recente/

  Dim arqSys As FileSystemObject
  Dim objArq As File
  Dim minhaPasta
  Dim nomeArq As String
  Dim dataArq As Date
                
  Const Diret As String = "\\SOLIDUS7\NextccReport$\[Default]\SSTCRD\Daily"
  Set arqSys = New FileSystemObject
  Set minhaPasta = arqSys.GetFolder(Diret)
      dataArq = DateSerial(1900, 1, 1)
  For Each objArq In minhaPasta.Files
  If objArq.Name Like "Agentes_*csv*" Then
  If objArq.DateLastModified > dataArq Then
        dataArq = objArq.DateLastModified
        nomeArq = objArq
  End If
  End If
  Next objArq
        ActiveWorkbook.FollowHyperlink Address:=nomeArq
        Set arqSys = Nothing
        Set minhaPasta = Nothing
End Sub
Resolveu a questão, irei criar um ciclo para cada um dos meus arquivos de interesse.

Mais um detalhe, preciso inserir uma variável no endereço dos arquivos.

Const Diret As String = "\\SOLIDUS7\NextccReport$\[Default]\depende do usuário que gera o relatório\Daily"

Pensei em pegar uma célula, por exemplo a M1 e lá o usuario digita o nome, então assim completa o campo, mas não rodou.


Obrigado!

Wagner.cwb

29-10-2016 00:15:32

Encontrei outro código, bem mais curto e quase funcional... digo quase, pois ele traz o primeiro arquivo "agentes_" gerado no ano de 2016 e não o último. Por favor, podem me ajudar entende-lo?

O primeiro código está travando a maquina, enquanto este executou o procedimento mais rápido.

Código: Selecionar todos

Sub recente()

'https://www.youtube.com/watch?v=ufBp20Lr1oE

FolderName = "\\SOLIDUS7\NextccReport$\[Default]\SSTCRD\Daily"

If Right(FolderName, 1) <> Application.PathSeparator Then
FolderName = FolderName & Application.PathSeparator
Fname = Dir(FolderName & "*Agentes_.csv")
End If
With Workbooks.Open(FolderName & Fname)
End With
End Sub

Reinaldo

29-10-2016 11:30:20

A Segunda rotina é menor e mais rápida por não buscar/comparar a data do arquivo, mas obter apenas a primeira ocorrência, na ordem interna do sistema; assim poderá retornar o mais novo, o mais velho ou alguma versão intermediaria.
Para usar em sua necessidade/demanda, e necessário reescreve-la, montando um loop bem como comparações; provavelmente ficara maior e provavelmente mais lenta do que a primeira; eu ficaria com a primeira.
O primeiro código está travando a maquina
Não há nada na rotina que justifique o travamento. Pelo endereço de diretório, entendo que está buscando os arquivos em um endereço na rede interna (intranet) de seu local, assim a velocidade/estabilidade da rotina está vinculada a velocidade/estabilidade dessa conexão.

Para a variavel experimente algo assim:
FPath = "\\SOLIDUS7\NextccReport$\[Default]\" & range("M1").value & "SSTCRD\Daily"

Const Diret As String = FPath

Wagner.cwb

29-10-2016 16:46:45

Exatamente Reinaldo, mudei o endereço para outra pasta com menos arquivos e alterei o código para não abrir mais o arquivo, ficou mais rápido. Sim, irei ficar com o primeiro código, até adquirir mais conhecimento para desenvolver outras técnicas, agradeço pelo sua ajuda, está sendo de grande valia.

Naquela parte do LIKE, onde busca o nome do arquivo, estou pensando em criar um loop que busque pelos 4 nomes distintos, por enquanto estou levando uma surra kkk, mas vou tentar mais vezes, caso eu não consiga, pedirei mais esta mão. A princípio pensei em criar na planilha uma colona com os nomes dos arquivos (a encontrar)... o while iria percorrer até a linha da coluna ficar em branco... estou apanhando para fazer a configuração disso, juntar o while com o like e a range, mas bora estudar um pouco mais. Obrigado!

Reinaldo, modifiquei para

fpath = "\\SOLIDUS7\NextccReport$\[Default]\" & Range("M1").Value & "SSTCRD\Daily"
Const Diret As String = fpath

Porém está ocorrendo erro "expressão constante obrigatória para fPath
Const Diret As String = fpath

eu entendi que que fpath não esta declarada, então tentei declará-la
dim fpath as string, mas continuou com o erro...

Eu entendi a razão do fpath, tentei fazer sem ele, incluindo aspas simples, porém continua esbarrando
na expressão constante obrigatório, agora para Range("M1").Value

Const Diret As String = "\\SOLIDUS7\NextccReport$\[Default]\'" & Range("M1").Value & "'\Daily"

Reinaldo

30-10-2016 11:11:10

Aparentemente Const não aceita algumas definições; experimente utilizar assim

Código: Selecionar todos

Sub AbreMaisRecenteNovo()

'http://forum.clubedohardware.com.br/topic/891657-resolvido-macro-para-abrir-um-determinado-arquivo-mais-recente/

  Dim arqSys As FileSystemObject
  Dim objArq As File
  Dim minhaPasta
  Dim nomeArq As String
  Dim dataArq As Date
                
  Dim Diret As String
    Diret = "\\SOLIDUS7\NextccReport$\[Default]\" & Range("M1") & "\SSTCRD\Daily"
  
 ' Const Diret As String = "\\SOLIDUS7\NextccReport$\[Default]\SSTCRD\Daily"
  
  Set arqSys = New FileSystemObject
  Set minhaPasta = arqSys.GetFolder(Diret)
      dataArq = DateSerial(1900, 1, 1)
  For Each objArq In minhaPasta.Files
  If objArq.Name Like "Agentes_*csv*" Then
  If objArq.DateLastModified > dataArq Then
        dataArq = objArq.DateLastModified
        nomeArq = objArq
  End If
  End If
  Next objArq
        ActiveWorkbook.FollowHyperlink Address:=nomeArq
        Set arqSys = Nothing
        Set minhaPasta = Nothing
End Sub

Wagner.cwb

30-10-2016 16:37:39

Obrigado, funcionou!