Problema para fazer Pesquisa (Resolvido)

Doug.Vulcano

10-11-2010 13:16:00

Bom dia,
Alguem pode me explica oq é
ADODB.Connection
ADODB.Recordset
que esta sublinhado na macro abaixo?
pq qnd estou mandando odar a macro aparece q essas variaveis nao foram definidas.
como resolvo esse problema???


Private Sub PopulaListBox(ByVal Nome As String, ByVal Area As String, ByVal Endereco As String, ByVal Classificacao As String, ByVal Cidade As String, ByVal Bairro As String)

On Error GoTo TrataErro

Dim conn As ADODB.Connection
Dim rst As ADODB.Recordset

Dim sql As String
Dim sqlWhere As String
Dim sqlOrderBy As String
Dim i As Integer
Dim campo As Field
Dim myArray() As Variant

Set conn = New ADODB.Connection
With conn
.Provider = "Microsoft.JET.OLEDB.4.0"
.ConnectionString = "Data Source=" & ThisWorkbook.FullName & ";Extended Properties=Excel 8.0;"
.Open
End With

sql = "SELECT * FROM [Fornecedores$]"

'monta a cláusula WHERE
'NomeDaEmpresa
Call MontaClausulaWhere(txtNomeEmpresa.Name, "NomeDaEmpresa", sqlWhere)

'NomeDoContato
Call MontaClausulaWhere(txtNomeContato.Name, "NomeDoContato", sqlWhere)

'Endereço
Call MontaClausulaWhere(txtEndereco.Name, "Endereço", sqlWhere)

'Cidade
Call MontaClausulaWhere(txtCidade.Name, "Cidade", sqlWhere)

'Telefone
Call MontaClausulaWhere(txtTelefone.Name, "Telefone", sqlWhere)

'Região
Call MontaClausulaWhere(txtRegiao.Name, "Região", sqlWhere)

'faz a união da string SQL com a cláusula WHERE
If sqlWhere <> vbNullString Then
sql = sql & " WHERE " & sqlWhere
End If

'faz a união da string SQL com a cláusula ORDER BY
If cboOrdenarPor.ListIndex <> -1 Then
sqlOrderBy = " ORDER BY " & cboOrdenarPor.List(cboOrdenarPor.ListIndex, 0)
'define a direção
Select Case cboDirecao.ListIndex
Case Ascendente
sqlOrderBy = sqlOrderBy & " ASC"
Case Descendente
sqlOrderBy = sqlOrderBy & " DESC"
End Select
'une a query order ao sql
sql = sql & sqlOrderBy
End If

Set rst = New ADODB.Recordset
With rst
.ActiveConnection = conn
.Open sql, conn, adOpenDynamic, _
adLockBatchOptimistic
End With

'pega o número de registros para atribuí-lo ao listbox
lstLista.ColumnCount = rst.Fields.Count

'preenche o combobox com os nomes dos campos
'persiste o índice
Dim indiceTemp As Long
indiceTemp = cboOrdenarPor.ListIndex
cboOrdenarPor.Clear
For Each campo In rst.Fields
cboOrdenarPor.AddItem campo.Name
Next
'recupera o índice selecionado
cboOrdenarPor.ListIndex = indiceTemp

'coloca as linhas do RecordSet num Array, se houver linhas neste
If Not rst.EOF And Not rst.BOF Then
myArray = rst.GetRows
'troca linhas por colunas no Array
myArray = Array2DTranspose(myArray)
'atribui o Array ao listbox
lstLista.List = myArray
'adiciona a linha de cabeçalho da coluna
lstLista.AddItem , 0
'preenche o cabeçalho
For i = 0 To rst.Fields.Count - 1
lstLista.List(0, i) = rst.Fields(i).Name
Next i
'seleciona o primeiro item da lista
lstLista.ListIndex = 0
Else
lstLista.Clear
End If

'atualiza o label de mensagens
If lstLista.ListCount <= 0 Then
lblMensagens.Caption = lstLista.ListCount & " registros encontrados"
Else
lblMensagens.Caption = lstLista.ListCount - 1 & " registros encontrados"
End If

' Fecha o conjunto de registros.
Set rst = Nothing
' Fecha a conexão.
conn.Close

TrataSaida:
Exit Sub
TrataErro:
Debug.Print Err.Description & vbNewLine & Err.Number & vbNewLine & Err.Source
Resume TrataSaida
End Sub

Mauro Coutinho

11-11-2010 00:31:29

ADO - ActiveX Data Objects - Utilizado para se conectar a Banco de Dados.

Para entender melhor as linhas abaixo, veja os links abaixo.
Dim conn As ADODB.Connection
Dim rst As ADODB.Recordset


VBA - Excel : Acessando dados com ADO
http://www.macoratti.net/vba_xls1.htm

ADO - Usando com Visual Basic
http://www.macoratti.net/ado_vbas.htm

[]s