Problema Cancelamento OnTime

Wild Wolf

11-03-2011 14:52:48

Bom dia Tomás,
preciso novamente da sua Ajuda.


Utilizei a função de OnTime para fazer com que um campo de hora do meu formulário atualize a cada 10s, e gostaria que ele parasse a execução depois que o Formulário fosse fechado.
Porém quando executo o comando para Cancelamento de execução da Função, o sistema me exibe a mensagem de erro:

Código: Selecionar todos

Erro em tempo de execução '1004:' 
O método 'OnTime' do objeto '_Application' falhou
Estou executando os seguintes comandos:
Na inicialização do Formulário existem mais comandos, porém para simplificar irei mencionar apenas a parte do OnTime:

Código: Selecionar todos

Private Sub UserForm_Initialize()
    Application.OnTime Now + TimeValue("00:00:10"), "Tempo" 'Ativa a contagem de tempo qdo abrir a planilha 10 seg - altere 'para o tempo que quiser
End Sub

Código: Selecionar todos

Public Sub AtualizaAutomatico()
Chamadas.TextHora = Format(Time$, "hh:mm")
'MsgBox "Opa! Executou."
Application.OnTime Now + TimeValue("00:00:10"), "Tempo" 'Ativa a contagem de tempo qdo abrir a planilha 10 seg - altere 'para o tempo que quiser
End Sub

Código: Selecionar todos

Public Sub Tempo()
    Call Application.OnTime(Now + TimeValue("00:00:00"), "AtualizaAutomatico")
End Sub
Adicionei um botão no Formulário para testar o Cancelamento da função com o comando abaixo, porém ocorre o erro mencionado anteriormente.

Código: Selecionar todos

Public Sub CancelaOnTime()
    Application.OnTime EarliestTime:=Now, Procedure:="Tempo", Schedule:=False
End Sub

webmaster

15-03-2011 20:10:14

Wolf,

Procedimentos dentro do UserForm não são enxergados pelo OnTime. Ele precisa estar em um módulo, marcado como Public, daí então seu nome poderá ser chamado por seu nome textual. Não consegui contornar a limitação, por isso, no momento é uma obrigatoriedade.

Abraços

Wild Wolf

18-03-2011 14:43:19

webmaster escreveu:Wolf,

Procedimentos dentro do UserForm não são enxergados pelo OnTime. Ele precisa estar em um módulo, marcado como Public, daí então seu nome poderá ser chamado por seu nome textual. Não consegui contornar a limitação, por isso, no momento é uma obrigatoriedade.

Abraços
Tomás, tirei o relacionamento com o UserForm e coloquei para executar o OnTime assim que a pasta fosse aberta e finalizar antes de fechar a pasta, porém ocorre o mesmo erro mencionado acima.

Código: Selecionar todos

Private Sub Workbook_Open()
    Sheets("Inicio").Select
    Call Tempo
End Sub

Private Sub Workbook_BeforeClose(Cancel As Boolean)
    Call CancelaOnTime
End Sub

webmaster

18-03-2011 16:47:29

Wolf,

Pode enviar a planilha para dar uma olhada?

Abraços

Wild Wolf

18-03-2011 20:04:54

webmaster escreveu:Wolf,

Pode enviar a planilha para dar uma olhada?

Abraços
Tranquilo, segue em Anexo a Planilha.

Vlw

webmaster

19-03-2011 04:19:57

Wolf,

Perdoe-me. Tinha esquecido de um detalhe. O Schedule = False só funciona quando o Ontime agenda a execução com hora definido, e não intervalo de tempo, por exemplo:

Código: Selecionar todos

'Este exemplo executa my_Procedure às 17:00.
Application.OnTime TimeValue("17:00:00"), "my_Procedure" 

Código: Selecionar todos

'Este exemplo cancela a definição de OnTime do exemplo anterior.
Application.OnTime EarliestTime:=TimeValue("17:00:00"), _
    Procedure:="my_Procedure", Schedule:=False 
Quando se agenda usando um intervalo de tempo, não há como cancelar, a não ser que você saiba a hora exata em que ele fio agendado. Neste caso, para não adicionar essa complexidade ao código, o que se faz é colocar uma condição para execução do método. No caso de seu código, ficar algo assim:

Código: Selecionar todos

Public Cancela As Boolean

Public Sub AtualizaAutomatico()
    Chamadas.TextHora = Format(Time$, "hh:mm")

    If Not Cancela Then
        Application.OnTime Now + TimeValue("00:00:10"), "Tempo"    'Ativa a contagem de tempo qdo abrir a planilha 10 seg - altere 'para o tempo que quiser
    End If
End Sub
Public Sub Tempo()
    Cancela = False
    Call AtualizaAutomatico
End Sub

Public Sub CancelaOnTime()
    Cancela = True
End Sub
Ou seja, você não cancela o próximo Ontime. Ele é executado, mas é preciso tratar para que o loop não aconteça novamente. É uma saída. Utilizo-a a algum tempo e funciona bem.

Abraços

webmaster

21-08-2014 18:13:47

Wolf,

Um intervalo de tempo também é um horário definido. Mas, a precisão do horário é na casa dos segundos. Por isso, é preciso fazer o cancelamento exatamente no tempo no qual foi agendado.

Para mostrar o exemplo funcionando, veja o código que produzi em anexo. Acredito que vai ficar claro.

Abraços