VBA – Ordenando Arrays Multi Dimensionais

Mais uma do fórum, dessa vez, da autoria do colega André.

O código abaixo faz a ordenação de um array multidimensional, incrementando um exemplo já colocado aqui no blog que fazia o trabalho, mas somente com em arrays com uma dimensão. Bom, o código e seus comentários falam por si:

'@Sort ArrayMulti
'@Data: 04/08/2010
'@Autor: André Tonini
'   Esta função ordena um array multidimensional
'   Parametros
'       @TheArray - Array - Array que será ordenado
'       @Column - Integer - Por qual coluna o array será ordenado
'       @ColumnCount - Integer - O número de colunas do array
 
Public Function SortArrayMulti(ByRef TheArray As Variant, _
                                    Column, _
                                    ColumnCount)
    'Variaveis
    '----------
    Dim temp()
    Dim x, i, y As Integer
    Dim sorted As Boolean
 
    'Dimensões do array
    '------------------
    ReDim Preserve temp(1 To UBound(TheArray, Column), 1 To ColumnCount)
 
 
    'Repetição para ordenar até o final do array
    '--------------------------------------------
    Do While Not sorted
 
        'No inicio ele está ordenado
        '--------------------------
        sorted = True
 
        'Laço que percorre as linhas
        '----------------------------
        For x = linhaCabecalho + 1 To UBound(TheArray, Column) - 1
 
            'Faz a comparação
            '----------------
            If (TheArray(x, Column) > TheArray(x + 1, Column) And TheArray(x + 1, Column) <> Empty) Then
 
                'Ando por todas as colunas
                '-------------------------
                For y = 1 To ColumnCount
                    temp(x, y) = TheArray(x + 1, y)
                Next y
 
                'Ando por todas as colunas
                '-------------------------
                For y = 1 To ColumnCount
                    TheArray(x + 1, y) = TheArray(x, y)
                Next y
 
                'Ando por todas as colunas
                '-------------------------
                For y = 1 To ColumnCount
                    TheArray(x, y) = temp(x, y)
                Next y
 
                'Passou pelo if, então não está ordenado
                '---------------------------------------
                sorted = False
 
            End If
        Next x
    Loop
 
End Function

Valeu André!

VBA – Retornando a última posição lida no documento do Word

O Microsoft Word não é muito bem o melhor leitor de textos do mundo. Como assim? Pois, ele é um excelente editor de textos, ou seja, para criar, editar, etc. Mas para ler, convenhamos, nem programas como o Adobe Reader suprem as necessidades que os eBook Readers trouxeram. Uma delas e muito bem vinda para documentos grandes é manter a página na qual se está navegando.

Por exemplo, você abre um documento de 200 páginas, vai lendo, pára a leitura na página 88 e fecha o documento porque tem que fazer outra coisa. Horas depois, ou mesmo dias, você volta o documento e, em qual página estava mesmo? Imagine isso em documentos maiores?

Pois bem, de posse dessa necessidade, o código VBA abaixo faz exatamente isso. Em miúdos, antes de fechar o documento, ele adicionará um Indicador do Word (Inserir->Indicador), que serve para isso mesmo, bem no local onde estiver o cursor naquele momento. Após fechar e salvar, o que é obrigatório para o funcionamento da rotina, ao abrir novamente o documento, ele posicionára o documento no indicador que foi adicionado e o removerá, deixando-o livre para a próxima vez em que o documento for fechado.

Para funcionar em no documento desejado, com ele aberto no Word, abra o VBA (Atl+F11), localize na janela de Projeto o documento atual, que estará como “Project (Nome do documento)”. Clique sobre este item com o botão direito e selecione Inserir->Módulo. Na janela em branco que aparecer, coloque o seguinte código:

Sub ReferenciaAtual()
    With ActiveDocument.Bookmarks
        .Add Range:=Selection.Range, Name:="ReferenciaAtual"
        .DefaultSorting = wdSortByName
        .ShowHidden = False
    End With
End Sub
 
Sub IrParaReferenciaAtual()
    Selection.GoTo What:=wdGoToBookmark, Name:="ReferenciaAtual"
End Sub
 
Sub RemoverReferenciaAtual()
    If ActiveDocument.Bookmarks.Exists("ReferenciaAtual") Then
        ActiveDocument.Bookmarks("ReferenciaAtual").Delete
    End If
End Sub

Volte a janela de Projeto e clique duas vezes em ThisDocument. Na janela que aparecer, que é o código referente ao objeto do documento atual, coloque o seguinte código:

Private Sub Document_Close()
    Call ReferenciaAtual
End Sub
 
Private Sub Document_Open()
    Call IrParaReferenciaAtual
    Call RemoverReferenciaAtual
End Sub

Agora salve o documento. Para que tudo funcione, é preciso sempre habilitar as macros. No caso do Word 2007, é preciso salvar o documento no formato .docm, que é um documento do Word habilitado para macros.

Seguindo os passos descritos acima, toda vez que abrir o documento, ele voltará para a última página em que estava antes de ser fechado.

Download da planilha de exemplo

https://www.tomasvasquez.com.br/downloads/Teste_Retorna_Ultima_Pagina.zip

Bom proveito!

VBA – Aumente a segurança de seus projetos VBA

 

Logo VBA

Código de autoria do colega Felipe Dasi, colaborador do blog e do nosso fórum.

O conjunto de código abaixo serve para proteger seu arquivo de projeto VBA. Ele faz com que, caso o projeto VBA esteja desprotegido, todo os conteúdo de código dos módulos e planilha sejam excluídos, dificultando o hackeamento de seu aplicativo.

O código abaixo promove a proeza. Os comentários auxiliam na orientações deste e são do próprio autor.

Colocar em Estapasta_de_trabalho:

Option Explicit
 
Private Sub Workbook_Open()
      If Application.Version &gt; 9 Then
            Dim VisualBasicProject As Object
            On Error Resume Next
            Set VisualBasicProject = ActiveWorkbook.VBProject
            If Not Err.Number = 0 Then
 
      End If
      'DESABILITA ESC E INICIA RELOGIO
      Application.EnableCancelKey = xlDisabled
      Run "IniciaRelogio"
      End If
End Sub
 
'
'TODAS AS POSSIBILIDADES
Private Sub Workbook_SheetCalculate(ByVal Sh As Object)
      Run "ParaRelogio"
      'PODE COLOCAR CODIGO PROPRIO AQUI
      Run "IniciaRelogio"
End Sub
 
Private Sub Workbook_SheetChange(ByVal Sh As Object, ByVal Target As Range)
      Run "ParaRelogio"
      'PODE COLOCAR CODIGO PROPRIO AQUI
      Run "IniciaRelogio"
End Sub
 
Private Sub Workbook_SheetSelectionChange(ByVal Sh As Object, ByVal Target As Excel.Range)
      Run "ParaRelogio"
      'PODE COLOCAR CODIGO PROPRIO AQUI
      Run "IniciaRelogio"
End Sub
 
Private Sub Workbook_BeforeSave(ByVal SaveAsUI As Boolean, Cancel As Boolean)
      Run "ParaRelogio"
      'PODE COLOCAR CODIGO PROPRIO AQUI
      Run "IniciaRelogio"
End Sub
 
Private Sub Workbook_BeforeClose(Cancel As Boolean)
      Run "ParaRelogio"
      'PODE COLOCAR CODIGO PROPRIO AQUI'
End Sub

Colocar em um módulo VBA:

'Se a senha em A1 for igual a 123
'Se a senha em Comentários em propriedades da Planilha = 456
'Se a senha do VBA = 123
'RESULTADO O projeto VBA é aberto
'Resumindo, se uma das senha não bater o VBA é apagado
'Se você tirar a senha de A1 e Salvar, a planilha pode ser usada normalmente, mas
' se o usuário quebrar a senha, ao acessar o modulo o VBA serás apagado.
Option Explicit
 
Public IdleTime As Date
 
Private Sub DeletaVBA()
      With ThisWorkbook
            If Plan1.[A1] = "123" _
               And .BuiltinDocumentProperties("Comments") = "456" Then
                  'COLOCANDO A SENHA CORRETA DO VBA E MANTENDO AS OUTRAS DUAS EM A1 E EM PROPRIEDADES O RELOGIO NÃO É ATIVADO.
               'CASO CONTRARIO O RELOGIO É ATIVADO E EM 5 SEGUNDOS O PROJETO VBA SERÁ APAGADO.
                  Run "ParaRelogio"
                  Exit Sub
            Else
                  If .VBProject.Protection = 0 Then   'unlocked
                        Run "ParaRelogio"
 
                        Dim Component As Object
 
                        ' AQUI DELETA TODOS MODULOS DO VBA
                        For Each Component In .VBProject.VBComponents
                              With Component.CodeModule
                                    .DeleteLines 1, .CountOfLines
                              End With
                        Next
 
                        'SALVA AS ALTERAÇÕES FEITAS NA PLANILHA
                        .Save
                        'SE QUISER COLOCAR UMA MENSAGEM
                          MsgBox "SENHA(S) INCORRETA(S) - " &amp; _
                               "TODOS OS MODULOS SERÃO APAGADOS... :o)"
                        Workbooks.Open (.FullName)
                        .Close
                  Else
                        'INICIA A CONTAGEM DO RELOGIO SE VBA FOR QUEBRADO
                        Run "IniciaRelogio"
                  End If
            End If
      End With
      Exit Sub
 
End Sub
 
Private Sub IniciaRelogio()           
      If Plan1.[A1] = "123" _
         And ThisWorkbook.BuiltinDocumentProperties("Comments") = "456" _
         Then Exit Sub
 
            'AQUI É O TEMPO DE ABERTURA DO VBA
      IdleTime = Now + TimeValue("00:00:05")
 
      Application.OnTime IdleTime, "DeletaVBA"
End Sub
 
Private Sub ParaRelogio()
      On Error Resume Next
      Application.OnTime EarliestTime:=IdleTime, _
                         Procedure:="DeletaVBA", Schedule:=False
End Sub

O código e melhorias estão sendo discutidas em nosso fórum:

https://www.tomasvasquez.com.br/forum/viewtopic.php?f=6&t=249&start=10

Bom proveito! Valeu Felipe!

VBA – Lendo um arquivo texto linha a linha (sem FileSystemObject)


Bom, como falei sobre o mesmo problema outro dia em C#, nada mais justo do que publicar em VBA também, até porque a dúvida surgiu no fórum também.

A rotina abaixo faz o trabalho de abrir e ler uma arquivo no formato texto linha a linha. A idéia é permitir alterar o código de tal forma que se for preciso fazer uma análise do conteúdo da linha, fica fácil de fazer:

Option Explicit
 
Public Sub LeArquivoTexto()
    Dim Arquivo As Integer
    Dim CaminhoArquivo As String
    Dim TextoArquivo As String
    Dim TextoProximaLinha As String
    Dim ContadorLinha As Long
 
    'Configura a leitura do arquivo
    Arquivo = FreeFile
    CaminhoArquivo = "C:\temp\arquivo.txt"
 
    'Abre o arquivo para leitura
    Open CaminhoArquivo For Input As Arquivo
    ContadorLinha = 1
    'Lê o conteúdo do arquivo linha a linha
    Do While Not EOF(Arquivo)
        Line Input #Arquivo, TextoProximaLinha
        TextoProximaLinha = TextoProximaLinha & vbCrLf
        TextoArquivo = TextoArquivo & TextoProximaLinha
    Loop
 
    'Coloca na janela de verificação imediata
    Debug.Print TextoArquivo
 
    'Fecha o arquivo
    Close Arquivo
 
End Sub

Como destacado no título do arquivo, a vantagem deste método, apesar de menos legível, é não precisar carregar a dependência da biblioteca do FileSystemObject, usando somente os recursos padrão do Visual Basic.

Bom proveito!