VBA – Criando um Splash Screen

Quer criar um Splash Screen para seu aplicativo Excel? Antes de mais nada, Splash Screen é o temo usado para descrever a imagem ou tela inicial apresentada por um programa no momento da sua inicialização, resumindo, sua apresentação. No Excel por exemplo, na versão 2007, o Splash Screen é o seguinte:

VBA - Criando um Splash Screen

Bom, sabemos que podemos e desenvolvemos nossos aplicativos em VBA (pelo menos imagino isso dos leitores deste post) e é interessante em alguns colocar uma apresentação. Na maior parte dos casos, um Splash Screen é o mais indicado. Siga os passo abaixo para criar um Splash Screen no VBA.

Atenção: testei o passo a passo no Excel e no Word e funcionaram bem.

  • Abra o VBA (Alt+F11)
  • Insira um Novo UserForm (Inserir->UserForm)
  • Adicione um controle Label através da Caixa de Ferramentas (Exibir->Caixa de Ferramentas)
  • Configure a propriedade Caption do controle Label e do UserForm para o nome do Aplicativo (por exemplo, “Meu Aplicativo”)
  • Altere o tamanho da fonte do controle Label para ficar em evidência, assim como o tamanho do UserForm
  • Abra a janela de código do UserForm (F7 ou clique com o botão direito e dê um Exibir código)
  • Na parte superior da janela de código, selecione Userform na lista da esquerda e em seguida na lista da direita, selecione Initialize (nesta ordem)
  • Com isto, o evento UserForm_Initialize será criado conforme a figura abaixo:
  • VBA - Criando um Splash Screen
  • Agora, insira um novo módulo (Inserir->Módulo) e adicione nele o seguinte código:
  • Sub FechaForm()
    	Unload UserForm1
    End Sub
  • Volte ao códido o Userform e adicione o seguinte código no evento Initialize criado anteriormente para que fique da seguinte forma:
  • Private Sub UserForm_Initialize()
        Application.OnTime Now + TimeValue("00:00:05"), "FechaForm"
    End Sub
  • Até aqui, está tudo pronto para que, ao abrir o form, ele será fechado após 5 segundos através da macro FechaForm configurada pela função Application.Ontime
  • Experimente abrindo o Userform no VBA e clicando em F5
  • Agora, só falta colocar o Userform para abrir ao iniciar a planilha (neste caso, no Excel)
  • Para isso, no VBA, vá até a janela do Projeto (Exibir->Project Explorer)
  • Nele, selecione o item EstaPasta_de_trabalho e clique duas vezes sobre esta para abrir a janela de código
  • Na parte superior da janela de código, selecione WorkBood na lista da esquerda e em seguida na lista da direita, selecione Open (nesta ordem)
  • Com isto, o vento Workbook_Open será gerado
  • Altere-o para que fique da seguinte forma:
  • Private Sub Workbook_Open()
        UserForm1.Show
    End Sub

Com isso, toda vez que a Pasta de Trabalho (arquivo xls ou xlsm) for aberta com as macros ativadas, o form será aberto e fechado automiticamente 5 segundos depois.

Pronto! Temos nosso Splash Screen!

Abraços

C# – static readonly vs. const

C#
O pessoal do grupo em que participo colocou essa pergunta e achei bacana comentar aqui.

Qual a diferença entre utilizar static readonly ou const ? Tem algum
que é mais performatico?

const é avaliado em tempo de compilação, enquanto static readonly em tempo de execução. Isso permite que no static readonly você inicialize uma classe ou struct, enquanto no const você só pode usar tipos primários (porque são compilados).

O readonly pode ser inicializado dentro do construtor. Ou seja, dependendo do construtor que você usar, o readonly pode ter valores diferentes. Já o const não. Mas isso só vale pra readonly non-static, pq só existe um construtor static pra classe.

Tem mais um fator, muito importante aliás, principalmente na utilização de componentes.

Em quase todas as linguagens, const é apenas um facilitador para substituição de valores. Quando você declara um const e atribui um valor a ele, por exemplo, um inteiro de valor 5, ao compilar, todos os lugares que referenciam sua const vão ter o valor substituído pelo inteiro 5. Por isso a performance.

No caso do static reanonly, isso não acontece pois, apesar da variável ser somente leitura, ela ainda é uma “variável” e sempre será referenciada.

Um caso típico de onde não se deve usar const é em bibliotecas. Por exemplo, você criar uma lib que vai conter a string de conexão. Você a coloca em uma const. Na compilação, todos os valores que refenciam a
string de conexão terão seus valores substituídos pelo valor da const. Ok, era o que você queria. Mas, caso você preciso alterar a string de conexão, você obviamente vai recompilar e publicar somente a lib com a
informação. O fato é, ao fazê-lo, todo o resto do código só conhece o valor anterior da const.

Para ver um exemplo bem simples, crie o seguinte programa no notepad mesmo:

1
2
3
4
5
6
7
8
9
10
11
using System;
 
public class TestConst
{
        public static void Main(string[] args)
        {
                const string MinhaString = "bla";
                Console.WriteLine(MinhaString);
        }
 
}

Compile com o csc.exe. Em seguida, abra o assembly com o ILDASM ou mesmo o Reflector. Veja o resultado.

VBA – Como Filtrar dados no ListBox

VBA - Como Filtrar dados no ListBox

Este é um código de exemplo que tenho a muito tempo, mas como o pessoal tem pedido muito, vou deixá-lo em uma forma mais visível.

Como o VBA carece de controles de apresentação de dados mais avançados, como Grids e Listas complexas, acabamos apelando para o controle ListBox para apresentação de dados vindos de ResultSets (particularmente, prefiro apresentar os dados em uma planilha). Bom, como os dados já estão na LisBox, porque não aplicar o filtro nele mesmo?

Para ver um exemplo, proceda da seguinte forma:

  • Em um novo arquivo, crie uma lista de dados na Plan1, na coluna A a partir da célula A1
  • Abra o VBA (Alt+F11)
  • Adicione um UserForm ao projeto
  • No UserForm, adicione um controle TextBox e um ListBox (mantenha os nomes padrão dos controles)
  • Cliquem em F7 para exibir o código e adicione o seguinte:
  • Option Explicit
    'Autor: Tomás Vásquez.
    '       www.tomasvasquez.com.br/blog
    '       www.tomasvasquez.com.br/forum
    '       www.tomasvasquez.com.br/cursocsharp
    'Data:  15 de Janeiro de 2007.
    'Versão: 1.00 - Em VBA Microsoft Excel 2003 e 2007
    Private TextoDigitado As String
     
    Private Sub TextBox1_Change()
        TextoDigitado = TextBox1.Text
        Call PreencheLista
    End Sub
     
    Private Sub UserForm_Initialize()
        Call PreencheLista
    End Sub
     
    Private Sub PreencheLista()
        Dim ws As Worksheet
        Dim i As Integer
        Dim TextoCelula As String
        Set ws = ThisWorkbook.Worksheets(1)
        i = 1
        ListBox1.Clear
        With ws
            While .Cells(i, 1).Value <> Empty
                TextoCelula = .Cells(i, 1).Value
                If UCase(Left(TextoCelula, Len(TextoDigitado))) = UCase(TextoDigitado) Then
                    ListBox1.AddItem .Cells(i, 1)
                End If
                i = i + 1
            Wend
        End With
    End Sub

Execute o UserForm e digite valores válidos de filtro no TextBox e veja o efeito.

Trocando em miúdos, primeiro o UserForm carrega os dados da Plan1 no ListBox. Depois, o evento TextChange é mapeado para que toda digitação provoque a refiltragem dos dados. A forma de comparação é simples, mas poderia ter sido feita também com o operador Like.

Download do arquivo

https://www.tomasvasquez.com.br/forum/download/file.php?id=2142

VBA – Caixa de Diálogo para Abrir arquivo (OpenFileDialog)

Função pouco comum, mas em sistemas em VBA tem se tornado cada vez mais trivial a necessidade de abrir ou referenciar um arquivo.

A função abaixo (OpenFileDialog) abre uma caixa de diálogo para seleção de um arquivo e retorna o caminho deste juntamente com o nome do arquivo:

Public Function OpenFileDialog() As String
    Dim Filter As String, Title As String
    Dim FilterIndex As Integer
    Dim Filename As Variant
    ' Define o filtro de procura dos arquivos
    Filter = "Arquivos Wave (*.wav),*.wav,"
    ' O filtro padrão é *.*
    FilterIndex = 3
    ' Define o Título (Caption) da Tela
    Title = "Selecione um arquivo"
    ' Define o disco de procura
    ChDrive ("C")
    ChDir ("C:\")
    With Application
        ' Abre a caixa de diálogo para seleção do arquivo com os parâmetros
        Filename = .GetOpenFilename(Filter, FilterIndex, Title)
        ' Reseta o Path
        ChDrive (Left(.DefaultFilePath, 1))
        ChDir (.DefaultFilePath)
    End With
    ' Abandona ao Cancelar
    If Filename = False Then
        MsgBox "Nenhum arquivo foi selecionado."
        Exit Function
    End If
    ' Retorna o caminho do arquivo
    OpenFileDialog = Filename
End Function

Mais detalhes:

  • Utiliza-se o método GetOpenFilename para chamar a caixa de diálogo
  • Define-se o filtro de seleção de arquivos para o tipo  “Wave Files (*.wav),*.wav,”, mas poderia ser qualquer outro (txt, xls, doc, etc)
  • Pode-se definir um drive padrão de busca do arquivo

Bom proveito!

Referências:

http://www.tek-tips.com