Criar planilha para envio em e-mail [Resolvido]

Ana Laura

20-10-2010 14:08:26

bom dia a todos!

Estou com um problema, tenho uma planilha de cotação. A mesma possuí várias "abas". Até aí ok.

1- Eu preciso de um código que gere uma cópia da planilha ativa (detalhe, somente valores, ela tem fórmulas e quero que vá somente os valores na cópia).

2- Essa nova planilha deve ser salva em uma outra pasta específica, e deve ser nomeada com o valor de uma célula da planilha. Ex: no B2 tem Ana Laura, a planilha nova deve chamar Ana Laura.

É possível?

Esse dois itens acima são prioridades.

Agora uma perfumaria.
Essa planinha nova (chamada acima, com exemplo de Ana Laura) deve ser anexada em um e-mail (outlook) com o assunto e texto fixos.

Alguém pode me orientar????

Obrigada!

webmaster

20-10-2010 17:18:37

Ana,

Praticamente todas as respostas as essas perguntas foram respondidas em outros fóruns. Use o mecanismo de busca para encontrá-las. Na falta delas, voltamos a falar.

Abraços

webmaster

21-10-2010 13:21:31

Ana,

Mantenha a conversa no mesmo tópico. Não abra outros, a não ser que assunto tratado mude. Assim deixamos o fórum mais organizado.

Abraços

Ana Laura

22-10-2010 10:11:20

Bom dia!

Eu só abri um novo tópico pq não achei o q procuro nos demais tópicos.

Pode me direcionar?

Obrigada!

Mauro Coutinho

22-10-2010 14:31:04

Ana, as rotinas abaixo, copia a planilha Ativa para uma nova, renomeando de acordo com o nome na Celula B2 e sem as formulas, copie as mesmas para um modulo e teste :

Código: Selecionar todos

Public delShts

Sub NovaPlanilhaSemFormulas()
Dim wshPlan As Worksheet
Dim i As Integer
Dim DelNome As Worksheet

Application.ScreenUpdating = False

Application.DisplayAlerts = False

On Error Resume Next

'Nome na Sheet Ativa em B2
delShts = CStr(ActiveSheet.Range("B2").Value)

Set DelNome = Sheets(delShts)
    
            'Se já existir deleta antes de criar
            MyNewSheet delShts
                
                'Conta qde de Planilhas
                i = Worksheets.Count
                
                'Define o novo nome
                newSht = delShts
                    
                ActiveSheet.Copy after:=Worksheets(i)
                i = i + 1
                
                Set wshPlan = Worksheets(i)
                
                On Error Resume Next
        
        'Copia a Planilha Ativa e cola sem as formulas
        With wshPlan.UsedRange
            .Copy
            .PasteSpecial Paste:=xlValues
        End With
        
        Application.CutCopyMode = False

    'Renomeia a planilha nova
    With wshPlan
            .Name = newSht
            .Range("A1").Select
    End With

End Sub

'Deleta a planilha antiga
Sub MyNewSheet(SheetName)
    Application.DisplayAlerts = False
    On Error Resume Next
    Worksheets(SheetName).Delete
End Sub
Quanto a parte de envio de email, pelo sistema de BUSCA do Forum, temos alguns tópicos, é só pesquisar por Enviar Email e encontrará varios outros.

Enviar e-mail através do excel
viewtopic.php?f=5&t=287&p=1764&hilit=enviar+email#p1764

Incluir compromisso e anexo em conta do Outllook Externo
viewtopic.php?f=6&t=372&p=2240&hilit=enviar+email#p2240

Enviar email sem uso do Outlook
viewtopic.php?f=6&t=423&p=2549&hilit=enviar+email#p2549

[]s

Ana Laura

22-10-2010 15:54:25

boa tarde Mauro,

obrigada pela resposta, o código funcionou, porém um detalhes. Eu preciso que seja criado um novo arquivo e não uma nova pasta e mais um detalhe, tenho dois botoes nessa planilha, gostaria que eles não aparececem na nova planilha.

Pode me ajudar mais uma vez?????

Obrigada mesmo!!

webmaster

22-10-2010 16:34:52

Ops!

Estava construindo outra solução quando o Mauro respondeu a questão. De qualquer forma, a macro abaixo cria uma nova planilha e copia somente os valores desta, sem fórmulas:

Código: Selecionar todos

Sub CopiaSomenteConteudo()
    Dim NewSheet As Worksheet, CurrentSheet As Worksheet
    'pega a planilha atual
    Set CurrentSheet = ActiveSheet
    'cria uma nova planilha
    Set NewSheet = ThisWorkbook.Worksheets.Add
    NewSheet.Name = CurrentSheet.Name & "2"
    'copia todas as células da planilha ativa
    CurrentSheet.Cells.Copy
    'cola só os valores na nova planilha
    NewSheet.Range("A1").PasteSpecial Paste:=xlPasteValues, Operation:=xlNone, SkipBlanks:=False, Transpose:=False
    'zera os objetos
    Set NewSheet = Nothing
    Set CurrenSheet = Nothing
End Sub
Neste caso, como não houve a cópia da planilha, objetos como imagem e botões não são trazidos.

Abraços

Mauro Coutinho

22-10-2010 22:43:52

Ana, veja se seria isso, aproveitei parte da rotina do Tomas e fiz outra adaptação.

Só não se esqueça de alterar o Caminho aonde será salva a nova Pasta.

Código: Selecionar todos

Sub NovaPastaSemFormulas()

Dim CurrentSheet As Worksheet

    Application.ScreenUpdating = False

    'Nome na Sheet Ativa em B2
    nomeB2 = CStr(ActiveSheet.Range("B2").Value)

    Set CurrentSheet = ActiveSheet
                
    On Error Resume Next
        
    'copia todas as células da planilha ativa
    CurrentSheet.Cells.Copy
        
    'Cria a Nova PASTA (ARQUIVO)
    Set Wkb = Workbooks.Add
       
    'cola somente os valores na planilha Ativa da nova Pasta
    ActiveSheet.Range("A1").PasteSpecial Paste:=xlPasteValues, Operation:=xlNone, SkipBlanks:=False, Transpose:=False
        
    Application.CutCopyMode = False
        
    'Define os Novos Nomes - Planilha(ABA) e Pasta(Arquivo)
    novoNome = nomeB2
 
    'Renomeia a planilha nova com
    'o Nome que estava em B2
    With ActiveSheet
        .Name = novoNome
        .Range("A1").Select
    End With

    Range("A1").Select
    
    'Enibe a mensagem se a pasta já existir
    'Com essa instrução a Pasta será substiutida sem questionamento
    Application.DisplayAlerts = False
    
    'Salva a Nova Pasta com o mesmo Nome
    Wkb.SaveAs Filename:="E:\EXCEL FORUN\TOMAZ\Ana\" & novoNome & ".xls"

End Sub
[]s

Ana Laura

27-10-2010 12:30:49

Bom dia Mauro,

Muito ótimo, o código, o nome e o caminho estão funcionando perfeitamente mas, ainda me falta um detalhe... essa planilha copiada tem um layout que deve ser preservado.
Desta forma a nova planilha vem sem a configuração da outra.

Muito obrigada por todo o apoio, a macro está perfeita. Pode ajustar só mais esse detalhe por gentileza?


Muitoooo obrigada mesmo!

Ana Laura

27-10-2010 13:00:35

Bom dia novamente!

Obrigada mais uma vez pelo apoio, eu já consegui ajustar para a minha necessidade o que voces montaram. Muito obriagda!

Mauro Coutinho

27-10-2010 13:02:05

Ana, se está se referindo as formatações, efetue a seguinte alteração na rotina acima :

Código: Selecionar todos

'Substitua esta linha
'ActiveSheet.Range("A1").PasteSpecial Paste:=xlPasteValues, Operation:=xlNone, SkipBlanks:=False, Transpose:=False

'Por esta
    With ActiveSheet.Range("A1")
        .PasteSpecial Paste:=xlPasteValues, Operation:=xlNone, SkipBlanks:=False, Transpose:=False
        .PasteSpecial Paste:=xlFormats
    End With
[]s

BrunoCarvalho

29-08-2015 13:50:40

Bom dia.

Desculpem eu ressuscitar o artigo, porem eu consigo adaptar este código para salvar as células ativas e encaminhar via e-mail diretamente, hoje eu estou trabalhando com o código abaixo, porem tenho que atualizar a célula para que seja enviada o e-mail.

Código: Selecionar todos

Private Sub Worksheet_Change(ByVal Target As Range)
    Dim OutApp As Object
    Dim OutMail As Object
    Dim texto As String
    Dim hora As Date
    
            
            
    Set OutApp = CreateObject("Outlook.Application")
    
    Set OutMail = OutApp.CreateItem(0)
    
    hora = -0.416666666666667
                        
    linha = ActiveCell.Row - 1
    
    If Target.Address = "$J$" & linha Then

        If Plan3.Cells(linha, 10) <> "0,208333333333333" Then
        
            texto = "Prezados(a)" & vbCrLf & vbCrLf & _
                    "O Condutor da Frota " & Plan3.Cells(linha, 2) & " - " & Plan3.Cells(linha, 3) & ", está com sua jornada prestes a exceder, " & _
                    " veja informações abaixo:" & vbCrLf & vbCrLf & _
                    "Jornada atual: " & Plan3.Cells(linha, 8) & vbCrLf & _
                    "Jornada restante: " & Plan3.Cells(linha, 10) - hora + hora & vbCrLf & vbCrLf & _
                    "Atenciosamente - Controle de Jornada," & vbCrLf & vbCrLf & vbCrLf & _
                    "Grupo Gelog - Este email está em periodo de testes, estamos adaptando para melhorar a informação."
                    
        End If
        
        With OutMail
            
            .To = ""
            .CC = "
            .BCC = ""
            .Subject = "( TESTE ) Controle de Jornada - " & Plan3.Cells(linha, 3)
            .Body = texto
            .Send
            
        End With
        
        On Error GoTo 0

        Set OutMail = Nothing
        Set OutApp = Nothing
        
        End If
        
End Sub