ModeloCadastro3ListView

Diovanino Cassio

15-03-2017 14:47:18

Senhores,
Foi postado há bastante tempo um exemplo de LISTVIEW, conforme título acima.
Baixei o exemplo que mostra um cadastro de fornecedores através de formulários VBA, composto de um formulário de cadastro e outro de pesquisa, usando LISTVIEW.
Quando tento adaptar este exemplo ao meu sistema, utilizando controle de ligações telefônicas, e quando vou abrir o formulário para cadastro das ligações, sempre está me dando o erro de:
Erro em tempo de execução '1004"
O método 'Range' do objeto'_Global' falhou
Na planilha de "Configurações", deixei igual ao do exemplo, somente mudando o nome da planilha de ligações.
Gostaria de saber o porquê que minha planilha não está sendo encontrada, quando o código: Private Sub DefinePlanilhaDados(), está sendo executado.

Sds,
Diovanino Cássio

Reinaldo

16-03-2017 10:42:45

Erro 1004 e um erro um tanto quanto generico, Muito provavelmente está se referindo a um objeto não encontrado.
Infelizmente não há uma "receita" que diga diretamente o que fazer; esta diretamente ligada ao seu projeto/estrutura/rotinas.
Poste seu modelo; poucos dados (altere para ficticios se necessario); que seja representativo da atual estrutura e erro. Assim podera obter uma ajuda mais direta e que atenda seus objetivos

Diovanino Cassio

16-03-2017 14:34:27

Reinaldo,
Consegui resolver o problema, pois o mesmo estava relacionado há uma referência de nome incorreta na planilha de configurações, ok?
Agora estou com um outro problema, que como adaptei o modelo exemplo ao meu projeto, estou recebendo a mensagem de erro:
"A variável do objeto ou a variável do bloco 'with' não foi definida 91"
Tenho um formulário para controle de ligações e nele um botão de pesquisa que abre um outro formulário com a ListView. Acontece que após o erro na abertura deste formulário, o mesmo aparece com a ListView sem os dados das ligações.
Irei postar o meu projeto para ser verificado!

Reinaldo

18-03-2017 12:18:50

Tambem em (http://www.planilhando.com.br/forum/vie ... 96#p120896), basicamente o problema reside na validação de valores na rotina de validação dos dados creio que o mesmo se da apenas em campos numéricos/data; lembro de ter havido uma outra situação referente a data e na época não consegui resolver mas propus um paliativo (que não recordo tambem).
Estou avaliando;mas se alguem mais puder....

Diovanino Cassio

23-03-2017 12:12:57

Reinaldo,
Consegui resolver o problema da seguinte forma:
Fui gradativamente criando as minhas planilhas usando a planilha modelo (Cadastro de fornecedores), substituindo as colunas existentes, pelas colunas das minhas planilhas. Da mesma forma, fiz com os formulários, aproveitando ao máximo, os campos existentes do formulário modelo.
Após sucesso no primeiro formulário de cadastro feito a partir do modelo, fui criando os outros do meu sistema, que agora está funcionando perfeitamente.
Quero deixar aqui, os meus sinceros agradecimentos pelo seu esforço de tentar me ajudar com este erro, ok?

Diovanino Cassio

30-10-2017 17:03:52

Senhores,

Como faço para mudar a cor da letra de uma determinada coluna no LISTVIEW?
Por exemplo, quero que a coluna nome, saia na cor vermelha.

Sds,
Diovanino Cássio

Diovanino Cassio

12-01-2018 18:31:35

Todos os meus controles, utilizam o formulário de pesquisa do modelo supra citado.
Mas acontece que quando rodo uma determinada pesquisa, há uma repetição das colunas no LISTVIEW, à direita das colunas que foram preenchidas com os dados da pesquisa, deixando o meu formulário com um aspecto muito feio.
Abaixo, o código que utilizo para mostrar os valores no LISTVIEW:

Private Sub PopulaListBox(ByVal Datanf As String, _
ByVal serienf As String)
On Error GoTo TrataErro

Dim rst As ADODB.Recordset
Dim campo As Field
Dim myArrayTodos() As Variant
Dim i As Integer
Dim li As ListItem, fld As Field, ch As ColumnHeader

Dim Column As Long
Dim Counter As Long
Counter = 0

Set rst = PreecheRecordSet(Datanf, serienf)

'preenche o combobox com os nomes dos campos
'persiste o índice
Dim indiceTemp As Long
indiceTemp = cboOrdenarPor.ListIndex
cboOrdenarPor.Clear
For Each campo In rst.Fields
cboOrdenarPor.AddItem campo.Name
Next
'recupera o índice selecionado
cboOrdenarPor.ListIndex = indiceTemp

'Colunas a Preencher Inicia na Primeira
For i = 0 To rst.Fields.Count - 1 'For i = 1 : a partir da 2ª coluna
Set ch = lstLista.ColumnHeaders.Add(, , rst.Fields(i).Name)
'ch.Width = 48 'Define o Tamanho de Todas as COLUNAS
'MsgBox rst.Fields(i).Name
Next

'Clear the Column Headers
lstLista.ListItems.Clear

'coloca as linhas do RecordSet num Array, se houver linhas neste
If Not rst.BOF Then
Do While Not rst.EOF


'Preenche o LISTVIEW a partir da 1ª Coluna
Set li = lstLista.ListItems.Add(, "k" & rst.Fields(0), CheckNull(rst.Fields(0)))
'Fill in the rest of the columns
For i = 1 To rst.Fields.Count - 1
li.SubItems(i) = CheckNull(rst.Fields(i))
Next

rst.MoveNext 'Move to next record
Loop

'Define os Tamanhos das colunas automaticamente
Call TamanhoColAutomatico

End If
'atualiza o label de mensagens
If rst.RecordCount <= 0 Then
lblMensagens.Caption = rst.RecordCount & " registros encontrados"
Else
lblMensagens.Caption = rst.RecordCount & " registros encontrados"
End If


Exit Sub

' Fecha o conjunto de registros.
Set rst = Nothing
' Fecha a conexão.
'conn.Close

TrataSaida:
Exit Sub
TrataErro:
Debug.Print Err.Description & vbNewLine & Err.Number & vbNewLine & Err.Source
MsgBox Err.Description & vbNewLine & Err.Number & vbNewLine & Err.Source
Resume TrataSaida
End Sub

srobles

12-01-2018 19:09:27

Diovanino Cassio,

Vamos lá :
1) Mudar a cor de determinada coluna no ListView :
Na rotina que adiciona os itens ao ListView, adicione ao final :

Código: Selecionar todos

lstLista.ListItems(li).SubItems(numeroColuna).BackColor = vbRed
2)Repetição das colunas do ListView á cada pesquisa realizada:
Nesta linha do seu código, apenas são limpos os itens da lista

Código: Selecionar todos

'Colunas a Preencher Inicia na Primeira
For i = 0 To rst.Fields.Count - 1 'For i = 1 : a partir da 2ª coluna
Set ch = lstLista.ColumnHeaders.Add(, , rst.Fields(i).Name)
'ch.Width = 48 'Define o Tamanho de Todas as COLUNAS
'MsgBox rst.Fields(i).Name
Next

'Clear the Column Headers
lstLista.ListItems.Clear
Conforme a linha comentada, para limpar os cabeçalhos, altere para :

Código: Selecionar todos

'Clear the Column Headers
lstLista.ColumnHeaders.Clear
'Clear all ListItems
lstLista.ListItems.Clear 

'Colunas a Preencher Inicia na Primeira
For i = 0 To rst.Fields.Count - 1 'For i = 1 : a partir da 2ª coluna
'Esta linha adiciona novamente os cabeçalhos ao ListView
Set ch = lstLista.ColumnHeaders.Add(, , rst.Fields(i).Name)
'ch.Width = 48 'Define o Tamanho de Todas as COLUNAS
'MsgBox rst.Fields(i).Name
Next
Abs

Diovanino Cassio

17-01-2018 13:50:20

Saulo, bom dia!

Primeiramente muito obrigado por sua interação ao meu problema.
A solução apresentada para a repetição das colunas, funcionou perfeitamente.
Agora, referente a mudança de cor dos dados de uma determina coluna, está me apresentando uma mensagem de erro, que é a seguinte: "Qualificador inválido", isso no SubItems.

Sds,
Diovanino Cássio

srobles

18-01-2018 01:35:31

Diovanino, boa noite!

Amigo me desculpe. Acabei me equivocando na orientação de como colorir uma coluna em especifico.

Na verdade, para colorir a coluna em questão, use:

Código: Selecionar todos

lstLista.ListItems(li).SubItems(numeroColuna).ForeColor = vbRed
Apenas ressalto, que isso irá mudar a cor da fonte de todos os itens na coluna selecionada ok?

Deixo abaixo, um modelo para estudo.

Espero ter ajudado, e mais uma vez, desculpe pelo equivoco.

Abs

Diovanino Cassio

24-01-2018 12:34:35

Valeu Saulo!
Obrigado mais uma vez pela ajuda.

Sds,
Diovanino Cássio

Diovanino Cassio

24-01-2018 13:07:06

Senhores,

Como já disse aqui, sempre estou criando os meus formulários para o meu sistema, usando o modelo supra citado, ok?
Criei um formulário recentemente, para inserir as minhas despesas com manutenções dos nossos equipamentos, onde o mesmo busca informações sobre o equipamento em manutenção, de uma planilha de controle dos equipamentos (em anexo parte do meu formulário).
Estou necessitando fazer o seguinte:
Assim que o equipamento a ser enviado para manutenção for escolhido, preciso mostrar no campo ao lado o seu número de série, que também consta na planilha de controle de equipamentos.
como eu conseguiria mostrar este serial no meu formulário?
Segue abaixo, o código para carregar a relação dos equipamentos, que eu escolho em uma combo de equipamentos:
Private Sub UserForm_Activate()
Dim SourceWB As Workbook
Dim ListItems As Variant
Dim i As Integer

Application.ScreenUpdating = False

Call LimpaControles
Call HabilitaBotoesAlteracao

With Me.cboEquipto
.Clear ' Limpa a combobox

' Abre arquivo de origem com somente leitura

Set SourceWB = Workbooks.Open("\\140.1.0.222\Base de Dados NGLPA\Controles TI\Planilhas\CTHS.xlsx", _
False, True)

ListItems = SourceWB.Worksheets(1).Range("e2", Range("e400").End(xlUp)).Value
SourceWB.Close False ' fechar o Arquivo de origem sem salvar as alterações
Set SourceWB = Nothing
ListItems = Application.WorksheetFunction.Transpose(ListItems)

For i = 1 To UBound(ListItems)
.AddItem ListItems(i)
Next i
.ListIndex = -1
End With
Call OrdenaComboEquipto

End Sub

Sds,
Diovanino Cássio

srobles

24-01-2018 16:47:21

Diovanino,

Primeiro, adicione um novo módulo á sua pasta de trabalho e nele, cole o que segue :

Código: Selecionar todos

Public ListSeriais As Variant
Public retornoSerial As String
Function retornaSerial (ByVal CodEquip As Long)
   For vID = 1 To Ubound(ListSeriais)
      If vID = CodEquip Then
          retornoSerial = ListSeriais(vID)
          Exit For
      End If
   Next
End Function
Agora, no seu formulário, experimente substituir a rotina existente pela que deixo abaixo:

Código: Selecionar todos

Private Sub UserForm_Activate()
Dim SourceWB As Workbook
Dim ListItems As Variant
Dim i As Integer

Application.ScreenUpdating = False

Call LimpaControles
Call HabilitaBotoesAlteracao

With Me.cboEquipto
.Clear ' Limpa a combobox

' Abre arquivo de origem com somente leitura

Set SourceWB = Workbooks.Open("\\140.1.0.222\Base de Dados NGLPA\Controles TI\Planilhas\CTHS.xlsx", _
False, True)

ListItems = SourceWB.Worksheets(1).Range("e2", Range("e400").End(xlUp)).Value

'Aqui criamos a lista com os seriais
'Mude a letra da coluna para a correspondente na planilha
ListSeriais = SourceWB.Worksheets(1).Range("e2", Range("e400").End(xlUp)).Value

SourceWB.Close False ' fechar o Arquivo de origem sem salvar as alterações
Set SourceWB = Nothing
ListItems = Application.WorksheetFunction.Transpose(ListItems)

'Criação da nova lista, que contem os seriais
ListSeriais = Application.WorksheetFunction.Transpose(ListSeriais)

For i = 1 To UBound(ListItems)
.AddItem ListItems(i)
Next i
.ListIndex = -1
End With
Call OrdenaComboEquipto
End Sub
E no evento Change do ComboBox :

Código: Selecionar todos

Private Sub ComboBox1_Change()
    'Se o valor do combo for diferente de nulo
    If ComboBox1 <> "" Then
        'Chamamos a função para retornar os dados do equipamento
        'com base no Indice do combobox +1
        'Pois a listagem no combobox começa em 0
        'e para retornar os dados começamos em 1
        retornaSerial ComboBox1.ListIndex + 1
        With Me
            'Preenchemos os campos com os dados obtidos na função
            .TextBox1 = retornoSerial
        End With
    Else
        'Se o valor do combo for nulo
        'Limpamos os campos
        TextBox1 = ""
    End If
End Sub    
Espero ter ajudado.

Abs

Diovanino Cassio

25-01-2018 11:45:01

Saulo, bom dia!

Na solução apresentada por você, estou tendo problema na execução do módulo, pois está me retornando uma mensagem de "tipos incompatíveis", veja o anexo:

Sds,
Diovanino Cássio

srobles

25-01-2018 14:40:14

Diovanino,

Estranho amigo, pois copiei e colei os códigos em uma nova pasta para testes e não enfrentei o problema.

Todavia, experimente o que segue abaixo.

Código: Selecionar todos

Public ListSeriais As Variant
Public retornoSerial As String
Function retornaSerial(ByVal CodEquip As Long)
    Dim vID As Long
    For vID = 1 To UBound(ListSeriais)
       If vID = CodEquip Then
           retornoSerial = ListSeriais(vID)
           Exit For
       End If
    Next
End Function
Espero que te ajude.

Abs

Diovanino Cassio

25-01-2018 16:45:00

Saulo,

Me desculpe, mas o erro estava acontecendo porquê eu tinha colocado o BLOCO do CHANGE, em local incorreto. Estava sendo executado antes da abertura da planilha contendo os dados, ok?

Mais uma vez, te agradeço muito pela ajuda.

Sds,
Diovanino Cássio

Diovanino Cassio

26-01-2018 16:06:00

Saulo, boa tarde!

Já estou em fase final do meu sistema, e gostaria de aproveitar os vossos conhecimentos, para tentar solucionar um problema que tenho:
A maioria dos meus formulários, possui COMBOX que efetua o carregamento de informações, provenientes de outras planilhas (Exemplo: formulário custo de manutenção, tem COMBOX que busca dados da planilha contendo as informações dos equipamentos (campo codigoequipamento).
Gostaria que sempre que estivesse no formulário de controle dos custos das manutenções, e eu clicasse no botão de VOLTAR, estas planilhas abertas forem fechadas. No print acima, necessito fechar a planilha customanut.xlsx.
Estou lhe enviando um print da tela para evidenciar melhor o que estou necessitando, ok?

Sds,
Diovanino Cássio

srobles

26-01-2018 16:52:55

Diovanino,

Se as demais pastas de trabalho estiverem abertas na mesma instância do Excel, basta que você adicione ao código do botão voltar, a instrução :

Código: Selecionar todos

'Fechar pasta de trabalho
'True = Fecha a pasta salvando alterações
'False = Fecha a pasta sem salvar as alterações
WorkBooks("nomedapastaafechar.xlsx").Close , True
Creio que isso resolva seu problema.

Abs

Diovanino Cassio

02-02-2018 13:47:10

Saulo, bom dia!

Mais uma vez conto com a vossa ajuda para resolver os meus problemas de VBA, ok?

Tenho um problema no meus formulários de pesquisas, que é o ordenamento dos dados das colunas em ASCENDENTE e DESCENDENTE.
Uso o código VBA abaixo, para fazer ordenação de uma determinada coluna, quando clicar sobre ela.

Private Sub lstLista_ColumnClick(ByVal ColumnHeader As MSComctlLib.ColumnHeader)
' ordena a coluna ao clicar no título da mesma
lstLista.Sorted = False
lstLista.SortKey = ColumnHeader.Index - 1

If lstLista.SortOrder = lvwAscending Then
lstLista.SortOrder = lvwDescending
Else
lstLista.SortOrder = lvwAscending
End If

lstLista.Sorted = True
End Sub

Acontece que funciona bem, quando o dado é ALFA, mas quando é NÚMERO, ele não ordena na sequencia que pretendo que fique ordenado (ver arquivo em anexo).

Uma outra coisa que necessito, é que ao abrir o LISTVIEW, o meu último registro, seja o primeiro a ser mostrado, na primeira linha do LISTVIEW.

Sds,
Diovanino Cássio

srobles

11-02-2018 04:00:12

Diovanino,

Desculpe a demora amigo.

Creio que se você formatar sua coluna Registro da planilha como texto e modificar sua rotina de Cadastro para adicionar o 0 (zero) em índices menores que 10, resolva seu problema.

A forma como a classificação desta coluna no ListView está sendo feita no momento, está correta, pois ela classifica na ordem numérica mesmo. Como o número 19 começa em 1, sempre virá á frente do 2 e assim por diante.

Agora, se você acrescentar o 0 (zero) nos registros menores que 10, verá que os dados serão carregados da forma que deseja.

Para exibir sempre o último registro como sendo o primeiro da lista, após adicionar os dados ao ListView, faça:

Código: Selecionar todos

    With nomeSeuFormulario.ListView
         .Sorted = False
         'Informe qual coluna devemos ordenar
         .SortKey = 0 'Primeira coluna
         'Ou se preferir, use o indice do ComboBox Campo
         '.SortKey = nomeComboxCampo.ListIndex
        
         'Informe qual a forma de classificação
         .SortOrder = lvwAscending
         'Ou se preferir, use o indice do ComboBox Ordem
        '.SortOrder = nomeCombox.ListIndex
        'Classificamos os dados
        .Sorted = True
    End With
Todavia, deixo abaixo um modelo de exemplo.

Abs

Diovanino Cassio

15-02-2018 17:03:05

Saulo,
Acatei a vossa sugestão, e mudei o campo REGISTRO da planilha, para tipo TEXTO e acrescentei o ZERO nos registros de 1 a 9. Funciona bem, até o registro 99, mas quando passa de 100, acontece o que está sendo mostrado no print em anexo:

Sds,

srobles

15-02-2018 17:28:40

Diovanino,

Percebo que a única opção que nos resta será adicionar zeros á frente de cada registro...Tanto ao realizar novos cadastros quanto aos que já existem.

Em testes aqui, ressaltando que um ListView só pode ter pouco mais 32.000 registros, logo, você terá de padronizar os registros existentes com 6 ou mais dígitos, sendo que sempre deverá ter 1 zero á frente de cada, para que a ordenação fique á contento.

Vamos esperar um pouco mais e quem sabe, alguns dos ilústres colegas não tem uma solução mais simples.

Abs

Diovanino Cassio

16-02-2018 11:33:55

Saulo, bom dia!

Eu resolvi o problema mudando o tipo de dado da coluna REGISTRO das planilhas de número para um tipo personalizado (CEP), e no código, onde é definido o registro automático, eu usei o FORMAT no campo REGISTRO, como "00000"

Sds,
Diovanino Cássio

Diovanino Cassio

12-03-2018 14:16:48

Saulo, bom dia!

Gostaria do vosso corriqueiro apoio, no problema abaixo:
Também baseado no conceito do "ModeloCadastro", estou inserindo no meu sistema, um formulário para controle de abastecimentos.
O formulário já está pronto, e o que ficou pendente, foi a mostragem dos kms rodados e da média do veículo.
Coloquei na pasta C:\temp, todas a planilhas utilizadas pelo formulário, e gostaria que você, claro se for possível, me mostrasse como que eu faço para mostrar os valores nos campos de KM RODADO e MÉDIA.
Compactei o arquivo no formato .RAR, ok?

Sds,
Diovanino Cássio

srobles

12-03-2018 17:26:25

Diovanino,

A forma com a qual irá trabalhar, necessita de todas as base separadas? Não poderíamos consolidar todas em um único arquivo?

Abs

Diovanino Cassio

12-03-2018 18:58:02

Saulo,
O meu sistema, utiliza vários formulários, que segue o mesmo padrão de código, do formulário que lhe enviei, ok?
O que eu fiz aqui, foi de copiar todas a planilhas necessárias para a pasta TEMP do meu disco C, apontar o caminho para este diretório, e deixar somente o formulário e o módulo necessário, para você conseguir rodá-lo. Aqui, está funcionando perfeitamente.

Sds,
Diovanino Cássio.

srobles

12-03-2018 22:23:00

Diovanino,

OK, entendi sua demanda.

Editei seu modelo conforme orientação, acrescentando um novo módulo onde está a função que efetua a validação para cálculo de média de consumo.

A mesma funciona da seguinte maneira :

Ao se teclar ENTER ou TAB no campo Hodômetro, a função é chamada e é passado como parâmetro de pesquisa, a placa do veículo.

A função percorre a planilha Abastecimento de baixo para cima procurando a placa informada e, ao encontrar, retorna o ultimo hodômetro registrado.

Caso encontre a placa informada, com base nos campos Qtde e Hodômetro do formulário, fazemos os cálculos da seguinte maneira :

Campo Distância = Hodômetro informado no formulário - o último hodômetro registrado;
Campo Média = Campo Distância / Campo Qtde

Caso não encontre a placa informada, preenchemos os campos Distância e Média com 0 (zero)

Espero ter ajudado.

Abs

Diovanino Cassio

13-03-2018 01:02:39

Saulo,

Valeu mesmo brother!
Era isso mesmo que eu estava precisando.
Ficou muito boa a vossa sugestão, ok?

Sds,
Diovanino Cássio

Diovanino Cassio

16-03-2018 14:04:36

Saulo, bom dia!

Desculpe-me te incomodar novamente sobre este assunto, pois eu até lhe respondi sobre este assunto, como resolvido, ok?
Acontece que efetuei os testes no Controle de Combustíveis, digitando informações de abastecimentos, usando veículos diferentes, mas quando tentei efetuar vários lançamentos simultâneos de um mesmo veículo, o formulário está ficando escondido atrás da tela do Excel (ver print em anexo).

Sds,
Diovanino Cássio

srobles

16-03-2018 16:16:00

Diovanino,

Sinceramente amigo, não sei o que pode estar causando esse transtorno. Todavia, fiz pequenas alterações no formulário e durante meus testes, não enfrentei o problema. Peço que verifique se o erro pode estar ocorrendo por falta de memória no computador, mas...

Segue abaixo o que alterei no formulário :
No evento Initialize, adicionei a chamada da rotina CarregaComboBox, removendo a mesma do evento click do botão Novo.

Adicionei também a instrução frmControlAbast.Repaint na função de cálculo de média de KM, apenas para atualizar o formulário.

No botão Voltar, removi a instrução frmControlAbast.Hide (que apenas esconde o formulário, mas mantém o mesmo na memória) e adicionei também Windows("Abastecimento.xlsx").Close True (para fecharmos a base de dados, salvando as alterações), assim descarregamos tudo que estiver na memória.

Creio que isso possa resolver o problema, mas peço que realize testes e retorne.

Abs

Diovanino Cassio

16-03-2018 19:46:51

Saulo, boa tarde!

Efetuei os testes aqui, mas continua da mesma forma. Na digitação de um novo registro para o mesmo veículo, o formulário fica por baixa da tela do Excel.
Com a mudança no botão de VOLTAR, a planilha de combustivel, aparece no explorador do Windows, para ser salva como cópia, pois a mesma continua aberta no sistema.

Muito esquisito mesmo o que está acontecendo!

Sds,
Diovanino Cássio

srobles

16-03-2018 22:45:02

Diovanino,

Amigo, sinceramente não sei o que pode estar causando o problema. Analisei toda a planilha novamente e não pude identificar a causa.

Fiz testes inserindo vários registros para o mesmo veículo e não ocorreu problema algum. Removi o fechamento da pasta Abastecimento do botão voltar e adicionei o fechamento quando o formulário for descarregado da memória. Notei que você utiliza o Office 365 / 2013 ,correto? Aqui uso o Office 2010 32bits, porém não posso afirmar que o problema ocorra justamente por causa das versões do Office. :(

Deixo abaixo, seu modelo reeditado.

Abs

Diovanino Cassio

19-03-2018 11:16:28

Saulo, bom dia!

Eu já estava suspeitando que poderia ser problema no meu OFFICE, pois tive alguns problemas com o mesmo. Hoje, efetuei os testes no OFFICE 2010 32bits, e funcionou perfeitamente.
Vou efetuar agora, os testes em um outro micro, que roda o OFFICE 365, para ver se o problema vai se repetir. Te manterei informado dos testes, ok?

Sds,
Diovanino Cássio.

Diovanino Cassio

22-03-2018 14:01:50

Saulo, bom dia!

Realmente o problema estava relacionado ao OFFICE 365 do meu note, pois testei em vários outros OFFICE 365, rodando no Windows10, e funcionou perfeitamente.

Estou postando o modelo novamente, pra você me ajudar no formulário de PESQUISA.
Na tabela de combustível, tenho apenas o campo de DATA, mas no formulário de pesquisa, eu tenho os campos de Data Inicial e Data Final, pois necessito mostrar no ListView, datas dentro de uma determinada faixa.
Poderia mais uma vez, me ajudar neste problema?

Sds,
Diovanino Cássio

Diovanino Cassio

04-04-2018 13:59:36

Senhores,

Estava tratando deste assunto com o nobre colega SAULO, que tem me ajudado bastante.
Como ele está um pouco ausente aqui do fórum, gostaria que alguém me ajudasse neste assunto, ok?

Eu vi algumas adaptações a esta minha dúvida, mas não consegui fazê-las rodar, dentro do meu sistema.

Sds,
Diovanino Cássio

Diovanino Cassio

03-10-2018 18:42:29

Saulo, boa tarde!

Após muito tempo sem mexer no meu projeto, gostaria de retomar o assunto do LISTVIEW, relacionado a ordenação da coluna de REGISTROS, como sugerido por você, em parentese (Creio que se você formatar sua coluna Registro da planilha como texto e modificar sua rotina de Cadastro para adicionar o 0 (zero) em índices menores que 10, resolva seu problema).
A minha coluna REGISTRO na planilha, já está como texto, cujos registros estão como vários zeros à esquerda. Mas mesmo assim, quando abro o LISTVIEW, os registros continuam sendo mostrados como: 1, 2, 3, 4, 5, 6, 7, 8, 9, 10, 11, etc.
Como que eu faria para adicionar o 0 (zero) em índices menores que 10?

Sds,

LaerteB

05-10-2018 04:14:18

Boa Noite..madrugada.. :lol: rsrsrs.., Diovanino Cassio.

Olha não baixei o seu arquivo, então não posso te responder neste momento sobre o seu problema.. contudo posso de passar uns códigos para ordenar de forma correta as colunas clicadas (que ajuda muito ;) ).

Primeiro a Listview não interpreta de forma numérica, por isso a forma desordenada das colunas (principalmente quando é números); desta forma podemos declarar as colunas do cabeçalho em forma de .Tag (no procedimento Initialize) um exemplo :

Código: Selecionar todos

.columnHeaders.Add(, , "Nome", Width:=100).Tag = ""
.columnHeaders.Add(, , "Código", Width:=60, Alignment:=2).Tag = "number"
Acima informei a Tag "number" (números) e Tag "" (textos), mas você pode colocar também por data : Tag "date".

Agora abaixo os códigos para ordenar de forma correta (quando clicado no cabeçalho da coluna), você pode colocar no formulário OK ;) :

Código: Selecionar todos

Private Sub ListView1_ColumnClick(ByVal ColumnHeader As MSComctlLib.ColumnHeader)
    On Error Resume Next

    '    Começa ordenar o listview pela coluna clicada

    Dim vbHourglass
    With ListView1
        ' Mostrar o cursor ampulheta enquanto faz o filtro
        Dim lngCursor As Long
        lngCursor = .MousePointer
        .MousePointer = vbHourglass
        'A rotina impede que o controle ListView faça atualização na tela
        'Isto é para esconder as mudanças que estão sendo feitas aos listitems
        'E também para acelerar o código
        'Verifique o tipo de dados da coluna de ser classificada,
        'para nomeá-la em conformidade
        Dim l As Long
        Dim strFormat As String
        Dim strData() As String
        Dim lngIndex As Long
        lngIndex = ColumnHeader.Index - 1
        '***************************************************************************
        ' Ordenar por data.
        Select Case UCase$(ColumnHeader.Tag)
        Case "DATE"
            strFormat = "YYYYMMDDHhNnSs"
            'O Loop através dos valores desta coluna organizam
            'As datas de modo que eles possam ser classificados em ordem alfabética,
            With .ListItems
                If (lngIndex > 0) Then
                    For l = 1 To .Count
                        With .Item(l).ListSubItems(lngIndex)
                            .Tag = .Text & Chr$(0) & .Tag
                            If IsDate(.Text) Then
                                .Text = Format(CDate(.Text), _
                                                    strFormat)
                            Else
                                .Text = ""
                            End If
                        End With
                    Next l
                Else
                    For l = 1 To .Count
                        With .Item(l)
                            .Tag = .Text & Chr$(0) & .Tag
                            If IsDate(.Text) Then
                                .Text = Format(CDate(.Text), _
                                                    strFormat)
                            Else
                                .Text = ""
                            End If
                        End With
                    Next l
                End If
            End With
            ' Ordenar a lista em ordem alfabética por esta coluna
            .SortOrder = (.SortOrder + 1) Mod 2
            .SortKey = ColumnHeader.Index - 1
            .Sorted = True
            ' Restaura os valores anteriores das "células" nesta
            ' Coluna da lista das tags, e também restaura
            ' as tags para os valores originais
            With .ListItems
                If (lngIndex > 0) Then
                    For l = 1 To .Count
                        With .Item(l).ListSubItems(lngIndex)
                            strData = Split(.Tag, Chr$(0))
                            .Text = strData(0)
                            .Tag = strData(1)
                        End With
                    Next l
                Else
                    For l = 1 To .Count
                        With .Item(l)
                            strData = Split(.Tag, Chr$(0))
                            .Text = strData(0)
                            .Tag = strData(1)
                        End With
                    Next l
                End If
            End With
            
        '***************************************************************************
        'Ordenar Numericamente
        Case "NUMBER"
            strFormat = String(30, "0") & "." & String(30, "0")
            ' Loop através dos valores desta coluna. Ordena os valores de modo que eles
            ' Podem ser classificados em ordem
            With .ListItems
                If (lngIndex > 0) Then
                    For l = 1 To .Count
                        With .Item(l).ListSubItems(lngIndex)
                            .Tag = .Text & Chr$(0) & .Tag
                            If IsNumeric(.Text) Then
                                If CDbl(.Text) >= 0 Then
                                    .Text = Format(CDbl(.Text), _
                                        strFormat)
                                Else
                                    .Text = "&" & InvNumber( _
                                        Format(0 - CDbl(.Text), _
                                        strFormat))
                                End If
                            Else
                                .Text = ""
                            End If
                        End With
                    Next l
                Else
                    For l = 1 To .Count
                        With .Item(l)
                            .Tag = .Text & Chr$(0) & .Tag
                            If IsNumeric(.Text) Then
                                If CDbl(.Text) >= 0 Then
                                    .Text = Format(CDbl(.Text), _
                                        strFormat)
                                Else
                                    .Text = "&" & InvNumber( _
                                        Format(0 - CDbl(.Text), _
                                        strFormat))
                                End If
                            Else
                                .Text = ""
                            End If
                        End With
                    Next l
                End If
            End With
            ' Ordenar a lista em ordem alfabética por esta coluna
            .SortOrder = (.SortOrder + 1) Mod 2
            .SortKey = ColumnHeader.Index - 1
            .Sorted = True
            With .ListItems
                If (lngIndex > 0) Then
                    For l = 1 To .Count
                        With .Item(l).ListSubItems(lngIndex)
                            strData = Split(.Tag, Chr$(0))
                            .Text = strData(0)
                            .Tag = strData(1)
                        End With
                    Next l
                Else
                    For l = 1 To .Count
                        With .Item(l)
                            strData = Split(.Tag, Chr$(0))
                            .Text = strData(0)
                            .Tag = strData(1)
                        End With
                    Next l
                End If
            End With
        Case Else   ' Assume ordenação como string
            .SortOrder = (.SortOrder + 1) Mod 2
            .SortKey = ColumnHeader.Index - 1
            .Sorted = True
        End Select
        .MousePointer = lngCursor
    End With
       
   End Sub
OBS: Troque o nome da ListView1 que se encontra no código acima, pelo nome da sua ListView :) .

E para números negativos :

Código: Selecionar todos

'InvNumber
'Função usada para permitir que os números negativos possam ser classificados
'-----------------------------------------------------------------------------
Private Function InvNumber(ByVal Number As String) As String
    Static i As Integer
    For i = 1 To Len(Number)
        Select Case Mid$(Number, i, 1)
        Case "-": Mid$(Number, i, 1) = " "
        Case "0": Mid$(Number, i, 1) = "9"
        Case "1": Mid$(Number, i, 1) = "8"
        Case "2": Mid$(Number, i, 1) = "7"
        Case "3": Mid$(Number, i, 1) = "6"
        Case "4": Mid$(Number, i, 1) = "5"
        Case "5": Mid$(Number, i, 1) = "4"
        Case "6": Mid$(Number, i, 1) = "3"
        Case "7": Mid$(Number, i, 1) = "2"
        Case "8": Mid$(Number, i, 1) = "1"
        Case "9": Mid$(Number, i, 1) = "0"
        End Select
    Next
    InvNumber = Number
End Function
Espero que estes códigos possam te ajudar de alguma forma :) .

Abraços

LaerteB

Diovanino Cassio

10-10-2018 13:59:15

Valeu Laerte...!