Listbox não busca os valores

Vitor Molena

06-09-2016 16:35:17

Boa tarde Galera!

Estou com uma dúvida no código-fonte onde tenho uma Listbox mostrando os cadastros dentro de um Userform onde posso filtrar 5 variáveis diferentes. As opções Código, Protocolo e Contagem buscam as informações corretamente. Já as opções Ultima Fatura e Proxima Fatura não funcionam . Podem me ajudar e verificar o que estou fazendo de errado para ele não buscar estas informações?
Inclusive tirei muitas informações deste código do blog.

Código: Selecionar todos

Private Sub btnFiltrar_Click()
    Call PopulaListBox(txtCodigo.Text, txtProtocolo.Text, txtContagem.Text, txtUltimaFatura.Text, txtProximaFatura.Text)
        
End Sub

Private Sub lstLista_DblClick(ByVal Cancel As MSForms.ReturnBoolean)
    If lstLista.ListIndex > 0 Then
        Dim indiceRegistro As Long
        indiceRegistro = frmRegistro.ProcuraIndiceRegistroPodId(lstLista.List(lstLista.ListIndex, 0))
        If indiceRegistro <> -1 Then
            Call frmRegistro.CarregaRegistroPorIndice(indiceRegistro)
        End If
        Unload Me
    Else
        lblMensagens.Caption = "Favor selecionar um item válido."
    End If
End Sub

Private Sub frmPesquisa_Initialize()
    Call PopulaListBox(vbNullString, vbNullString, vbNullString, vbNullString, vbNullString)
    
End Sub

Private Sub PopulaListBox(ByVal Codigo As String, _
                          ByVal Protocolo As String, _
                          ByVal Contagem As String, _
                          ByVal UltimaFatura As String, _
                          ByVal ProximaFatura As String)
                          

    On Error GoTo TrataErro

    Dim conn As ADODB.Connection
    Dim rst As ADODB.Recordset
    Dim sql As String
    Dim sqlWhere As String
    Dim sqlOrderBy As String
    Dim i As Integer
    Dim campo As Field
    Dim myArray() As Variant

    Set conn = New ADODB.Connection
    With conn
        .Provider = "Microsoft.JET.OLEDB.4.0"
        .ConnectionString = "Data Source=" & ThisWorkbook.FullName & ";Extended Properties=Excel 8.0;"
        .Open
    End With

    sql = "SELECT * FROM [Setembro$]"

    'Codigo
    Call MontaClausulaWhere(txtCodigo.Name, "Codigo", sqlWhere)
    
    'Protocolo
    Call MontaClausulaWhere(txtProtocolo.Name, "Protocolo", sqlWhere)

    'Contagem
    Call MontaClausulaWhere(txtContagem.Name, "Contagem", sqlWhere)
    
    'Ultima Fatura
    Call MontaClausulaWhere(txtUltimaFatura.Name, "Ultima Fatura", sqlWhere)
    
        'Contagem
    Call MontaClausulaWhere(txtProximaFatura.Name, "Proxima Fatura", sqlWhere)

    If sqlWhere <> vbNullString Then
        sql = sql & " WHERE " & sqlWhere
    End If

    If cboOrdenarPor.ListIndex <> -1 Then
        sqlOrderBy = " ORDER BY " & cboOrdenarPor.List(cboOrdenarPor.ListIndex, 0)
       
        'une a query order ao sql
        sql = sql & sqlOrderBy
    End If

    Set rst = New ADODB.Recordset
    With rst
        .ActiveConnection = conn
        .Open sql, conn, adOpenDynamic, _
              adLockBatchOptimistic
    End With

    lstLista.ColumnCount = rst.Fields.Count

    Dim indiceTemp As Long
    indiceTemp = cboOrdenarPor.ListIndex
    cboOrdenarPor.Clear
    For Each campo In rst.Fields
        cboOrdenarPor.AddItem campo.Name
    Next
    cboOrdenarPor.ListIndex = indiceTemp

    If Not rst.EOF And Not rst.BOF Then
        myArray = rst.GetRows
        myArray = Array2DTranspose(myArray)
        lstLista.List = myArray
        lstLista.AddItem , 0
        For i = 0 To rst.Fields.Count - 1
            lstLista.List(0, i) = rst.Fields(i).Name
        Next i
        lstLista.ListIndex = 0
    Else
        lstLista.Clear
    End If

    If lstLista.ListCount <= 0 Then
        lblMensagens.Caption = lstLista.ListCount & " registros encontrados"
    Else
        lblMensagens.Caption = lstLista.ListCount - 1 & " registros encontrados"
    End If

    Set rst = Nothing
    conn.Close

TrataSaida:
    Exit Sub
TrataErro:
    Debug.Print Err.Description & vbNewLine & Err.Number & vbNewLine & Err.Source
    Resume TrataSaida
End Sub

Reinaldo

07-09-2016 00:23:26

O que vem a ser esses campos? Que tipo de dados
Disponha seu modelo, para que não precisemos montar algo do nada

Vitor Molena

12-09-2016 13:17:08

Bom dia,

Essa planilha consiste em atualizarmos e consultarmos as datas de visita ao cliente, que é a coluna "CONTAGEM", mais as datas que foram feitas as faturas de cada cliente, porém fiz uma Userform de "PESQUISA" onde aparece uma listbox que lista todas os cadastros e eu consigo filtrar as informações que eu quero, porém quando fui colocar a "Última Fatura" e "Próxima Fatura", ele não faz o filtro.

Segue em anexo para que vocês possam visualizar melhor.

Reinaldo

16-09-2016 14:21:56

O "sistema" de filtro no modelo utilizado, considera campos tipo string/Texto para a procura aproximada (like); porem para campos/dados numéricos e campos data (que internamente são numéricos), essa pesquisa não obtêm resultado,pois um numero e sempre "olhado" completo e não parcial. Assim sendo sua montagem de clausulaWhere deve ser revista considerando essas premissas.
Como são duas datas deve decidir também se serão registros entre as duas datas (Inicio e Fim) ou registros que tenham uma ou outra ou registros que tenham as duas
Se forem entre as datas ficaria algo +/- assim (DataInicial/DataFinal devem ser alterados para os nomes de seu campo):

Código: Selecionar todos

        If NomeCampo <> "DataInicial" And NomeCampo <> "DataFinal" Then
        sqlWhere = sqlWhere & " UCASE(" & NomeCampo & ") LIKE UCASE('%" & Trim(Me.Controls(NomeControle).Text) & "%')"
        ElseIf NomeCampo = "DataInicial" Then
        sqlWhere = sqlWhere & NomeCampo & ">=#" & (Me.Controls(NomeControle).Text) & "# "
        ElseIf NomeCampo = "DataFinal" Then
        sqlWhere = sqlWhere & " " & NomeCampo & "<=#" & (Me.Controls(NomeControle).Text) & "#;"
        End If