[RESOLVIDO]Localizar dados na mesma linha da Planilha

milton

20-12-2017 01:53:23

Boa noite Pessoal!

Preciso de uma ajudinha,

Como fazer para localizar 2 ou 3 dados na mesma linha da Planilha e exibir um msgbox com outro dado também da mesma linha?

Ou seja, coloco um nome na Combobox, seleciono um OptionButton e ao clicar no botão faz a procura na Planilha, após localizar exibe a msgbox.

Alguém pode me ajudar?
Segue planilha em anexo.

Desde já muito obrigado!!!

Reinaldo

20-12-2017 13:23:33

Antes de mais nada, verifique a nomenclatura/descrição:
Entenda que --> Missinário e diferente de -->Missionário
Segue uma possibilidade, troque sua rotina de busca conforme abaixo

Código: Selecionar todos

Private Sub BtnLocalizar_Click()
Dim i As Integer
Dim Dco As String, Mno As String
Worksheets("Plan1").Select

If CbbIeamu = "" Then Exit Sub

For i = 3 To Cells(Cells.Rows.Count, "A").End(xlUp).Row
    
If OptDiaconato.Value = True Then
    If Plan1.Cells(i, 32).Value = CbbIeamu And Plan1.Cells(i, 33).Value = "Diácono" Or _
       Plan1.Cells(i, 32).Value = CbbIeamu And Plan1.Cells(i, 33).Value = "Diaconisa" Then
        If Dco = "" Then
            Dco = Cells(i, 4).Value
        Else
            Dco = Dco & "; " & Cells(i, 4).Value
        End If
    End If
ElseIf OptMissionarios.Value = True Then
    If Plan1.Cells(i, 32).Value = CbbIeamu And Plan1.Cells(i, 33).Value = "Missionário" Or _
       Plan1.Cells(i, 32).Value = CbbIeamu And Plan1.Cells(i, 33).Value = "Missionária" Then
        If Mno = "" Then
            Mno = Cells(i, 4).Value
        Else
            Mno = Mno & "; " & Cells(i, 4).Value
        End If
    End If
End If
Next
If Dco <> "" Then
    MsgBox "O nome do Diácono/Diaconisa é : " & Dco
ElseIf Mno <> "" Then
    MsgBox "O nome do Missionário/Missionária é: " & Mno
Else
    MsgBox "Dados não localizados!"
End If
End Sub

milton

20-12-2017 15:13:38

Reinaldo boa tarde!

Perfeito e desde já agradeço a sua ajuda, só tem um porém.
Necessito que o msgbox seja exibido com os nomes separadamente.

Ou seja, a busca localiza na Plan o primeiro nome 'Diaconisa Maria' exibi o msgbox Maria, clico em Ok prossegue a busca Localiza o segundo nome 'Diácono João' exibi o msgbox João e assim por diante caso haja outros nomes com Diacono e Diáconisa...

E essa mesma rotina será para Missionário e Missionária.

Reinaldo

21-12-2017 11:53:04

Código: Selecionar todos

Private Sub BtnLocalizar_Click()
Dim i As Integer
Dim Dco As Integer, Mno As Integer
Worksheets("Plan1").Select

If CbbIeamu = "" Then Exit Sub

For i = 3 To Cells(Cells.Rows.Count, "A").End(xlUp).Row
    
If OptDiaconato.Value = True Then
    If Plan1.Cells(i, 32).Value = CbbIeamu And Plan1.Cells(i, 33).Value = "Diácono" Or _
       Plan1.Cells(i, 32).Value = CbbIeamu And Plan1.Cells(i, 33).Value = "Diaconisa" Then
    
        MsgBox "O nome do Diácono/Diaconisa é : " & Cells(i, 4).Value
        Dco = Dco + 1
    End If
ElseIf OptMissionarios.Value = True Then
    If Plan1.Cells(i, 32).Value = CbbIeamu And Plan1.Cells(i, 33).Value = "Missionário" Or _
       Plan1.Cells(i, 32).Value = CbbIeamu And Plan1.Cells(i, 33).Value = "Missionária" Then
    
        MsgBox "O nome do Missionário/Missionária é: " & Cells(i, 4).Value
        Mno = Mno + 1
    End If
End If
Next
If Dco + Mno = 0 Then MsgBox "Dados não localizados!"
End Sub

milton

21-12-2017 16:23:59

Reinaldo era isso mesmo.
Muito obrigado pela ajuda!