Tomás Vásquez Fórum

Enviado: **Ter Jan 10, 2017 11:11 am**

Olá, boa tarde!

Gostaria de ajuda para elaborar uma função para pesquisar os vencimentos da semana atual e da próxima semana, pois ainda não consegui fazer...fiz apenas uma rotina que traz os vencimentos do dia quando clicar no botão hoje, conforme abaixo:

Código: Selecionar todos

Private Sub CarregaVencimentos()

Dim lastRow As Long
Dim i As Integer
lbVencimento.Clear
With lbVencimento
'define nº colunas
        .ColumnCount = 3
End With
' Verifica qual a ultima linha preenchida
lastRow = Planilha3.Range("A65000").End(xlUp).Row

'adiciona dados
For i = 2 To lastRow
If Day(Planilha3.Range("S" & i).Value) = Day(Date) And Month(Planilha3.Range("S" & i).Value) = Month(Date) Then
Me.lbVencimento.AddItem Planilha3.Range("A" & i)
Me.lbVencimento.List(Me.lbVencimento.ListCount - 1, 1) = Planilha3.Range("F" & i)
Me.lbVencimento.List(Me.lbVencimento.ListCount - 1, 2) = Planilha3.Range("S" & i)
End If

Next
End Sub

Caso alguém tem algo parecido, ajudaria bastante.
Obrigado!

Enviado: **Ter Jan 10, 2017 9:42 pm**

Código: Selecionar todos

Private Sub CarregaVencimentos()
Dim lastRow As Long
Dim i As Integer
Dim dtIni As Date, dtFim As Date
'Determina a segunda-feira da semana corrente
dtIni = Date - Weekday(Date, vbMonday) + 1
'Determina a sextaf-feira da semana seguinte
dtFim = dtIni + 12
lbVencimento.Clear
With lbVencimento
'define nº colunas
        .ColumnCount = 3
End With
' Verifica qual a ultima linha preenchida
lastRow = Planilha3.Range("A65000").End(xlUp).Row

'adiciona dados
For i = 2 To lastRow
'Supondo que coluna S seja data
If Planilha3.Range("S" & i).Value >= dtIni And Planilha3.Range("S" & i).Value <= dtFim Then
'If Day(Planilha3.Range("S" & i).Value) = Day(Date) And Month(Planilha3.Range("S" & i).Value) = Month(Date) Then
Me.lbVencimento.AddItem Planilha3.Range("A" & i)
Me.lbVencimento.List(Me.lbVencimento.ListCount - 1, 1) = Planilha3.Range("F" & i)
Me.lbVencimento.List(Me.lbVencimento.ListCount - 1, 2) = Planilha3.Range("S" & i)
End If

Next
End Sub

Enviado: **Qua Jan 11, 2017 7:55 am**

Reinaldo! bom dia!

Muito obrigado. Funcionou!

Tomás Vásquez Fórum

Listbox com vencimentos do dia e da semana. [Resolvido]

Listbox com vencimentos do dia e da semana. [Resolvido]

Re: Listbox com vencimentos do dia e da semana.

Re: Listbox com vencimentos do dia e da semana. [Resolvido]