Preencher TXT a partir de Matriz Variável

Adonias

28-05-2020 13:52:35

Bom dia pessoal,
Estou precisando preencher um arquivo txt com dados de uma coluna, apenas, do excel e no txt também terá só uma coluna.
Acontece que os valores dessa coluna estarão numa Array variável e não na coluna mesmo.

Esclarecendo
A única coluna que mostra valores será a coluna A
a partir dela o código cria a coluna B só que não coloca na coluna B, mas sim na matriz.
Eu quero preencher meu txt com dados dessa matriz.

Exemplo

Coluna A
11.111.111/0001-11
22.222.222/0002-22

o código retira a formatação desses números e coloca na matriz apenas
11111111000111
22222222000222
e conclui criando um arquivo txt apenas com os dados obtidos.
Só que o numero de itens poderá variar sempre

Reinaldo

30-05-2020 15:14:50

Talvez com um modelo do que é vs o que espera fique mais simples e obtenha um retorno que lhe auxilie

Adonias

31-05-2020 10:41:59

Ok, Reinaldo
Veja, meu objetivo é não ter que gerar na planilha qualquer coluna além a coluna A e para isso, pensei que uma matriz resolvesse.
Olha só de que se trata: eu terei uma relação de CNPJ que irão variar de quantidades, podendo ser mais de 1000 por lote.
Eu preciso criar uma pasta para cada CNPJ que recebo, elas serão temporárias que concluo o meu trabalho eu as deleto então não tenho problemas com espaço.
Essa foi a solução mais viável que encontrei de criar essas pastas automaticamente: recebo a relação de CNPJ, copio e colo na célula A1 e gero o arquivo bat que depois é só executar e as pastas serão criadas.

Outra coisa que queria implementar era fazer com que o inputbox que é chamado para o usuário inserir o caminho onde quer salvar o arquivo, abrisse a pasta "salvar como". Daé depois de escolhido o local ele precisaria digitar apenas o nome do arquivo e o codigo além de tudo salvaria o caminho no defaut do inputbox e clicando em OK, seguiria o código e enviaria esse endereço com o nome do arquivo para ficar registrado na célula E1, módulo invisível. Pensei tb em enviar para uma variável, mas não consegui. O objetivo era sempre que o usuário chegasse nesse inputbox ele já viesse preenchido o defaut com o caminho onde ele salvou anteriormente e ele mudaria só o nome do arquivo.

Então é isso: quero retirar os caracteres dos CNPJ, acrescentar o comando Make Directory(MD) que gerará as pastas e salvar arquivo bat no endereço escolhido.
aqui está onde consegui chegar aproveitando códigos de macros já trabalhadas aqui no site.

A propósito Reinaldo, poderia me ensinar a colocar a palavra [Resolvido] aqui nao site quando encontramos antes do tópico?

segue modelo e obrigado

Reinaldo

31-05-2020 17:37:26

Veja no anexo se está em linha com o que espera/demanda

Adonias

01-06-2020 01:18:58

Reinaldo, ficou excelente meu amigo. Como sempre você arrasa. Espero um dia chagar a pelo menos 20% do seu conhecimento em VBA.
E quanto a colocar a Palavra Resolvido no Tópico, como procedo?

Reinaldo

01-06-2020 13:11:11

Boa Pergunta, em todos os fóruns que participo/participei nunca me preocupei com isso.
Porem acredito que deva ser editado manualmente o titulo do tópico e acrescentado a palavra/termo desejado

Adonias

04-06-2020 15:18:14

Reinaldo, para concluir minha planilha eu queria acrescentar algo mais.
O meu sistema anexa arquivos que estarão em cada pasta criada por esse código.
Os arquivos serão colocados em cada pasta pelo usuário, só que existem uns 10 arquivos que deverão estar em todas essas pastas.
Eu os mantenho na pasta C:\Temp. Como faria para acrescentar essa rotina ao codigo para ele verificar a pasta Temp, copiar todos os arquivos e colar em todas as pastas que foram criadas no código?

Reinaldo

04-06-2020 17:28:37

Veja em https://www.rondebruin.nl/win/s3/win026.htm como copiar pastas ou arquivos e tente adaptar a sua realidade
chame a rotina para copiar +/- neste local

Código: Selecionar todos

...        If fsoLocal.FolderExists(strPath) Then
        Else
            fsoLocal.CreateFolder (Caminho & NomeDir)
            Copy_Folder
        End If
...

Adonias

06-06-2020 15:07:10

Reinaldo eu já tinha vistos todos os exemplos dessa página, mas todos eles focal apenas numa pasta. Eu quero copiar todos os arquivos de uma pasta, isso o código faz tranquilamente, e quero salvar todos em cada uma das pastas dentro de um diretório escolhido, isso o código dessa pasta não faz.

acho que tem de ter um loop e não estou conseguindo.

Reinaldo

08-06-2020 13:47:42

Ao criar a nova pasta
"...fsoLocal.CreateFolder (Caminho & NomeDir)..."
logo a seguir insira o codigo/rotina para copiar/colar pasta/arquivo
" fsoLocal.CreateFolder (Caminho & NomeDir)
Copy_Folder to caminho & NomeDir
end if"

Adonias

20-06-2020 00:48:59

Reinado, tentei de tudo, mas não tenho tanto conhecimento ainda.
Entrei no fórum do mrexcel, mas um membro me deu uma dica pelos comando dir, só que complicou ainda mais.
Não consegui.
Quem puder ajudar, por favor.

Reinaldo

21-06-2020 01:40:31

Experimente

Código: Selecionar todos

Dim NovaPasta As String
Private Sub CriarCaminho()
'Obtem o diretorio a ser salvo
With Application.FileDialog(msoFileDialogFolderPicker)
        If .Show = -1 Then ' if OK is pressed
            NovaPasta = .SelectedItems(1)
        Else
            MsgBox ("Nenhum diretorio selecionado, será mantido o diretorio inicial")
        End If
End With
End Sub

Private Sub btCriar_Click()
Dim Linha As Long
Dim NomeDir As String, Caminho As String
Dim strTemp As String, strPath As String
Dim fsoLocal As Object
Dim msgResp As VbMsgBoxResult

strTemp = Cells(1, "AA").Value
If strTemp <> "" Then msgResp = MsgBox("O Diretorio Atual é:" & strTemp & " Deseja mante-lo??", vbYesNo)
If msgResp <> 6 Then CriarCaminho
If strTemp <> "" And NovaPasta = "" Then
    Caminho = strTemp
ElseIf NovaPasta <> "" Then
    Caminho = NovaPasta
    Cells(1, "AA").Value = NovaPasta
End If
Set fsoLocal = CreateObject("scripting.filesystemobject")
'Inicia o loop na linha 1 da coluna "A" (1) - Altere se necessario
For Linha = 1 To Range("A1").End(xlDown).Row
    If VBA.Right(Caminho, 1) <> "\" Then Caminho = Caminho & "\"
    NomeDir = VBA.Replace(VBA.Replace(VBA.Replace(Cells(Linha, 1).Value, "/", ""), ".", ""), "-", "")
    If VBA.Right(NomeDir, 1) <> "\" Then NomeDir = NomeDir & "\"
    strPath = Caminho & NomeDir
    If fsoLocal.FolderExists(strPath) Then
    Else
        fsoLocal.CreateFolder (Caminho & NomeDir)
        CopyFilesInFolder (Caminho & NomeDir)
    End If
Next
End Sub

Private Sub btLimpar_Click()
Range("A1:d1").Select
Range(Selection, Selection.End(xlDown)).Select
Selection.ClearContents
Range("A1").Select
Range("a1").Value = "Cole Aqui"
Range("a1").HorizontalAlignment = xlCenter
End Sub

Private Function CopyFilesInFolder(Byval Destino as string)
'https://www.rondebruin.nl/win/s3/win026.htm
'This example copy all Excel files from FromPath to ToPath.
'Note: If the files in ToPath already exist it will overwrite
'existing files in this folder
Dim FSO As Object
Dim FromPath As String
Dim ToPath As String
Dim FileExt As String
'Diretorio/Pasta de Origem
FromPath = "C:\Temp"  '<< Altere se necessario
'Diretorio/pasta de Destino    
ToPath = Destino

'Seleciona/determina arquivo
'You can use *.xl* for Excel files or *.doc for Word files
'"*.*" for All Files
FileExt = "*.*"  '<< Altere quando necessario

If Right(FromPath, 1) <> "\" Then FromPath = FromPath & "\"

Set FSO = CreateObject("scripting.filesystemobject")
'Se pasta de origem não for encontrada exibe mensagem e sai da rotina
If FSO.FolderExists(FromPath) = False Then
   MsgBox FromPath & " doesn't exist"
   Exit function
End If
'Se pasta de destino não for encontrada exibe mensagem e sai da rotina
If FSO.FolderExists(ToPath) = False Then
   MsgBox ToPath & " doesn't exist"
   Exit function
End If

    FSO.CopyFile Source:=FromPath & FileExt, Destination:=ToPath
   ' MsgBox "Os Arquivos de " & FromPath & " foram copiados para " & ToPath
End Function

Adonias

23-06-2020 08:54:40

Reinaldo, mais uma vez você foi brilhante.
Era exatamente o que eu precisava, MUITO OBRIGADO!!
e até a próxima, pois o aprender nunca finda.

Adonias

05-08-2020 01:58:30

Reinaldo, tentei de tudo, mas não consigo copiar para dentro das pastas criadas.
Cria as pastas e copia todos os arquivos da origem dentro da pasta principal de destino, mas nao dentro das pastas criadas nessas pasta principal.

Poderia dizer onde está o erro?

Reinaldo

06-08-2020 13:11:32

Sem testar experimente

Código: Selecionar todos

Private Sub btCriar_Click()
Dim Linha As Long
Dim NomeDir As String, Caminho As String
Dim strTemp As String, strPath As String
Dim fsoLocal As Object
Dim msgResp As VbMsgBoxResult

strTemp = Cells(1, "AA").Value
If strTemp <> "" Then msgResp = MsgBox("O Diretorio Atual é:" & strTemp & " Deseja mante-lo??", vbYesNo)
If msgResp <> 6 Then CriarCaminho
If strTemp <> "" And NovaPasta = "" Then
    Caminho = strTemp
ElseIf NovaPasta <> "" Then
    Caminho = NovaPasta
    Cells(1, "AA").Value = NovaPasta
End If
Set fsoLocal = CreateObject("scripting.filesystemobject")
'Inicia o loop na linha 1 da coluna "A" (1) - Altere se necessario
For Linha = 1 To Range("A1").End(xlDown).Row
    If VBA.Right(Caminho, 1) <> "\" Then Caminho = Caminho & "\"
    NomeDir = VBA.Replace(VBA.Replace(VBA.Replace(Cells(Linha, 1).Value, "/", ""), ".", ""), "-", "")
    If VBA.Right(NomeDir, 1) <> "\" Then NomeDir = NomeDir & "\"
    strPath = Caminho & NomeDir
    If fsoLocal.FolderExists(strPath) Then

    Else
        fsoLocal.CreateFolder (Caminho & NomeDir)
        Copy_Folder (Caminho & NomeDir)
    End If
Next
End Sub
Private Sub Copy_Folder(ByVal strLocal As String)
'Este exemplo copia todos os arquivos da subpasta FromPath to ToPath.
'Note: If ToPath already exist it will overwrite existing files in this folder
'if ToPath not exist it will be made for you.
Dim FSO As Object
Dim FromPath As String
Dim ToPath As String

FromPath = "C:\Users\ADONIAS\Downloads\VBA\Model\"  '<< Change

If strLocal <> "" Then
    ToPath = strLocal
Else
    ToPath = "C:\Users\ADONIAS\Downloads\VBA\ModelOne\"    '<< Change
End If
If Right(FromPath, 1) = "\" Then
    FromPath = Left(FromPath, Len(FromPath) - 1)
End If

If Right(ToPath, 1) = "\" Then
    ToPath = Left(ToPath, Len(ToPath) - 1)
End If

Set FSO = CreateObject("scripting.filesystemobject")

If FSO.FolderExists(FromPath) = False Then
    MsgBox FromPath & " doesn't exist"
    Exit Sub
End If

FSO.CopyFolder Source:=FromPath, Destination:=ToPath
MsgBox "Você pode encontrar os arquivos da Subpasta " & FromPath & " Em " & ToPath
End Sub

Adonias

06-08-2020 15:55:59

Reinaldo, agora funcionou direitinho. Muito obrigado
Estou muito empolgado com VBA e cada dia aprendendo mais coisas aqui com Vocês.
Estou e