Filtrar o listview com condição [RESOLVIDO]

lima27

05-03-2018 09:27:20

Olá pessoal,

Confesso que nunca trabalhei com listview, mas comecei a dar os primeiros passos.
Estou com uma dificuldade, consegui fazer a listview carregar na abertura do meu formulário, mas ainda não sei como fazer com que ela seja carregada obedecendo a uma condição, como se fosse um filtro.

Tenho uma tabela:
DATA | VALOR | STATUS DO PEDIDO | CÓD CLIENTE

Quando dou um duplo clique na linha, os dados são carregados para um formulário que abre imediatamente com os dados clicados.
Abaixo do formulário eu incluí um listview que eu gostaria que exibisse apenas os lançamentos cujo CÓD CLIENTE seja igual ao do lançamento clicado.
Atualmente o listview carrega com todos os lançamentos da planilha, ou seja, sem nenhuma distinção.

Minha intenção: no evento UserForm_Initialize, ele captura o CÓD CLIENTE e utilize esse dado para carregar dentro da listview apenas os lançamentos cujo CÓD CLIENTE seja igual.

Eis as linhas do código:

Código: Selecionar todos

Option Explicit
Private linha As Long
Private varcod As String

Private Sub UserForm_Initialize()

linha = ActiveCell.Row
varcod = Cells(LINHA, 3)

With Me.ListView1
  .Gridlines = True
  .HideColumnHeaders = False
  .View = lvwReport
End With

  Call PopularListView
  
End Sub
Em seguida:

Código: Selecionar todos

Private Sub PopularListView()

    Dim wksOrigem As Worksheet
    Dim rData As Range
    Dim rCell As Range
    Dim LstItem As ListItem
    Dim linCont As Long
    Dim colCont As Long
    Dim v As Long
    Dim m As Long
   
    Set wksOrigem = Worksheets("Pedidos")
    
    Set rData = wksOrigem.Range("A1").CurrentRegion
    
    For Each rCell In rData.Rows(1).Cells
        Me.ListView1.ColumnHeaders.Add Text:=rCell.Value, Width:=90
    Next rCell
    
    'Alimentar variável linCont com número de linhas do intervalo fonte
    linCont = rData.Rows.Count
    
    'Alimentar variável colCont com número de colunas do intervalo fonte
    colCont = rData.Columns.Count

    For v = 2 To linCont
        Set LstItem = Me.ListView1.ListItems.Add(Text:=rData(v, 1).Value)
        For m = 2 To colCont
            LstItem.ListSubItems.Add Text:=rData(v, m).Value
        Next m
    Next v
    
End Sub
Alguém poderia me ajudar a evoluir nessa questão?
Desde já muito obrigado!!

Reinaldo

05-03-2018 12:03:03

uma possibilidade:

Código: Selecionar todos

...For v = 2 To linCont
        if seutxtcodigo=suacelulacomcodigo then
        Set LstItem = Me.ListView1.ListItems.Add(Text:=rData(v, 1).Value)
        For m = 2 To colCont
            LstItem.ListSubItems.Add Text:=rData(v, m).Value
        Next m
        end if
    Next v....

lima27

05-03-2018 14:18:13

Reinaldo, funcionou perfeitamente.
Não acredito, como não pensei nisso. Acho que tentei complicar algo que era simples. =)
Muito obrigado!!

Antes de terminar, gostaria de fazer uma pergunta, para trabalhar com o listview, tenho que habilitar a Referencia "Microsoft Windows Common Controls 6.0 (SP6)".
Tenho que ativar isso manualmente em todo computador que for utilizar a planilha? Ou tem como automatizar essa ativação?

Um abraço,
Reinaldo escreveu: ↑Seg Mar 05, 2018 9:03 am uma possibilidade:

Código: Selecionar todos

...For v = 2 To linCont
        if seutxtcodigo=suacelulacomcodigo then
        Set LstItem = Me.ListView1.ListItems.Add(Text:=rData(v, 1).Value)
        For m = 2 To colCont
            LstItem.ListSubItems.Add Text:=rData(v, m).Value
        Next m
        end if
    Next v....