Como alterar o caminho da importacao?[Resolvido]

macburn

11-08-2010 13:59:53

Boa dia Pessoal,
Minha dúvida é que a importação está sendo realizada para a planilha plan1, denominada de "Dados". Gostaria de saber como faço para ao invés de ser importado para essa planilha "Dados", ser importada para uma outra como plan2, plan3, etc., já que os botões coloquei nessa primeira planilha plan1 denominada "Dados", atualmente, sobrepoem os botões os dados importados.
Agradeço a todos...

Abraços

Código: Selecionar todos

Public Sub LeArquivoTexto()
    Dim Arquivo As Integer
    Dim CaminhoArquivo As String
    Dim TextoArquivo As String
    Dim TextoProximaLinha As String
    Dim ContadorLinha As Long
    Dim iniciaLeitura As Boolean
    
    'Configura a leitura do arquivo
    Arquivo = FreeFile
    CaminhoArquivo = "C:\temp\Planilha.txt"

    'Abre o arquivo para leitura
    Open CaminhoArquivo For Input As Arquivo
    ContadorLinha = 1
    'Lê o conteúdo do arquivo linha a linha
    Do While Not EOF(Arquivo)
        Line Input #Arquivo, TextoProximaLinha
        'add line numbers to it, in this case!
        TextoProximaLinha = TextoProximaLinha & vbCrLf
        
        'se for a linha de FIM, pára a leitura
        If InStr(1, TextoProximaLinha, "FIM", vbTextCompare) <> 0 Then Exit Do
        
        If iniciaLeitura Then TextoArquivo = TextoArquivo & TextoProximaLinha
        
        'se encontrar a string GRANDEZ, passa a coletar o texto
        If InStr(1, TextoProximaLinha, "GRANDEZ", vbTextCompare) <> 0 Then
            iniciaLeitura = True
        End If
    Loop
    
    Call EscreveArquivo(TextoArquivo)

    'Fecha o arquivo
    Close Arquivo

End Sub

Public Sub EscreveArquivo(ByVal Texto As String)
    Dim CaminhoArquivo As String
    CaminhoArquivo = "C:\temp\Grandez.txt"
    Arquivo = FreeFile
    Open CaminhoArquivo For Output As #Arquivo
    Print #Arquivo, Texto
    Close #Arquivo
    
    Call ImportaArquivo(CaminhoArquivo)
End Sub

Sub ImportaArquivo(CaminhoArquivo As String)

    With Worksheets("Dados").QueryTables.Add(Connection:= _
        "TEXT;" & CaminhoArquivo, Destination:= _
        Range("$A$1"))
        .Name = "Grandez"
        .FieldNames = True
        .RowNumbers = False
        .FillAdjacentFormulas = False
        .PreserveFormatting = True
        .RefreshOnFileOpen = False
        .RefreshStyle = xlInsertDeleteCells
        .SavePassword = False
        .SaveData = True
        .AdjustColumnWidth = True
        .RefreshPeriod = 0
        .TextFilePromptOnRefresh = False
        .TextFilePlatform = 850
        .TextFileStartRow = 1
        .TextFileParseType = xlDelimited
        .TextFileTextQualifier = xlTextQualifierDoubleQuote
        .TextFileConsecutiveDelimiter = False
        .TextFileTabDelimiter = True
        .TextFileSemicolonDelimiter = False
        .TextFileCommaDelimiter = False
        .TextFileSpaceDelimiter = False
        .TextFileColumnDataTypes = Array(1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, _
        1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1)
        .TextFileTrailingMinusNumbers = True
        .Refresh BackgroundQuery:=False
    End With
End Sub
Obs.: Código elaborado por Webmaster

André

11-08-2010 14:52:03

Tente alterar esta linha:

Código: Selecionar todos

With Worksheets("Dados").QueryTables.Add(Connection:= _
Em vez de "Dados", coloque o nome de outra sheet.

macburn

11-08-2010 17:07:19

Fala André,

Como vai? Pois então, tentei fazer esta alteração só que não obtive sucesso, dá erro de compilação.

Meus agradecimentos

André

11-08-2010 17:40:49

Qual erro é retornado?

macburn

11-08-2010 18:13:45

André,

Bom o erro dá nestas linhas aqui. Erro de sintaxe!

Código: Selecionar todos

Sub ImportaArquivo(CaminhoArquivo As String)

    With Worksheets("Plan2").QueryTables.Add(Connection:=
        "TEXT;" & CaminhoArquivo, Destination:= _
        Range("$A$1"))
Abraços

webmaster

11-08-2010 18:27:44

macburn,

De cara, coloque tudo em linha:

Código: Selecionar todos

With Worksheets("Plan2").QueryTables.Add(Connection:="TEXT;" & CaminhoArquivo, Destination:=Range("$A$1"))
Veja se o erro persiste.
Abraços

macburn

11-08-2010 18:45:58

Olá Pessoal,

Bom, agora o erro é: "Erro em tempo de execução '-2147024809(80070057)':
O intervalo de destino não está na mesma planilha na qual a tabela de consulta está sendo criada."

Obrigado pessoal!

macburn

12-08-2010 17:28:56

OLá Pessoal,

Como vai, tudo bom? Então, agora está aparecendo esse erro acima mencionado. Fiz as alterações sugeridas pelos colegas, mas não dá certo. Vou anexar a planilha. Obrigado a todos...

Abraços

macburn

12-08-2010 17:50:36

Boa tarde pessoal,

Bom, está resolvido este problema. Através da sugestão dos colegas, e o acréscimo desse pequeno detalhe nessa linha.

Mais uma vez...

Meus agradecimentos...

Código: Selecionar todos

    With Worksheets("Plan2").QueryTables.Add(Connection:="TEXT;" & CaminhoArquivo, Destination:=[i]Worksheets("Plan2")[/i].Range("$A$1"))

webmaster

12-08-2010 17:58:49

Muito bom macburn,

É uma excelente prática colocar aqui a solução para que todos possam ter acesso e não passar pelo mesmo problema outra vez.

Abraços

macburn

12-08-2010 19:26:54

Boa tarde Webmaster,

Obrigado. Espero poder ajudar também. Muito Obrigado.

Abraços

Mauro Coutinho

13-08-2010 00:50:17

mac, o merito é todo seu, mesmo com as ajudas recebidas você se empenhou em encontrar a solução e resolveu sem ter de postar novamente, e é por esse caminho que procuramos incentivar os participantes seguirem, entrar de cabeça no VBA não é fácil, mas se nos empenharmos em procurar entender com as dicas aonde estamos errando com certeza logo isso passará de questionamentos a ensinamentos aos mais novos.

parabens

][s

macburn

13-08-2010 17:43:36

Boa tarde pessoal,

Como vai, tudo bom? Obrigado pelo apoio que vocês dão ao pessoal. Muito bom. Isso faz parte do aprendizado. Um grande abraço a todos os colegas em especial Webmaster e Mauro Coutinho.