evento Worsheet_Change [RESOLVIDO]

Mauro Coutinho

20-03-2010 14:03:56

Excelistas, chegou minha vez de solicitar uma colaboração, ja postei essa duvida no forun, http://info.abril.com.br/forum/viewtopi ... 101&t=7050 , mas a anciedade de resposta é maior e tb peço a ajuda dos colegas.
A rotina abaixo após se digitar os dados em uma determinada planilha aciona-se a macro e a mesma corre a coluna B e D, verificando se na coluna B tem a palavra "Anulação", se sim converte o valor da coluna D para negativo, até ai tudo bem, funciona perfeitamente.

Essa Rotina funciona como deveria.

Código: Selecionar todos

'Converte Valor Positivo para Negativo conforme palavra Anulação
Sub PositivoNegativo()
    Dim i As Integer
    i = 2 'Linha 2
    While Cells(i, 2).Value <> "" 'Verifica Linha 2 + Coluna B
        If Cells(i, 2).Value = "Anulação" Then 'Se valor = Anulação
            If Cells(i, 4).Value < 0 Then 'Verifica se o valor já é negativo COLUNA D
            
            Else
                Cells(i, 4).Value = Cells(i, 4).Value * -1 'Altera o Valor de D em Negativo
                Cells(i, 4).Font.ColorIndex = 3 'Altera cor da fonte para vermelho
            End If
        End If
        i = i + 1
    Wend
End Sub
A minha duvida começa a partir da rotina abaixo :
Na intenção de automatizar sem precisar ficar acionando a rotina, adaptei para ser usada no Evento Worksheet_Change da seguinte forma :

Código: Selecionar todos

Private Sub Worksheet_Change(ByVal target As Range)
        Application.EnableEvents = False
        If Not Intersect(target, Range("D3:D30")) Is Nothing Then       'Até C30 é só modificar
            If target.Offset(0, -2) = "Anulação" Then                   'Se Na Coluna A tiver Anulação
                target = target.Value * -1                              'Transforma Valor de C de Positivo em Negativo
                target.Font.ColorIndex = 3                              'Formata a fonte em Vermelho
            End If
        End If
        Application.EnableEvents = True
End Sub
Então se digitar o texto na coluna B e depois o Valor na col. D o evento funciona normalmente, mas se eu resolver copiar esses dados de outra planilha e depois colar, me da erro de tempo de execução 1004, então tentei contornar modificando no Evento para que fosse chamado a macro em um modulo, ficando assim :

Código: Selecionar todos

Private Sub Worksheet_Change(ByVal Target As Range)
        Application.EnableEvents = False
        If Not Intersect(Target, Range("D3:D150")) Is Nothing Then       'Até C30 é só modificar
          Call PositivoNegativo
        End If
        Application.EnableEvents = True
End Sub
Feito isso, é possível eu copiar e colar sem problema sendo executado o pretendido, só que apareceu outro impasse e esse realmente não consegui resolver, é que após colar os dados se eu pretender digitar, a rotina se perde e formata a cor aleatoriamente dos numeros que não coincidem com o texto proposto, segue o anexo para melhor analise.
[REMOVIDO]

Desde já agradeço a atenção.
abraços

webmaster

22-03-2010 13:17:53

Mauro,

A rotina não se perde. O fato é que o Excel está copiando o formato da célula anterior ao digitar na nova linha. Isso é um comportamento padrão. Para resolver o seu problema, você terá que colorir também as células que não contenham o texto "Anulação" para a orginal. Mudei o código abaixo e funcionou bem:

Código: Selecionar todos

'Converte Valor Positivo para Negativo conforme palavra Anulação
Sub PositivoNegativo()
    Dim i As Integer
 '   Set rTarget = Target
    i = 3 'Linha 2
    While Cells(i, 4).Value <> "" 'Verifica Linha 2 + Coluna B
   
        If Cells(i, 2).Value = "Anulação" Then 'Se valor = Anulação
               If Cells(i, 4).Value < 0 Then 'Verifica se o valor já é negativo COLUNA D
               
               Else
                Cells(i, 4).Value = Cells(i, 4).Value * -1 'Altera o Valor de D em Negativo
                Cells(i, 4).Font.ColorIndex = 3 'Altera cor da fonte para vermelho
            End If
        Else
            Cells(i, 4).Font.ColorIndex = -4105 'Volta a cor para a original
        End If
        
        i = i + 1
    Wend
End Sub
Só creio que para um funcionamento total, você precisará mapear o evento Selection_Change também.

Abraços

Mauro Coutinho

23-03-2010 03:49:32

Tomaz, a solução era mais simples do que imaginava, grato pela ajuda, e apesar de alguns acharem que sou expert em VBA, eles se enganam, na maioria das vezes pesquiso muito antes para chegar a uma solução ou criar algo, então deixo uma outra pergunta:

O que você quer dizer com mapear o evento Selection_Change também.

Abraços

webmaster

23-03-2010 12:58:53

Mauro,

O Worksheet_Change é disparado somente na mudança entre planilhas. Se isso for suficiente, tudo bem. Mas o caso que citou, que inclui a digitação de dados na mesma planilha, seria interessante mapear o worksheet_selectionchange, que ocorre em toda navegação entre células. Pode ficar ou pouco pesado, mas é o caso de testar.

Aliás, se a necessidade for realmente essa, não é o caso de usar formatação condicional ou uma função personalizada?

Abraços

Mauro Coutinho

24-03-2010 02:28:16

Tomas, mais uma vez agradeço a atenção, o JValk do site da Info tambem tinha postado uma solução, e as duas servem direitinho ao pretendido, de forma diferente mas com o mesmo resiltado.

Quanto a sua colocação, entendi o que quiz dizer, e de fato, conversando com a solicitante o modelo ideal seria esse mesmo, pois a mesma utiliza com mais frequencia a opção de copiar (de uma plan Origem) e colar nessa, a digitação foi colocada em questão somente pelo fato de muito raramente se precisar e ter dado erro de incio.

Segue o link do modelo concluido para que possa servir de exemplo a outros que precisarem de solução parecida.
[REMOVIDO]

Abraços