ListBox para mais de 10 colunas

Gabriel

13-12-2015 08:25:00

Bom dia,gostaria de tirar uma dúvida com quem possa me ajudar e que também seria de grande valia a respeito do uso de ListBox para Pesquisa.
Sou iniciante em VBA e encontrei na internet um modelo de formulário muito bacana e com todas as descrições de fácil entendimento dentro do código, mesmo sem conhecimento algum em programação e na Linguagem atribuída ao VBA.
Pude não só aprender um pouco mas como também retirar aquilo que não me era útil dentro do formulário sem danificá-lo,este trabalho acabou por me tomar uma tarde inteira. Feliz em estar solucionando o que necessito me deparei com uma impossibilidade,
minha planilha tem um total de 14 colunas e eu necessito que apareça todas as descrições dessas 14 colunas na ListBox. Vi aqui neste fórum a explicação para isso, em que realmente são apenas 10 no caso resultante de 9 colunas da planilha.
Li a respeito das dicas em que outros colegas mandaram a quem também teve esse problema, mas pela falta de conhecimento da minha parte em copiar e colar possivelmente em áreas erradas não fui bem sucedido.
Enviarei em ANEXO a minha Planilha com este formulário e torcerei para que alguém possa me ajudar.
Muito Obrigado
filtrar dados de listbox - andamento.rar

netocasaroli

13-12-2015 17:54:51

Gabriel, neste caso você terá que usar a propriedade RowSource para definir o intervalo de dados a ser populado na ListBox. Substitua nos seus códigos o Loop utilizado para preencher a ListBox por esse código:

Código: Selecionar todos

Me.ListBox1.RowSource = "A3:N" & Plan1.Cells(Rows.Count, 14).End(xlUp).Row

Mauro Coutinho

14-12-2015 10:51:34

Gabriel, só depois que respondi sua msg em pvt que vi que vc tinha aberto um tópico.

De fato no VBA o Listbox está limitado a 10 colunas (0-9), usando additem o limite são 10 colunas
usando RowSource 256 colunas

então, alem da dica do netocasaroli, você tambem poderá utilizar umas das seguintes formas :

Código: Selecionar todos

Private Sub UserForm_Initialize()

'''carrega dados
Dim c As Range, a() As String, n As Long, i As Long

    ListBox1.ColumnCount = 14

        With Sheets("Produtos")
            Set Rng = .Range("A3", .Range("A3").End(xlDown))
           
            Me.ListBox1.Clear
           
            For Each c In Rng
                n = n + 1: ReDim Preserve a(1 To 14, 1 To n)
                For i = 1 To 14
                    a(i, n) = c.Offset(, i - 1).Value
                Next
            Next
        End With
       
    'Preenche o Listbox
    If n > 0 Then Me.ListBox1.Column = a

End Sub
ou

Esta é parecida com a do netocasaroli e tem istrução para se definir o tamanho das colunas:

Código: Selecionar todos

Private Sub UserForm_Initialize()

    '''carrega dados
    Dim lastRow As Long
    
    'Limpa o Listbox
    Me.ListBox1.Clear
    
    lastRow = Worksheets("Produtos").Range("A65000").End(xlUp).Row
    'Preenche o Listbox
    ListBox1.RowSource = Sheets("Produtos").Range("A3:N" & lastRow).Address(external:=True)
    
    'Define os tamanhos das colunas
    ListBox1.ColumnWidths = "80 pt; 60 pt; 80 pt ;90 pt; 100 pt; 80 pt;80 pt;80 pt;80 pt;80 pt;80 pt;80 pt"
    
End Sub
Uma outra dica e eu prefiro, é utilizar o Controle ListView ao inves de Listbox, este controle tem várias propriedades em que podemos formatar.

[]s