VBA – A Instrução GoTo

O que é?

É um desvio incondicional para uma linha especificada dentro de uma função VBA.

Estrutura

GoTo [label]

O argumento [label] obrigatório pode ser qualquer rótulo de linha ou número de linha.
rótulo de linha

Utilizado para identificar uma única linha de código. Um rótulo de linha pode ser qualquer combinação de caracteres que inicie com uma letra e termine com dois-pontos (:). Os rótulos de linha não diferenciam maiúsculas de minúsculas e devem iniciar na primeira coluna.
número de linha

Utilizado para identificar uma única linha de código. Um número de linha pode ser qualquer combinação de dígitos que seja exclusiva dentro do módulo no qual é utilizado. Os números de linha devem iniciar na primeira coluna.

Exemplo

Abaixo segue um trecho de código que refleto o uso do Goto:

1
2
3
4
5
6
7
8
9
10
11
12
Public Sub TesteGoto()
    MsgBox "Inicio da função"
    GoTo Rotulo2
Rotulo1:
    MsgBox "Executando Rotulo1"
    GoTo Saida
Rotulo2:
    MsgBox "Executando Rotulo2"
    GoTo Rotulo1
Saida:
    MsgBox "Fim da função"
End Sub

O código acima mostra mensagens em uma sequência definida pela instrução Goto. A instrução não obedece nenhum critério, mesmo sendo executada de dentro uma estrutura condicional (If…Else) ou de repetição (While, For, For Each), fazendo desvio conforme informado. Neste caso, a instrução segue a sequência de execução normalmente até a linha 4, quando é desviada para o Rotulo2 na linha 9, que executa até a linha 11 que desvia a execução para o Rotulo1 na linha 6, que por fim executa até a instrução na linha 8 e quando é desviada para o Saida na linha 12, seguindo a execução até o fim da função.

Veja este outrou exemplo de código:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
Public Sub TesteGoto2()
 
    MsgBox "Inicio da função"
    GoTo Saida
 
    MsgBox "Conteúdo da função"
    MsgBox "Conteúdo da função"
    MsgBox "Conteúdo da função"
    MsgBox "Conteúdo da função"
    MsgBox "Conteúdo da função"
    MsgBox "Conteúdo da função"
    MsgBox "Conteúdo da função"
    MsgBox "Conteúdo da função"
 
Saida:
    MsgBox "Fim da função"
End Sub

Neste caso, por conta do desvio na linha 4 para o rotulo Saida na linha 15, todas as instruções das linhas 5 a 14 nunca serão executadas.

Comentários

GoTo pode desviar somente para linhas de dentro da função em que é colocado.

Observação Excesso de instruções GoTo pode tornar difícil a leitura e depuração do código. Sempre que possível, use instruções de controle estruturado (Do…Loop, For…Next, If…Then…Else, Select Case).

VBA – Criando um Splash Screen

Quer criar um Splash Screen para seu aplicativo Excel? Antes de mais nada, Splash Screen é o temo usado para descrever a imagem ou tela inicial apresentada por um programa no momento da sua inicialização, resumindo, sua apresentação. No Excel por exemplo, na versão 2007, o Splash Screen é o seguinte:

VBA - Criando um Splash Screen

Bom, sabemos que podemos e desenvolvemos nossos aplicativos em VBA (pelo menos imagino isso dos leitores deste post) e é interessante em alguns colocar uma apresentação. Na maior parte dos casos, um Splash Screen é o mais indicado. Siga os passo abaixo para criar um Splash Screen no VBA.

Atenção: testei o passo a passo no Excel e no Word e funcionaram bem.

  • Abra o VBA (Alt+F11)
  • Insira um Novo UserForm (Inserir->UserForm)
  • Adicione um controle Label através da Caixa de Ferramentas (Exibir->Caixa de Ferramentas)
  • Configure a propriedade Caption do controle Label e do UserForm para o nome do Aplicativo (por exemplo, “Meu Aplicativo”)
  • Altere o tamanho da fonte do controle Label para ficar em evidência, assim como o tamanho do UserForm
  • Abra a janela de código do UserForm (F7 ou clique com o botão direito e dê um Exibir código)
  • Na parte superior da janela de código, selecione Userform na lista da esquerda e em seguida na lista da direita, selecione Initialize (nesta ordem)
  • Com isto, o evento UserForm_Initialize será criado conforme a figura abaixo:
  • VBA - Criando um Splash Screen
  • Agora, insira um novo módulo (Inserir->Módulo) e adicione nele o seguinte código:
  • Sub FechaForm()
    	Unload UserForm1
    End Sub
  • Volte ao códido o Userform e adicione o seguinte código no evento Initialize criado anteriormente para que fique da seguinte forma:
  • Private Sub UserForm_Initialize()
        Application.OnTime Now + TimeValue("00:00:05"), "FechaForm"
    End Sub
  • Até aqui, está tudo pronto para que, ao abrir o form, ele será fechado após 5 segundos através da macro FechaForm configurada pela função Application.Ontime
  • Experimente abrindo o Userform no VBA e clicando em F5
  • Agora, só falta colocar o Userform para abrir ao iniciar a planilha (neste caso, no Excel)
  • Para isso, no VBA, vá até a janela do Projeto (Exibir->Project Explorer)
  • Nele, selecione o item EstaPasta_de_trabalho e clique duas vezes sobre esta para abrir a janela de código
  • Na parte superior da janela de código, selecione WorkBood na lista da esquerda e em seguida na lista da direita, selecione Open (nesta ordem)
  • Com isto, o vento Workbook_Open será gerado
  • Altere-o para que fique da seguinte forma:
  • Private Sub Workbook_Open()
        UserForm1.Show
    End Sub

Com isso, toda vez que a Pasta de Trabalho (arquivo xls ou xlsm) for aberta com as macros ativadas, o form será aberto e fechado automiticamente 5 segundos depois.

Pronto! Temos nosso Splash Screen!

Abraços

VBA – Excluindo arquivos e Movendo para a Lixeira

Lixeira
Lixeira

Programadores mais experientes sempre tiveram a mão uma função simples para exclusão de arquivos no VBA. A função Kill. A Macro abaixo exclui o arquivo no caminho informado:

Public Sub KillThem()
    Kill "C:\temp\delete.txt"
End Sub

Até aqui tudo bem. O inconveniente desta função é que o arquivo é definitivamente excluído, ou seja, não passa nem pela Lixeira. Em alguns casos isso pode até ser bom, em outros não, como por exemplo, selecionar um arquivo por engano.

Para isso, há uma pequena alternativa que seria a óbvia. Enviar o arquivo para a Lixeira. O código VBA abaixo permite a proeza:

Private Const FO_DELETE = &H3
Private Const FOF_ALLOWUNDO = &H40
Private Const FOF_NOCONFIRMATION = &H10
 
Private Type SHFILEOPSTRUCT
    hwnd As Long
    wFunc As Long
    pFrom As String
    pTo As String
    fFlags As Integer
    fAnyOperationsAborted As Long
    hNameMappings As Long
    lpszProgressTitle As Long
End Type
 
Private Declare Function SHFileOperation Lib _
 "shell32.dll" Alias "SHFileOperationA" (lpFileOp As SHFILEOPSTRUCT) As Long
 
Public Function Exclui_Arquivo(CaminhoArquivo As String) As Boolean
    Dim shfo As SHFILEOPSTRUCT
    Dim lresult As Long
 
    With shfo
        .wFunc = FO_DELETE
        .pFrom = CaminhoArquivo
        .fFlags = FOF_ALLOWUNDO Or FOF_NOCONFIRMATION
    End With
 
    lresult = SHFileOperation(shfo)
    Exclui_Arquivo = CBool(lresult = 0)
End Function
 
Um exemplo de chamada à função seria:
 
Public Sub Teste()
    Dim CaminhoArquivo As String
    CaminhoArquivo = "C:\temp\delete.txt"
    If Exclui_Arquivo(CaminhoArquivo) Then
        MsgBox "Arquivo " & CaminhoArquivo & " excluido com sucesso"
    Else
        MsgBox "Falha na exclusão do aquivo " & CaminhoArquivo
    End If
End Sub

É interessante notar que as constantes FOF_ALLOWUNDO e FOF_NOCONFIRMATION são utilizadas em cojunto. O resultado produzido é a efetivação da operação sem confirmação. Porém, se omitir o segundo, a caixa de confirmação de exclusão de arquivo padrão do Windows será mostrada.  Experimento deixar somente o FOF_ALLOWUNDO e execute o código novamente.

Não entrarei em detalhes da função SHFileOperation e da Estrutura SHFILEOPSTRUCT. Ambas estão bem detalhadas na documentação oficial:

SHFileOperation Function
SHFILEOPSTRUCT Structure

Bom proveito!

VBA – Como Filtrar dados no ListBox

VBA - Como Filtrar dados no ListBox

Este é um código de exemplo que tenho a muito tempo, mas como o pessoal tem pedido muito, vou deixá-lo em uma forma mais visível.

Como o VBA carece de controles de apresentação de dados mais avançados, como Grids e Listas complexas, acabamos apelando para o controle ListBox para apresentação de dados vindos de ResultSets (particularmente, prefiro apresentar os dados em uma planilha). Bom, como os dados já estão na LisBox, porque não aplicar o filtro nele mesmo?

Para ver um exemplo, proceda da seguinte forma:

  • Em um novo arquivo, crie uma lista de dados na Plan1, na coluna A a partir da célula A1
  • Abra o VBA (Alt+F11)
  • Adicione um UserForm ao projeto
  • No UserForm, adicione um controle TextBox e um ListBox (mantenha os nomes padrão dos controles)
  • Cliquem em F7 para exibir o código e adicione o seguinte:
  • Option Explicit
    'Autor: Tomás Vásquez.
    '       www.tomasvasquez.com.br/blog
    '       www.tomasvasquez.com.br/forum
    '       www.tomasvasquez.com.br/cursocsharp
    'Data:  15 de Janeiro de 2007.
    'Versão: 1.00 - Em VBA Microsoft Excel 2003 e 2007
    Private TextoDigitado As String
     
    Private Sub TextBox1_Change()
        TextoDigitado = TextBox1.Text
        Call PreencheLista
    End Sub
     
    Private Sub UserForm_Initialize()
        Call PreencheLista
    End Sub
     
    Private Sub PreencheLista()
        Dim ws As Worksheet
        Dim i As Integer
        Dim TextoCelula As String
        Set ws = ThisWorkbook.Worksheets(1)
        i = 1
        ListBox1.Clear
        With ws
            While .Cells(i, 1).Value <> Empty
                TextoCelula = .Cells(i, 1).Value
                If UCase(Left(TextoCelula, Len(TextoDigitado))) = UCase(TextoDigitado) Then
                    ListBox1.AddItem .Cells(i, 1)
                End If
                i = i + 1
            Wend
        End With
    End Sub

Execute o UserForm e digite valores válidos de filtro no TextBox e veja o efeito.

Trocando em miúdos, primeiro o UserForm carrega os dados da Plan1 no ListBox. Depois, o evento TextChange é mapeado para que toda digitação provoque a refiltragem dos dados. A forma de comparação é simples, mas poderia ter sido feita também com o operador Like.

Download do arquivo

https://www.tomasvasquez.com.br/forum/download/file.php?id=2142