Como executar macros em outro arquivo no Excel

Uma funcionalidade interessante de aplicativos Office é a possibilidade de executar macros de outros arquivos, mesmo que estes não estejam abertos.

Para fazer um teste, começe criando um arquivo, no Excel mesmo e crie a seguinte macro:

1
2
Public Sub testeMacro()
    MsgBox "Executou a macro em testeMacro.xls!"

End Sub

A observação aqui é que a macro deve obrigatoriamente Pública, como é mostrado neste exemplo. Grave a pasta de trabalho com o nome testeMacro.xls. Abra agora uma nova pasta de trabalho e nesta, crie uma nova macro com a seguinte código:

1
2
3
Sub teste()
    Application.Run "testeMacro.xls!testeMacro"
End Sub

O método Run serve exatamente para execução de macros no VBA. Salve este arquivo com qualquer nome, porém, na mesma pasta onde a pasta testeMacro.xls foi salva. Agora, execute a macro teste clicando em F5 e veja que o resultado é a MsgBox com a mensagem “Executou a macro em testeMacro.xls!”, conforme haviámos configurado.

Caso queira executar a macro que esteja localizada em algum outro arquivo, basta ao invés de informar somente o nome do arquivo, usar o caminho completo, por exemplo:

1
Application.Run "C:\temp\arquivo.xls!outraMacro"

É possível inclusiva passar parâmetros para tal função, bastando apenas informá-los após a chamada da função, por exemplo, para a macro:

1
2
3
Public Sub testeMacro(ByVal mensagem As String)
    MsgBox mensagem
End Sub

A chamada seria:

1
2
3
Sub teste()
    Application.Run "testeMacro.xls!testeMacro", "Minha mensagem"
End Sub

Abraços

Tomás Vásquez

Transpor dados no VBA – Invertendo Linhas e Colunas

Transpor Dados
Transpor Dados

Muito útil em seu formato tradicional no Excel, a função de transposição de dados permite trocar facilmente linhas por colunas de uma área de dados no Excel.

Para desenvolvedores VBA essa necessidade é um pouco rara, mas não menos importante, principalmente quando manipulamos muitos dados em arrays e controles. Bom, surgiu a necessidade e encontrei um código muito bem feito que efetua a tarefa.

A função recebe um Array de Variants de 2 dimensões como um argumento e retorna o mesmo já transposto.

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
Function Array2DTranspose(avValues As Variant) As Variant
    Dim lThisCol As Long, lThisRow As Long
    Dim lUb2 As Long, lLb2 As Long
    Dim lUb1 As Long, lLb1 As Long
    Dim avTransposed As Variant
    If IsArray(avValues) Then
        On Error GoTo ErrFailed
        lUb2 = UBound(avValues, 2)
        lLb2 = LBound(avValues, 2)
        lUb1 = UBound(avValues, 1)
        lLb1 = LBound(avValues, 1)
        ReDim avTransposed(lLb2 To lUb2, lLb1 To lUb1)
        For lThisCol = lLb1 To lUb1
            For lThisRow = lLb2 To lUb2
                avTransposed(lThisRow, lThisCol) = avValues(lThisCol, lThisRow)
            Next
        Next
    End If
    Array2DTranspose = avTransposed
    Exit Function
ErrFailed:
    Debug.Print err.description
    Debug.Assert False
    Array2DTranspose = Empty
    Exit Function
    Resume
End Function

Perfeita para trabalhar com dados, principalmente aqueles retornados em Recordsets ADO ou DAO.

Abraços e bom profeito!

Tomás Vásquez

Contando um determinado caractere em uma String no VBA

Aproveitando a dica passada a um colega de um fórum, segue uma função para contar a quantidade de ocorrências de um carater dentro de uma String no VBA:

1
2
3
4
5
6
7
8
9
Public Function ContaCaracteresNaString(ByVal texto As String, ByVal caracter As String) As Long
     Dim x As Variant
     x = Split(texto, caracter)
     ContaCaracteresNaString = UBound(x)
End Function
 
Public Sub Teste()
     MsgBox ContaCaracteresNaString("janeiro|fevereiro|março|abril|", "|")
End Sub

Os dados são um exemplo para testar a função. É bom lembrar que o código utiliza a função Split, não disponível em algumas versões do VBA.

Para uso da função Split nesses casos, existe um exemplo no site da própria Microsoft cujo link será colocado em breve neste blog.

Bom proveito!

Tomás Vásquez

Usando a função ShellExecute no VBA

 

EXECUTE ISSO!

A maioria dos desenvolvedores VBA conhecem a função Shell, que permite executar aplicativos baseados em seu caminho completo, por exemplo:

1
Shell("C:\Aplicativo.exe")

Porém, esta rotina se aplica apenas a executáveis. Caso fosse necessário abrir determinado arquivo, por exemplo, um documento do Word, existem dois caminhos:

– Passar o caminho do documento como parâmetro para o aplicativo usando a própria função Shell, por exemplo:

1
Shell ("WINWORD" & " " & """C:\temp\documento.doc""")

– Usar a função ShellExecute.
A função ShellExecute é capaz de “executar” um determinado arquivo, abrindo o arquivo associado a este, parâmetro determinado pelo Windows. É útil quando sabemos apenas o caminho do arquivo, e não de seu aplicativo, até porque isso pode mudar de computador para computador. Um exemplo do código pode ser visto abaixo:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
Const SW_SHOW = 1
Const SW_SHOWMAXIMIZED = 3
Public Declare Function ShellExecute Lib "Shell32.dll" Alias "ShellExecuteA" _
                      (ByVal hwnd As Long, _
                      ByVal lpOperation As String, _
                      ByVal lpFile As String, _
                      ByVal lpParameters As String, _
                      ByVal lpDirectory As String, _
                      ByVal nShowCmd As Long) As Long
Sub AbrirArquivo()
    On Error Resume Next
    Call ShellExecute(0, "open", "caminho do arquivo", "argumentos", _
                          "pasta onde está localizado o arquivo", _
                          SW_SHOWMAXIMIZED)
End Sub

As constantes declaradas são apenas para auxiliar a chamada da função. Perceba que é necessário apenas saber o caminho do arquivo. Os parâmetro “argumentos” pode ser vazio caso não seja necessário.

É mais uma alternativa para facilitar a manipulação de arquivos sem fazer referências diretas em nosso aplicativo.

Bom proveito!