Excel – O que é uma Pasta de trabalho no Excel?

Uma ajudinha a con sabor de Excel

Essa foi uma questão divertida, até. Ela surgiu não em um fórum, como de costume, mas de uma referência feita ao blog cujo critério de busca era exatamente o título deste post.

Como em muitas ocasiões e discussões em fóruns, blogs e outros meios de interação que existem na internet, o termo pasta de trabalho e planilha são pouco esclarecidos, resolvi colocar aqui um pequeno guia para elucidar e definir os mesmos, a fim de facilitar as discussões. Esta é uma idéia geral, mas suficiente para seguir em frente com longas discussões.

Vamos lá:

Pasta de trabalho

A pasta de trabalho é o arquivo do Excel como um todo, englobando todos os seus objetos, sendo eles planilhas, gráficos, planilhas de macro, tabelas dinâmicas, gráficos dinâmicos e projetos VBA. Ele é representado fundamentalmente pelo arquivo “fisico”, ou seja, o .xls (que pode ser também xlsx, xlsm, xla, xlt, entre outros formatos que em que o Excel pode ser salvo).

É muito comum este ser chamado de planilha. Até faz sentido, já que em sua concepção, o Excel é um gerenciador de planilhas eletrônicas. Porém, notem que o termo referente está no plural, ou seja, “planilhas”. Um arquivo do Excel é então, no mínimo um conjunto de planilhas, termo que será definido a seguir.

Planilha

Uma planilha é uma “aba”, popularmente falando. Normalmente, quando você abre o Excel, ele cria automaticamente uma nova pasta de trabalho com 3 planilhas. As planilhas podem ser visíveis na parte inferior da janela, como na figura abaixo:

Abas ou Planilhas

Tecnicamente, é correto chamar de “planilha” cada uma destas abas.

Arquivo

Um arquivo no contexto do Excel representa necessariamente uma pasta de trabalho, como foi explicado acima.

Esclarecendo

Portanto, de posse dos conceitos acima, é comum começarmos a estranhar frases como “tenho uma planilha do Excel”, ou “tenho um problema na minha planilha”, já que a primeira pergunta que se faz ao autor é “você quer dizer planilha ou pasta de trabalho?”.

Para programadores VBA, esse conceito tem que estar obrigatoriamente claro, já que, ao trabalhar com o modelo de objetos do Excel, esses dois ficam bem distintos, sendo representados pelos classes Worksheet e Workbook no VBA. Qualquer manipulação sobre qualquer um destes, as diferenças ficarão evidentes.

Só como um exemplo, uma planilha ou Worksheet contém uma coleção de células/cells. Já a pasta de trabalho ou Workbook, obrigatoriamente contém uma coleção de planilhas/worksheets, não sendo possível que ela tenha células diretamente.

Concluindo

Essa é a idéia geral. Seria preciso entrar no mérito de todos os objetos válidos do Excel para saber dar o correto nome aos bois, mas saber o descrito acima já ajuda e muito no entendimento das dúvidas que são colocadas nos fóruns e grupos de discussão.

Bom proveito a todos!

VBA – Copiando comentários de uma planilha para outra no Excel

Os fóruns de discussão são bacanas por gerarem situações das mais diversas, o que por consequência acaba gerando soluções que são de igual teor e variedade.

Mais uma que surgiu da necessidade de um colega, a macro abaixo copia todos os comentários de uma planilha do Excel para uma outra informada:

Sub CopiarComentarios(ByVal PlanilhaOrigem As String, ByVal PlanilhaDestino As String)
    Dim wsOrigem As Worksheet, wsDestino As Worksheet
    Dim c As Comment
    Dim r As Range
 
    Set wsOrigem = ThisWorkbook.Worksheets(PlanilhaOrigem)
    Set wsDestino = ThisWorkbook.Worksheets(PlanilhaDestino)
 
    For Each c In wsOrigem.Comments
        Debug.Print c.Parent.Address
 
        Set r = wsDestino.Range(c.Parent.Address)
 
        r.AddComment
        r.Comment.Visible = c.Visible
        r.Comment.Text Text:=c.Text
    Next
End Sub

Sem muito segredo, o código percorre a coleção de comentários (Comments) existente na planilha origem informada. Para cada comentário encontrado, é criado um na planilha destino com os mesmos dados e referências de célula.

Para fazer uma chamada a esta macro, segue um exemplo:

Sub Teste()
    Call CopiarComentarios("Plan1", "Plan2")
End Sub

Que solicita obviamente que os comentários da planilha de nome Plan1 sejam copiados para a planilha de nome Plan2. Para testar, é só copiar o código para um módulo VBA, inserir alguns comentários na Plan1 e executar a macro Teste.

Bom proveito!

VBA – Ocultando linhas em branco em uma lista no Excel

Fruto da necessidade de alguns colegas do Fórum, coloco aqui uma macro que possibilita ocultar as linhas de uma lista ou tabela no Excel. O efeito pode muito bem ser conseguido através do recurso AutoFiltro, mas, como relatado, algumas vezes usuários menos avançados não conhecem a funcionalidade para produzir o efeito determinado.

Para alguns familiarizados, a rotina é uma adaptação da macro que também existe aqui no blog para excluir linhas de acordo com um critério:

Function OcultaLinhasPorCriterio(ByVal nomePlanilha As String, ByVal linhaInicial As Integer, ByVal linhaFinal As Integer, ByVal colunaCriterio As Integer) As Integer
    Dim linhasOcultadas As Integer
    Dim i As Integer
    linhasOcultadas = 0
    With ActiveWorkbook.Worksheets(nomePlanilha)
        i = linhaInicial
        While i <= linhaFinal
            If IsEmpty(.Cells(i, colunaCriterio).Value) Then
                .Cells(i, colunaCriterio).Rows.Hidden = True
                linhasOcultadas = linhasOcultadas + 1
            End If
            i = i + 1
        Wend
    End With
    OcultaLinhasPorCriterio = linhasOcultadas
End Function

Em míudos:

nomePlanilha é o nome da planilha sobre a qual a macro atuará
linhaInicial é o número da linha pela qual a macro comecará a avaliar.
linhaFinal é o número da linha até a qual a macro fará a avaliação
colunaCriterio é o índice numérico da coluna na qual a macro fará o teste do valor vazio.

A macro abaixo faz a chamada a função apontadando para a panilha de nome “Plan1” avaliando a coluna de índice 5 (E) percorrendo até a última linha ocupada:

Sub OcultarLinhasEmBranco()
    MsgBox OcultaLinhasPorCriterio("Plan1", 2, ActiveSheet.UsedRange.Rows.Count, 5) & " linhas ocultadas"
End Sub

Bom proveito!

VBA – Mostrando uma mensagem durante o cálculo do Excel

A pergunta surgiu em um dós fóruns de Excel do qual participo. Das soluções com as quais me deparei, essa foi a mais interessante e limpa. Siga os seguintes passos:

Na planilha em que será avaliada para cálculo, abra o código VBA da planilha e coloque o seguinte código

Private Sub Worksheet_Calculate()
	UserForm1.Show
End Sub

Crie um novo UserForm chamado UserForm1 e adicione este código ao UserForm:

Private Sub UserForm_Activate()
	Call WaitTimer
End Sub

Crie um novo Módulo VBA e adicione o seguinte código:

Sub WaitTimer()
	If Application.CalculationState <> xlDone Then
		Application.OnTime EarliestTime:=Now + TimeValue("00:00:01"), _
		Procedure:="WaitTimer", Schedule:=True
	Else
		Unload UserForm1
	End If
End Sub

Essas e algumas outras podem ser vistas na seguinte referência:

http://www.eggheadcafe.com/software/aspnet/35770319/vba-message-box-to-inform.aspx

Bom proveito!