Formatar eixos via vba

fabricio

22-05-2013 16:05:55

oi, pessoal. Boa tarde. Espero que alguém possa me ajudar.
é o seguinte. Eu escrevi uma macros para fazer uns gráficos. Formato quase tudo que quero nesses gráficos via macro, também, mas há uma propriedade que não consigo acessar e o gravador de macros não registra!
Estou trabalhando com gráficos de dispersão. Nos eixos eu consigo formatar os títulos, mas o tamanho das fontes dos valores eu não consigo acessar.
Eu consigo, por exemplo, configura que o título de algum eixo exiba o nome "Qualuqer", que a fonte desse título tenha o tamanho especificado e que o título fique na posição que eu desejo. Mas em se tratando dos valores associados a esse eixo, não consigo fazer nada via macro.
Alguém pode me dar uma luz?
Thanks

vbalexandre

26-05-2013 14:33:00

Bom dia!!

Tente adaptar
With .Axes(xlCategory)
.MaximumScale = 100
.AxisTitle.Characters.Text = "x"
End With
With .PlotArea
.Format.Line.Weight = 2.25
.Border.ColorIndex = 1
End With
.Axes(xlValue).AxisTitle.Characters.Text = "y"
.ChartArea.Font.Size = 16

Código: Selecionar todos

Sub Graph() 
     
    ActiveCell(1, 1) = 1 
    ActiveCell(1, 2) = 2 * ActiveCell(1, 1) + 7 
     
    For i = 2 To 100 
        ActiveCell(i, 1) = ActiveCell(i - 1, 1) + 1 
        ActiveCell(i, 2) = 2 * ActiveCell(i, 1) + 7 
    Next i 
     'Charts.Add
     
    Dim chtChartObj     As ChartObject 
    Dim rngSource       As Range 
     
    Set rngSource = [a1:b100] 
     
    Set chtChartObj = ActiveSheet.ChartObjects.Add(75, 75, 450, 250) 
     
    With chtChartObj.Chart 
        .ChartType = xlXYScatterSmoothNoMarkers 
        .SetSourceData rngSource 
        .SetElement (msoElementChartTitleAboveChart) 
        .SetElement (msoElementPrimaryCategoryAxisTitleAdjacentToAxis) 
        .SetElement (msoElementPrimaryValueAxisTitleRotated) 
        .SetElement (msoElementLegendNone) 
        .SetElement (msoElementPrimaryValueGridLinesNone) 
        .ChartTitle.Characters.Text = "y = 2x + 7" 
        With .Axes(xlCategory) 
            .MaximumScale = 100 
            .AxisTitle.Characters.Text = "x" 
            .AxisTitle.Font.Size = 16 
            .TickLabels.Font.Size = 16 
            .Format.Line.Weight = 2.25 
            .Border.ColorIndex = 1 
        End With 
        With .Axes(xlValue) 
            .AxisTitle.Characters.Text = "y" 
            .AxisTitle.Font.Size = 16 
            .TickLabels.Font.Size = 16 
            .Format.Line.Weight = 2.25 
            .Border.ColorIndex = 1 
        End With 
        .SeriesCollection(1).Border.ColorIndex = 1 
        .ChartArea.Border.LineStyle = None 
    End With 
End Sub 
..Leia mais em:
http://peltiertech.com/Excel/Charts/format.html
Att

fabricio

27-05-2013 17:52:49

Cara, muito obrigado. Muito bom mesmo!
Todo o código é muito didático e interessante.

Identifiquei qual era a prorpiedade que eu não estava conseguindo acessar: ".TickLabels.Font.Size"


vbalexandre escreveu:Bom dia!!

Tente adaptar
..Leia mais em:
http://peltiertech.com/Excel/Charts/format.html
Att