Editando dados da Listview

Kdumyv

21-02-2016 16:10:18

Boa tarde galera,

Estou trabalhando em um código(cadastro), onde clico duas vezes no registro dentro da Listview para o mesmo retornar para o formulário e então editá-lo, o problema é que sempre que tenho mais de um registro na mesma data só volta para o formulario o primeiro daquela data os demais não retornam. ex.:

Reg.| data
01 | 01/01/2001 (se clicar nesse ele volta p o formulário)
02 | 01/01/2001 (se clicar nesse volta o primeiro dessa data ou seja o 01)
03 | 02/01/2001 (se clicar nesse ele volta p o formulário)
04 | 02/01/2001 (se clicar nesse volta o primeiro dessa data ou seja o 03)

Segue a parte do código que uso para essa tarefa.

Código: Selecionar todos

Private Sub lstconsulta_DblClick()

If (lstconsulta.ListItems.Count = 0) Then Exit Sub
    RsOsEmitidas.Seek "=", lstconsulta.SelectedItem.ListSubItems(1).Text
    Call Mostrar

End Sub

Kdumyv

24-02-2016 19:12:44

Boa tarde galera,

Alguém poderia me dar uma ajudinha com relação a esse problema,

Obrigado

Mikel Silveira Fraga

25-02-2016 11:31:08

Carlos, bom dia.

Respondi sua MP agora pela manhã.

Como mencionado na mensagem, favor postar um modelo com sua dúvida, pois apenas esse código, sem conhecer a estrutura da sua planilha, é muito vago para que possamos ajudar.

Fico no aguardo. Abraços!!!

Kdumyv

25-02-2016 17:54:32

Entendi,...

Segue então o código para melhor entendimento.

Código: Selecionar todos

Dim conexao As Database
Dim rsfluxo As Recordset
Dim Item As ListItem

Private Sub cmd_Acao_Click()
    If (cmd_Acao.Caption = "Gravar") Then

        If MsgBox("Confirma a gravação deste registro?", vbYesNo + vbQuestion, "Gravar") = vbNo Then Exit Sub
        If (Lbl_Acao.Caption = "I") Then
            rsfluxo.AddNew
        ElseIf (Lbl_Acao.Caption = "A") Then
            rsfluxo.Edit
        End If
        rsfluxo!Data = Txt_Data.Text
        rsfluxo!Classe = cmb_classe.Text
        rsfluxo!valor = txt_valor.Text
        rsfluxo!Descricao = txt_descricao.Text
        rsfluxo.Update

        rsfluxo.Seek "=", Txt_Data.Text

        Lbl_Acao.Caption = ""
        Call botoes
        Call Mostrar

    Else
        If MsgBox("Confirma a exclusão deste registro?", vbYesNo + vbQuestion + vbDefaultButton2, "Excluir") = vbNo Then Exit Sub
        rsfluxo.Delete
        If Not (rsfluxo.EOF) Then rsfluxo.MoveNext
        Call limpar
        Call Mostrar
        Call botoes
    End If
End Sub

Private Sub cmd_Alterar_Click()
    Txt_Data.SetFocus
    Lbl_Acao.Caption = "A"
    Call botoes
End Sub

Private Sub cmd_Consulta_Click()
    Dim rsConsulta As Recordset
    Dim sql As String
    sql = "select * from Fluxo where 1=1  "
    
    If (Cbo_Opcao.ListIndex > -1) And (Txt_opcao.Text <> "") Then
        If (Cbo_Opcao.ListIndex = 0) Then
            sql = sql & "and " & Cbo_Opcao.Value & "=" & Txt_opcao.Text & " "
        Else
            sql = sql & "and " & Cbo_Opcao.Value & " like '" & Txt_opcao.Text & "*' "
        End If
    End If
    
    If (Trim(Txt_pnome.Text) <> "") Then
        sql = sql & "and Data like '" & Txt_pnome.Text & "*' "
    End If
    
    sql = sql & "order by codigo"
    
    Set rsConsulta = conexao.OpenRecordset(sql, dbOpenDynaset)

    lstconsulta.ListItems.Clear
    Do Until (rsConsulta.EOF)
        Set Item = lstconsulta.ListItems.Add(, , rsConsulta!Codigo)
        Item.SubItems(1) = rsConsulta!Data
        Item.SubItems(5) = rsConsulta!Classe
        Item.SubItems(6) = Format(rsConsulta!valor, "#,##0.00")
        Item.SubItems(8) = rsConsulta!Descricao
        rsConsulta.MoveNext
    Loop
   
End Sub

Private Sub cmd_Consultar_Click()
    If (Lbl_Acao.Caption <> "") Then Exit Sub
    cmd_Consulta_Click
End Sub

Private Sub cmd_incluir_Click()
    Call limpar
    Caixa_Codigo.Text = "Automatico"
    Txt_Data.SetFocus
    Lbl_Acao.Caption = "I"
    Call botoes

End Sub

Private Sub lstconsulta_DblClick()
    If (lstconsulta.ListItems.Count = 0) Then Exit Sub
    rsfluxo.Seek "=", lstconsulta.SelectedItem.ListSubItems(1).Text
    Call Mostrar
End Sub

Private Sub UserForm_Initialize()

    Set conexao = OpenDatabase(ActiveWorkbook.Path & "\BDsistemafluxo.mdb")
    Set rsfluxo = conexao.OpenRecordset("Fluxo")

    rsfluxo.Index = "data"

    Call limpar
    Call botoes
    cmd_Consulta_Click

    StatusBar1.Panels(6).Text = "Usuário: " & Data & " - ID Sessão: " & sessao

End Sub

Private Sub Mostrar()
    If (rsfluxo.RecordCount > 0) Then
        Caixa_Codigo.Text = rsfluxo("Codigo")
        Txt_Data.Text = rsfluxo("Data")
        cmb_classe.Text = rsfluxo("Classe")
        txt_valor.Text = Format(rsfluxo("Valor"), "#,##0.00")
        txt_descricao.Text = rsfluxo("Descricao")
    End If
End Sub

Private Sub limpar()
    Caixa_Codigo.Text = ""
    Txt_Data.Text = ""
    cmb_classe.Text = ""
    txt_valor.Text = ""
    txt_descricao.Text = ""
   
End Sub

Private Sub botoes()
    If Lbl_Acao.Caption = "A" Then
        cmd_incluir.Enabled = False
        cmd_Alterar.Enabled = False
        cmd_Consultar.Enabled = False
        cmd_Acao.Caption = "Gravar"
        cmd_Sair.Caption = "Cancelar"
    ElseIf Lbl_Acao.Caption = "I" Then
        cmd_incluir.Enabled = False
        cmd_Alterar.Enabled = False
        cmd_Consultar.Enabled = False
        cmd_Acao.Caption = "Gravar"
        cmd_Acao.Enabled = True
        cmd_Sair.Caption = "Cancelar"
    ElseIf Lbl_Acao.Caption = "" Then
        cmd_incluir.Enabled = True
        If (rsfluxo.RecordCount > 0) Then cmd_Alterar.Enabled = True
        cmd_Consultar.Enabled = True
        If (rsfluxo.RecordCount > 0) Then
            cmd_Acao.Caption = "Excluir"
            cmd_Acao.Enabled = True
        End If
        cmd_Sair.Caption = "Sair"
    End If
End Sub

Kdumyv

01-03-2016 18:46:53

Boa tarde Galera,

Alguém tem uma solução para esse erro ?

Kdumyv

22-03-2016 16:04:01

Boa tarde galera,

Segue um exemplo do código que estou usando.

Mikel Silveira Fraga

22-03-2016 18:53:44

Carlos, boa tarde.

Cara como havia lhe dito, com o modelo em mãos é muito mais fácil conseguir ver a situação da planilha.

Veja abaixo:

Código: Selecionar todos

Private Sub lstconsulta_DblClick()

If (lstconsulta.ListItems.Count = 0) Then Exit Sub

    RsOsEmitidas.Index = "PrimaryKey"
    RsOsEmitidas.Seek "=", VBA.CInt(lstconsulta.SelectedItem.Text)
    'RsOsEmitidas.Seek "=", lstconsulta.SelectedItem.ListSubItems(1).Text
    
    Call Mostrar

End Sub
O que eu fiz foi, alterar o modelo de busca para a PrimaryKey (coluna AutoNumeração, ou Chave Primária). Na sequência, redefini para que o método Seek realizasse a busca pela coluna Os, que seria a PK da tabela. Dessa forma, ao invés de buscar pela data, busca diretamente pelo número da Os.

Altere esse comando e veja se é isso que você estava precisando.

Fico no aguardo.

Kdumyv

23-03-2016 00:32:40

Boa noite Mikel,

Perfeito meu amigo,...
Isso liquida mais essa duvida, obrigado.

Valeu,...