VBA numeros

Djeison Lindemann

25-07-2018 18:27:57

Boa Tarde. Minha duvida é o seguinte.

Alguém pode me ajudar ??

Tenho esses valores, 20.289207.1.1.77
1.371033.1.1.30
2.6357.1.1.47
20.22361.1.1.104
2.690.1.2.36


Eu precisava que eles ficasse todos com o mesmo numero de caracteres.
20.289207.01.01.0077
01.371033.01.01.0030
02.006357.01.01.0047
20.022361.01.01.0104
02.000690.01.02.0036

Seria um código que eu tenho, porém precisaria que esses ficassem com o mesmo numero de caracteres, como exemplo abaixo.

Se conseguir fazer uma macro para quando abrir ela ja fazer esse acerto, pode substituir a coluna existente, ou criar uma nova ao lado.

Agradeço se puderem me ajudar.

Reinaldo

25-07-2018 19:24:37

Uma possibilidade:
Copie a função abaixo em um modulo noeditor VBE

Código: Selecionar todos

Function IncluiZero(rng As Range, strvArray As String)
Dim vArray
Application.Volatile
vArray = Split(rng, strvArray)
If Len(vArray(0)) < 2 Then vArray(0) = Application.WorksheetFunction.Rept("0", 2 - Len(vArray(0))) & vArray(0)
If Len(vArray(1)) < 6 Then vArray(1) = Application.WorksheetFunction.Rept("0", 6 - Len(vArray(1))) & vArray(1)
If Len(vArray(2)) < 2 Then vArray(2) = Application.WorksheetFunction.Rept("0", 2 - Len(vArray(2))) & vArray(2)
If Len(vArray(3)) < 2 Then vArray(3) = Application.WorksheetFunction.Rept("0", 2 - Len(vArray(3))) & vArray(3)
If Len(vArray(4)) < 4 Then vArray(4) = Application.WorksheetFunction.Rept("0", 4 - Len(vArray(4))) & vArray(4)

IncluiZero = vArray(0) & "." & vArray(1) & "." & vArray(2) & "." & vArray(3) & "." & vArray(4)
End Function
Supondo que seus dados iniciem em A2, em B2=IncluiZero(A2;".")
Copie arraste para as demais

Djeison Lindemann

25-07-2018 20:10:42

Obrigado pela retorno.

Os dados são da coluna V 2.

Vai corrigir na mesma coluna ? ou vai gravar em outra coluna ? se gravar em outra precisa ser na coluna AK2.

Valeu....

webmaster

25-07-2018 21:41:58

Ops.. já estava com o código em andamento. Pensei em algo mais nesta linhaÇ

Espero que ajude:

Código: Selecionar todos

Function CrazyFormat(valor As String, formato As String)
    valorQuebrado = Split(valor, ".")
    formatoQuebrado = Split(formato, ".")
    Dim resultado()
    ReDim resultado(UBound(valorQuebrado))

    For i = LBound(valorQuebrado) To UBound(valorQuebrado)
        resultado(i) = Format(valorQuebrado(i), formatoQuebrado(i))
    Next
    
    CrazyFormat = Join(resultado, ".")
End Function

Sub Teste()
    MsgBox CrazyFormat("2.6357.1.1.47", "00.000000.00.00.0000")
End Sub

Djeison Lindemann

26-07-2018 12:07:32

Obrigado pessoal,, Funcionou, as duas