Evento ListBox_Change

eferreiralima

29-01-2018 18:09:39

Prazados,

Estou criando um projeto vba, utilizando vários exemplos que encontro na internet, estou aprendendo na raça sobre programação, por isso o surgimento algumas duvidas que através de pesquisas não consigo sanar.

Criei neste projeto uma ListBox com o evento Change para que quando selecionando, os dados da planilha apareçam nos campos (TextBox, ComboBox...), mas ocorre um erro quando eu tento atualizar a ListBox com o comando ListBox.Clear.

se caso nenhum item da ListBox não estiver selecionando, o comando funciona bem, mas caso contrario, ocorre o seguinte erro: "Não foi possível obter a propriedade List. Índice de matriz de propriedade inválido." e a primeira linha do ListBox_change () fica amarelo.

O arquivo está anexado junto a este tópico para que alguém me dê uma luz :)

Reinaldo

29-01-2018 19:00:35

Não olhei seu modelo ainda, mas pelo relato, ao limpar a listbox o evento change e gerado assim a rotina que carrega seus textbox etc.. não encontra o registro selecionado.
Para evitar que aconteça é preciso tratar o código, verificando se há registro em seu listbox, ou utilizar outro evento para carregar seus outros controles. Por exemplo o evento click

srobles

29-01-2018 20:45:05

eferreiralima,

Substitua o código existente no evento Change do ListBox, para o que segue abaixo :

Código: Selecionar todos

Private Sub lst_registros_Change()
    'Se  o índice do item selecionado for diferente de -1 (sem itens na lista), então preencha os campos
    If lst_registros.ListIndex <> -1 Then

        Me.txt_cod.Value = lst_registros.List(lst_registros.ListIndex, 0)
        Me.cbo_rg.Value = lst_registros.List(lst_registros.ListIndex, 1)
        Me.txt_nome.Value = lst_registros.List(lst_registros.ListIndex, 2)
        Me.txt_empresa.Value = lst_registros.List(lst_registros.ListIndex, 3)
        Me.txt_placa.Value = lst_registros.List(lst_registros.ListIndex, 4)
        Me.txt_veiculo.Value = lst_registros.List(lst_registros.ListIndex, 5)
        Me.cbo_funcionario.Value = lst_registros.List(lst_registros.ListIndex, 6)
        Me.lab_data = lst_registros.List(lst_registros.ListIndex, 7)
        Me.lab_hora = lst_registros.List(lst_registros.ListIndex, 8)
        Me.txt_observacao.Value = lst_registros.List(lst_registros.ListIndex, 9)
        
        
            With Worksheets("reg_visitas").Range("A:A")
            Set c = .Find(txt_cod.Value, LookIn:=xlValues, LookAt:=xlPart) '
        
            If Not c Is Nothing Then
            c.Activate
            txt_cod.Value = c.Value
            
            End If
            End With
        
    End If
End Sub
Espero que atenda sua necessidade.

Abs

eferreiralima

30-01-2018 13:13:46

Funcionou perfeitamente.

vou continuar a montar este projeto, e com ele, aprendendo mais sobre esta ferramente incrível.

Muito agradecido à colaboração de vcs

eferreiralima

30-01-2018 18:36:45

Saulo,

A questão anterior foi resolvida, porem veio mais um probleminha neste mesto evento.

Fiz o comando abaixo para deixar a linha da planilha em foco, para editar o respectivo dado

With Worksheets("reg_visitas").Range("A:A")
Set c = .Find(txt_cod.Value, LookIn:=xlValues, LookAt:=xlPart) '

If Not c Is Nothing Then
c.Activate
txt_cod.Value = c.Value

End If
End With

o problema é que quando a planilha "regvisitas" está ativa, funciona normal, mas quando eu estou em outra planilha ou até mesmo quando oculto esta planilha, da erro.

srobles

30-01-2018 20:10:42

eferreiralima,

Nestes casos, o ideal é sempre apontar no código do evento que faz a busca, com qual planilha estamos trabalhando.

Código: Selecionar todos

With ThisWorkBook.Sheets("nomeplanilha")
   .Visible = True
   .Activate
   'Aqui fazemos a busca (.Find)
      With .Range("A:A")
      Set c = .Find(txt_cod.Value, LookIn:=xlValues, LookAt:=xlPart)

         If Not c Is Nothing Then
             c.Activate
             txt_cod.Value = c.Value
         End If
      End With
   'Caso queira ocultar novamente a planilha
   .Visible = xlVeryHidden
End With
Assim,ao selecionar um item na lista, obrigamos a exibição da planilha onde devemos buscar os dados.

Abs

eferreiralima

31-01-2018 12:43:16

Coloquei este codigo no botão de alteração e deu super certo.

Muito obrigado mais uma vez.