[RESOLVIDO] Erro com ListView

NayanaE

15-02-2018 17:57:49

Boa tarde, pessoal!

Preciso de uma ajuda.

Fiz uma ListView com checkbox na Planilha A, e nela são listadas as Worksheets da planilha B e ao selecionar os checkbox, os dados são copiados nas worksheets de mesmo nome na planilha A. :D

ERRO: A Listview está copiando todas as Worksheets, até mesmo as não marcadas.

Exemplo:
Planilha A (worksheets): Adm1, Adm2, Adm3, B1, B2, B3, C1, C2, C3, D1, D2 e D3.
Planilha B: B1, B2 e B3

Se eu selecionar somente a Worksheet "B3", o código copia tudo, copia B1, B2 e B3. Mesmo o B1 e B2 NÃO estando marcados na ListView.

Reinaldo

16-02-2018 11:52:58

Experimente alterar a rotina do btn Atualizar conforme abaixo

Código: Selecionar todos

'Botão de ATUALIZAR
Private Sub CommandButton2_Click()
'Variavel para armazenarmos quais abas deverão ser manipuladas
Dim abasImportadas() As String
Dim Arquivo_atual As Workbook, Arquivo_importacao As Workbook
Dim Guia_Selecionada As Worksheet
Dim k As Integer, i As Integer

Application.ScreenUpdating = False
    
Set Arquivo_atual = ActiveWorkbook
    
'Abre o arquivo excel da planilha que você quer importar os dados
Set Arquivo_importacao = Workbooks.Open(Filename:=form_importa.txt_arquivo)
    
k = 0
    
For i = 1 To ListView1.ListItems.Count
    If Me.ListView1.ListItems.Item(i).Checked = True Then
        ReDim Preserve abasImportadas(k)
        abasImportadas(k) = ListView1.ListItems.Item(i).Text
        k = k + 1
    End If
Next i
                          
For k = LBound(abasImportadas) To UBound(abasImportadas)
    Set Guia_Selecionada = Arquivo_importacao.Worksheets(abasImportadas(k))
    Guia_Selecionada.Cells.Copy Arquivo_atual.Worksheets(abasImportadas(k)).Cells
Next

Application.CutCopyMode = False
    
Arquivo_importacao.Close
Unload Me
MsgBox ("Guia(s) atualizada(s) com sucesso!"), vbInformation
        
Application.ScreenUpdating = True
    
End Sub

NayanaE

16-02-2018 13:27:31

Bom dia Reinaldo!!

Funcionou sim, muito obrigada!!! :D