Travando um planilha Excel

Rodrigo

13-06-2010 14:40:16

Olá Tomaz,

Eu tenho planilha de excel que está compatilhada entre dois computadores, ou gostária de travar essa planilha para ser usada em apenas nesses dois comutadores, se pessoa copiasse esse programa e for usar em outro computador não seria possível. Pode me ajudar nessa questão ?

webmaster

14-06-2010 00:24:43

Rodrigo,

Isso ajuda?

Código: Selecionar todos

Function IsFileOpen(FileName As String) 
    Dim iFilenum As Long 
    Dim iErr As Long 
     
    On Error Resume Next 
    iFilenum = FreeFile() 
    Open FileName For Input Lock Read As #iFilenum 
    Close iFilenum 
    iErr = Err 
    On Error Goto 0 
     
    Select Case iErr 
    Case 0:    IsFileOpen = False 
    Case 70:   IsFileOpen = True 
    Case Else: Error iErr 
    End Select 
     
End Function 
 
Sub test() 
    If Not IsFileOpen("C:\MyTest\volker2.xls") Then 
        Workbooks.Open "C:\MyTest\volker2.xls" 
    End If 
End Sub 
Referência:
http://www.vbaexpress.com/kb/getarticle.php?kb_id=468

Abraços

fabriciosartori

18-06-2010 13:52:27

Cara você pode tambem usar a função environ("ComputerName"), conforme demonstro abaixo:

Em um Módulo

Código: Selecionar todos

Option Explicit

' Função Para liberar Acesso a Computadores pré-determinados
' Retorna Verdadeiro se o computador atual estiver na lista de computadores liberados, Falso se não estiver
' Data Criação: 18/06/2010
' Autor: Fabricio Sartori (fabricio@familiasartori.com.br)
' Desenvolvida em VBA - 6.3 - Office 2003

Function Liberar_Acesso() As Boolean
'Declaração das variaveis
    Dim Lista_Computadores
    Dim NomeComputador As String
    Dim Libera As Boolean
    Dim cont As Long

'Inicialização das variaves
    
    Lista_Computadores = Array("L1BBCCA", "L1BBCCV") 'Lista dos computadores liberados para acessar
    NomeComputador = Environ("COMPUTERNAME") 'Nome do computador que esta executando o código no momento da execução
    Libera = False 'Iniciada a variavel como falso

'   Faz o looping em todas as ocorrencias da lista de computadores comparado o valor da lista na _
    posição cont com o nome do computador Atual
For cont = 0 To UBound(Lista_Computadores)
    If Lista_Computadores(cont) = NomeComputador Then 'Se o nome do computador for localizado seta a variavel Libera e sai do looping
        Libera = True
        Exit For
    End If
Next
    
'Retorno o valor da variavel Libera para a função chamadaora
    Liberar_Acesso = Libera
End Function
No código do arquivo a ser travado no evento Abrir(no exemplo estou usando o EXCEL):

Código: Selecionar todos

Private Sub Workbook_Open()
    ' Chama a rotina para liberação, caso o computador não conte na lista fecha o arquivo, e exibe a mensagem de maquina não autorizada
    If Liberar_Acesso = False Then
        ThisWorkbook.Close False
        MsgBox "Esta máquina não esta autorizada a utilizar este arquivo", vbCritical, "Autorização"
        Exit Sub
    End If
End Sub
Testei no Office 2003, mas creio que não haverá problemas com outras versões do Office, pois não utiliza recursos do Office em si.