Verificar se impressora padrão está desligada

TARSA

24-05-2017 19:00:43

Olá pessoal,

Criei um userform que precisa avisar quando a impressora padrão está desligada e quando isso acontecer
coloquei uma label com o seguinte caption "Impressora desligada, verifique".

Alguém sabe como fazer?

Para tanto usei o seguinte código ao iniciar o formulário:

Private Sub UserForm_Initialize()


If Application.PrintCommunication = False Then

Me.Label3.Visible = True
Exit Sub
Else

Me.Label3.Visible = False

End If

End Sub

webmaster

25-05-2017 20:48:28

Não é algo muito trivial, mas isto pode dar uma ideia de como resolver o problema:

http://www.merrioncomputing.com/Program ... Status.htm
http://www.tomasvasquez.com.br/blog/mic ... computador

TARSA

30-05-2017 19:08:04

Muito obrigado,

Vou tentar adaptar.

TARSA

30-05-2017 23:21:46

Pessoal,

Resolvi esse problema adaptando uma função que achei na internet.

Function PROCURAENDERECO(ByVal Area As Range, ByVal Valor_Procurado As String)

If Not Area.Find(Valor_Procurado) Is Nothing Then
PROCURAENDERECO = Area.Find(Valor_Procurado).Address
Else
PROCURAENDERECO = CVErr(xlErrNA)
End If

End Function

** Depois de colocada em um módulo pode ser chamada na planilha e se a impressora estiver
DESLIGADA o resultado será (Verdadeiro ou True).

Espero que ajude alguém.

webmaster

31-05-2017 14:16:45

Valeu a indicacao do codigo! Tem o link da fonte para dar uma olhada?

TARSA

31-05-2017 18:23:26

Thomaz,

Se não me engano foi em um desses dois links que guardei no meu histórico que parti para a adaptação.

http://www.vbforums.com/showthread.php? ... -on-or-off

https://leegreffin.wordpress.com/2011/0 ... vba-macro/

TARSA

31-05-2017 18:47:39

Pessoal peço mil desculpas, a função de verificar se impressora está ON\OFF é a seguinte:

Public Function PrinterOffline(Optional pstrPrinter As String = "Default") As Boolean
Dim strWhere As String
Dim objWMI As Object
Dim objPrinters As Object
Dim objPrinter As Object

Set objWMI = GetObject("winmgmts:\\.\root\CIMV2")
If LCase$(pstrPrinter) = "default" Then
strWhere = "Default = True"
Else
strWhere = "Name = '" & pstrPrinter & "'"
End If
Set objPrinters = objWMI.ExecQuery("SELECT * FROM Win32_Printer WHERE " & strWhere)
For Each objPrinter In objPrinters
PrinterOffline = objPrinter.WorkOffline
Exit For
Next
Set objPrinter = Nothing
Set objPrinters = Nothing
Set objWMI = Nothing
End Function

webmaster

31-05-2017 20:11:15

Lindo! Voce permite que eu publique isso no blog?

TARSA

31-05-2017 21:46:01

Claro que sim, com maior prazer.
Lembrando que adaptei o código que enviei primeiro por engano, esse só implantei.

Abraços.

Basole

31-05-2017 23:17:42

Pra mim este codigo nao funcionou.
O que tenho usado é este:

Código: Selecionar todos

Sub Check_Printer_Status()
    Dim strComputer As String
    Dim objWMIService
    Dim colInstalledPrinters
    Dim objPrinter
    strComputer = "."
    Set objWMIService = GetObject("winmgmts:" _
                                  & "{impersonationLevel=impersonate}!\\" & strComputer & "\root\cimv2")
    Set colInstalledPrinters = objWMIService.ExecQuery _
                               ("Select * from Win32_Printer where Default = 'True'")
                               
    For Each objPrinter In colInstalledPrinters
        Select Case objPrinter.printerstatus
        Case 3
            MsgBox "A impressora está ociosa"
        Case 4
            MsgBox "Impressora esta imprimindo"
        Case 5
            MsgBox "A impressora está aquecendo"
        Case Else
            MsgBox "A impressora está desativada"
        End Select
    Next
End Sub 

webmaster

01-06-2017 15:20:00

Para mim ambas funcionaram! Agradeco aos dois pela colaboracao!

TARSA

01-06-2017 18:07:47

Legal seu código com os avisos. Vou testar caso precise implantar com MENSAGENS.

Valeu.

webmaster

03-06-2017 01:33:45

Está aí pessoal:

https://www.tomasvasquez.com.br/blog/mi ... -desligada

Esse é pra vocês! Obrigado por tudo!