Carregar Listview com banco de dados

pedro_mexico

29-08-2022 23:02:21

Boa noite amigos do forum,

tenho um problema com um codigo que nao estou a perceber a logica do erro que dá, e precisava de uma ajuda.
tenho um formulario que estou agora a tentar juntar um banco de dados em Access.

atraves de ajudas da internet, criei um um codigo
de conexao:

Código: Selecionar todos

Public Conexao As ADODB.Connection
Public Rs As ADODB.Recordset

Sub ConectarBD()
On Error GoTo Error

Dim strConexao As String
Dim CaminhoBanco As String
Set Conexao = New ADODB.Connection

CaminhoBanco = ThisWorkbook.Path & "\Mapa Viaturas menus NOVOs 2022 teste-com BaseDados.mdb"

Conexao.Open "Provider=Microsoft.ACE.OLEDB.12.0;Data Source= " & _
                     CaminhoBanco & ";Persist Security Info=False;"
Exit Sub
Error:

End Sub
e desconectar:

Código: Selecionar todos

Sub DesconectarBD()

If Not Conexao Is Nothing Then

    Conexao.Close
    Set Conexao = Nothing
End If
End Sub
e agora queria que a listview que tenho carregasse com os valores do banco de dados, o codigo é:

Código: Selecionar todos

'Sub PreencherListview5_BD()
On Error GoTo Error

With UserForm_Menu.ListView5
        .Gridlines = True
        .View = lvwReport
        .MultiSelect = True
        .ColumnHeaders.Add Text:="ID", Width:=52, Alignment:=0
        .ColumnHeaders.Add Text:="DT1", Width:=52, Alignment:=0
        .ColumnHeaders.Add Text:="Condutor", Width:=92, Alignment:=0
        .ColumnHeaders.Add Text:="Posto", Width:=32, Alignment:=0
        .ColumnHeaders.Add Text:="Dia", Width:=37, Alignment:=0
        .ColumnHeaders.Add Text:="Hora", Width:=40, Alignment:=0
        .ColumnHeaders.Add Text:="Viatura", Width:=60, Alignment:=0
        .ColumnHeaders.Add Text:="Destino", Width:=80, Alignment:=0
        .ColumnHeaders.Add Text:="Observacoes", Width:=220, Alignment:=0

End With

Dim Lista As Variant

UserForm_Menu.ListView5.ListItems.Clear

Set Rs = New ADODB.Recordset

ConectarBD

Rs.Open "SELECT * FROM Tabela1", Conexao, adOpenKeyset, adLockPessimistic

While Not Rs.EOF

With UserForm_Menu.ListView5
    Set Lista = UserForm_Menu.ListView5.ListItems.Add(Text:=Rs(0))
    Lista.ListSubItems.Add Text:=Rs(1)
    Lista.ListSubItems.Add Text:=Rs(2)
    Lista.ListSubItems.Add Text:=Rs(3)
    Lista.ListSubItems.Add Text:=Rs(4)
    Lista.ListSubItems.Add Text:=Rs(5)
    Lista.ListSubItems.Add Text:=Rs(6)
    Lista.ListSubItems.Add Text:=Rs(7)
    Lista.ListSubItems.Add Text:=Rs(8)

End With
Rs.MoveNext

Wend

If Not Rs Is Nothing Then
Rs.Close
Set Lista = Nothing
End If
DesconectarBD

Exit Sub
Error:
End Sub
e com este código esta-me so a carregar um valor do meio da base de dados.
mas se eu eliminar a linha
Lista.ListSubItems.Add Text:=Rs(8)
ele ja aparece os registos todos mas sem os valores dessa ultima coluna.

alguem consegue dar uma ideia do que se esta a passar?

Obrigado

pedro_mexico

29-08-2022 23:08:13

fiz o teste e coloquei a coluna 8 da listview(a que dá erro) a receber os valores da coluna7 do banco de dados, e ai ja aparece os valores todos, mas se colocar 8, ele cria o erro

Reinaldo

30-08-2022 17:04:48

Assim no escuro, fica muito complicado,
mas... talvez... o campo em questão (creo que obs) não esteja com "valores" na tabela access
tente validar esse campo antes da atribuição
em vez de

Código: Selecionar todos

 Lista.ListSubItems.Add Text:=Rs(8)
experimente algo +/-

Código: Selecionar todos

If Not IsNull(Rs(8)) Then Lista.ListSubItems.Add Text:=Rs(8)

pedro_mexico

30-08-2022 20:53:36

Boa noite Reinaldo,

obrigado pela ajuda.

funcionou no codigo .

muito obrigado mais uma vez, aos poucos com as ajudas do forum, vou conseguindo aprender um pouco