[RESOLVIDO] Exportar sempre o ultimo arquivo

Guarino

23-03-2017 14:34:12

Boa tarde a todos!

Gostaria de uma ajuda de vocês e não sei se é muito complexo.

Criei uma rotina para atualizar um determinado relatório diariamente, os arquivos ficam em um diretório.

Macro para atualizar o relatório:

Sub ImportarDados()
Dim wsOrigem As Worksheet
Dim wsDestino As Worksheet
Workbooks.Open Filename:="P:\Exemplos.xlsx"
Set wsOrigem = Workbooks("Exemplos.xlsx").Worksheets("Sheet1")
Set wsDestino = Workbooks("puxar.xlsm").Worksheets("Sheet2")
With wsOrigem
Range("A2:B20000").Copy Destination:=wsDestino.Range("A2:B20000")
End With
Workbooks("Exemplos.xlsx").Close SaveChanges:=True
MsgBox "Importação de Dados Concluída"
End Sub

Porém eu quero que a macro puxe somente o ultimo arquivo dentro desse diretório, a TI disponibiliza esse arquivo diariamente e joga sempre na ultima linha. Teria como realizar esse ajuste para a macro sempre puxar o ultimo arquivo desse diretório e não um fixo.

Obrigado novamente a todos!!

Mikel Silveira Fraga

23-03-2017 16:25:43

Guarino, boa tarde.

Com certeza isso é possível sim, mas o arquivo precisa estar com o nome em um formato padronizado.

Nesse caso, pode utilizar a biblioteca Micrsoft Scripting Runtime. Veja o link abaixo:
- VBA – LISTAR ARQUIVOS DE UM DIRETÓRIO (Tomás Vásquez Blog)

Caso tenha dúvida sobre a adaptação, envie nova mensagem e iremos tirar as dúvidas.

Abraços e bons estudos.

Guarino

23-03-2017 18:30:37

Oi Mikel, boa tarde!

No diretório tem um padrão sim, esse seria o padrão, o nome do arquivo disponibilizado pela TI:

situacao_pedidos_20170321040001 --------> Disponibilizado pela TI em 21/03/2017 ás 04h
situacao_pedidos_20170321110001 --------> Disponibilizado pela TI em 21/03/2017 ás 11h
situacao_pedidos_20170321143001 --------> Disponibilizado pela TI em 21/03/2017 ás 14h
situacao_pedidos_20170322040000 --------> Disponibilizado pela TI em 22/03/2017 ás 04h
situacao_pedidos_20170322110001 --------> Disponibilizado pela TI em 22/03/2017 ás 11h
situacao_pedidos_20170322143001 --------> Disponibilizado pela TI em 22/03/2017 ás 14h
situacao_pedidos_20170323040001 --------> Disponibilizado pela TI em 23/03/2017 ás 04h
situacao_pedidos_20170323110001 --------> Disponibilizado pela TI em 23/03/2017 ás 11h
situacao_pedidos_20170323143001 --------> Disponibilizado pela TI em 22/03/2017 ás 14h

Obs: Amanhã a TI vai disponibilizar o arquivo "situacao_pedidos_20170324143001".

Em relação a adaptar a macro, poderia me ajudar a iniciar essa adaptação? Segundo o link que me encaminhou a macro correta seria essa:

Public Function ListaArquivos(ByVal Caminho As String) As String()
'Atenção: Faça referência à biblioteca Micrsoft Scripting Runtime
Dim FSO As New FileSystemObject
Dim result() As String
Dim Pasta As Folder
Dim Arquivo As File
Dim Indice As Long


ReDim result(0) As String
If FSO.FolderExists(Caminho) Then
Set Pasta = FSO.GetFolder(Caminho)

For Each Arquivo In Pasta.Files
Indice = IIf(result(0) = "", 0, Indice + 1)
ReDim Preserve result(Indice) As String
result(Indice) = Arquivo.Name
Next
End If

ListaArquivos = result
ErrHandler:
Set FSO = Nothing
Set Pasta = Nothing
Set Arquivo = Nothing
End Function

Estou um pouco perdido nas variáveis...

Mikel Silveira Fraga

25-03-2017 23:23:46

Guarino, boa noite.

Nesse caso, você pode adaptar esse código, para que retorne o maior arquivos, se fazendo uma comparação entre eles, vendo qual é > que o outro, em relação a nomenclatura. Por exemplo, podemos fazer a seguinte comparação:

Código: Selecionar todos

situacao_pedidos_20170321143001 é maior que situacao_pedidos_20170323110001
Dessa forma, poderemos identificar o último arquivo gravado no diretório.

Para que a função retorne esse arquivo, fiz as modificações que geraram o código abaixo:

Código: Selecionar todos

Option Explicit

Sub TesteRotina()
  MsgBox UltimoArquivo("F:\")
End Sub

Public Function UltimoArquivo(ByVal Caminho As String) As String
 'Atenção: Faça referência à biblioteca Micrsoft Scripting Runtime
 Dim FSO As New FileSystemObject
 Dim Pasta As Folder
 Dim Arquivo As File
 Dim Indice As Long

 If FSO.FolderExists(Caminho) Then
  Set Pasta = FSO.GetFolder(Caminho)

  For Each Arquivo In Pasta.Files
   If Arquivo.Name > UltimoArquivo Then UltimoArquivo = Arquivo.Name
  Next
  
 End If

ErrHandler:
 Set FSO = Nothing
 Set Pasta = Nothing
 Set Arquivo = Nothing
End Function
Com essas alterações, você conseguirá obter o resultado esperado.

Teste e nos retorne com os resultados.

Abraços e excelente final de semana.

Guarino

28-03-2017 13:03:31

Mikel, bom dia!

Copiei o código que me encaminhou e colei em um módulo, alterei o caminho em que o arquivo está que é ("U:\"), e executei a macro e ela apresentou o seguinte erro:

Option Explicit

Sub TesteRotina()
MsgBox UltimoArquivo("U:\")
End Sub

Public Function UltimoArquivo(ByVal Caminho As String) As String
'Atenção: Faça referência à biblioteca Micrsoft Scripting Runtime
Dim FSO As New FileSystemObject ' o tipo definido pelo usuário não foi definido
Dim Pasta As Folder
Dim Arquivo As File
Dim Indice As Long

If FSO.FolderExists("U:\") Then
Set Pasta = FSO.GetFolder("U:\")

For Each Arquivo In Pasta.Files
If Arquivo.Name > UltimoArquivo Then UltimoArquivo = Arquivo.Name
Next

End If

ErrHandler:
Set FSO = Nothing
Set Pasta = Nothing
Set Arquivo = Nothing
End Function

Muito obrigado pela ajuda e boa semana!

Mikel Silveira Fraga

29-03-2017 19:44:12

Guarino, boa tarde.

Você ativou a Biblioteca/Referência do Microsoft Scripting Runtime, conforme orientação no inicio do código?

É necessário ativação da mesma. No link posta em tópicos anteriores, ensina como ativá-la.

Abraços e excelente semana.

Guarino

05-04-2017 12:21:33

Mikel, bom dia!

Desculpa pela demora, com a alteração do site acabei perdendo a minha senha.



Realmente não havia ativado a Biblioteca/Referência do Microsoft Scripting Runtime, ativei como a orientação e ele buscou o ultimo arquivo corretamente.

Porém, quando crio a outra rotina para abrir esse arquivo encontrado, ele da a seguinte mensagem:

""Erro em temop de execução 1004: Não foi possivel encontrar situação_pedidos_20170405. É possível que ele tenha sido movido, renomeado ou excluído?""

Macro que estou usando para abrir esse arquivo encontrado:

Sub TesteRotina()
Workbooks.Open Filename:=UltimoArquivo("R:\")
End Sub

Poderia me ajudar a verificar se estou fazendo algo de errado?

Obrigado novamente!

Mikel Silveira Fraga

05-04-2017 19:46:12

Guarino, boa tarde.

Entendi. Achei que precisasse retornar apenas o nome do arquivo. Na realizada, você precisa que o endereço completo do mesmo seja retornado.

Neste caso, substitua a linha abaixo:

Código: Selecionar todos

If Arquivo.Name > UltimoArquivo Then UltimoArquivo = Arquivo.Name
Por esta aqui:

Código: Selecionar todos

If Arquivo.Name > UltimoArquivo Then UltimoArquivo = Arquivo.Path
Dessa forma, vai retornar o nome e endereço do arquivo, de forma que o Método Open do objeto Workbooks irá funcionar normalmente.

Dúvidas, é só postar aqui.

Abraços!!!

Guarino

05-04-2017 20:31:53

Mikel, boa tarde!

adaptei o que me mandou de:

If Arquivo.Name > UltimoArquivo Then UltimoArquivo = Arquivo.Path

Para:

If Arquivo.Path > UltimoArquivo Then UltimoArquivo = Arquivo.Path

E abriu o arquivo perfeitamente.

Gostaria de agradecer pela ajuda, acabou otimizando o processo de algumas áreas dentro da minha empresa.

Obrigado!!!