[RESOLVIDO] Desabilitar o X da planilha

reinaldo.silva

23-09-2010 20:43:45

Dae meu caros, ja pesquisei bastante sobre este assunto mas só encontrei como desabilitar o X do userform, eu precisava desabilitar o X da planilha, alguém pode me ajudar?

valeu

Mauro Coutinho

23-09-2010 23:59:59

reinaldo, em um Módulo Separado coloque as rotinas abaixo:

Código: Selecionar todos

Option Explicit
'OCULTA OS BOTÕES MINIMIZAR / MAXIMIZAR E FECHAR DA BARRA DO EXCEL

'Sem as declarações abaixo as macros para retirar e repor os botões não funcionará
Declare Function FindWindow32 Lib "user32" Alias "FindWindowA" _
        (ByVal lpClassName As Any, ByVal lpWindowName As Any) As Integer
Declare Function GetWindowLong32 Lib "user32" Alias "GetWindowLongA" _
        (ByVal hWnd As Integer, ByVal nIndex As Integer) As Long
Declare Function SetWindowLong32 Lib "user32" Alias "SetWindowLongA" _
        (ByVal hWnd As Integer, ByVal nIndex As Integer, _
        ByVal dwNewLong As Long) As Long
        
Global Const GWL_STYLE = (-16)
Global Const WS_SYSMENU = &H80000

Sub RepoeXdaBarra()

    Application.ScreenUpdating = True
    Dim WindowStyle As Long
    Dim hWnd As Integer
    Dim WindowName As String
    Dim Result As Variant

    WindowName = Application.Caption
    hWnd = FindWindow32(0&, ByVal WindowName)
    WindowStyle = GetWindowLong32(hWnd, GWL_STYLE)
    WindowStyle = WindowStyle Or WS_SYSMENU
    Result = SetWindowLong32(hWnd, GWL_STYLE, WindowStyle)
    
    'Força a barra de títulos a se atualizar, Retornando os Botões
    Application.Caption = ""
    ActiveWindow.Caption = " OK "

End Sub

Sub RetiraXdaBarra()

Application.ScreenUpdating = False

    Dim WindowStyle As Long
    Dim hWnd As Integer
    Dim WindowName As String
    Dim Result As Variant

    WindowName = Application.Caption
    hWnd = FindWindow32(0&, ByVal WindowName)
    WindowStyle = GetWindowLong32(hWnd, GWL_STYLE)
    WindowStyle = WindowStyle And (Not WS_SYSMENU)
    Result = SetWindowLong32(hWnd, GWL_STYLE, WindowStyle)

    'Força a barra de títulos a se atualizar, Ocultando os Botões
    Application.Caption = "TESTE X DA BARRA"
    ActiveWindow.Caption = " OK "

End Sub
No Evento Workbook_Open coloque :

Código: Selecionar todos

Private Sub Workbook_Open()
    Application.ScreenUpdating = False
          Call RetiraXdaBarra
    Application.ScreenUpdating = True

End Sub
E no Evento BeforeClose:

Código: Selecionar todos

Private Sub Workbook_BeforeClose(Cancel As Boolean)
    Application.ScreenUpdating = False
    
        Call RepoeXdaBarra
        
    Application.ScreenUpdating = True
End Sub
abraços

Guima

24-09-2010 00:21:28

Mauro,

Permita-me um pitaco.

Para desabilitar o "X" da planilha

Código: Selecionar todos

Private Sub Workbook_BeforeClose(Cancel As Boolean)

Cancel = True

End Sub
Para desabilitar o "X" do FORM

Código: Selecionar todos

Private Sub UserForm_QueryClose(Cancel As Integer, CloseMode As Integer)
If CloseMode <> 1 Then
MsgBox "Finalize pelo botão SAIR",
End If
Cancel = 1
End Sub

costac

25-04-2017 20:45:14

olá, preciso de ajuda!! Como fazer para este código rodar em 64 Bits?